標(biāo)題: 看懂時序圖,單片機(jī)驅(qū)動LCD1602液晶屏 [打印本頁]
作者: nklug    時間: 2018-4-2 11:18
標(biāo)題: 看懂時序圖,單片機(jī)驅(qū)動LCD1602液晶屏
本帖最后由 nklug 于 2018-4-5 11:36 編輯

看懂時序圖，驅(qū)動LCD1602液晶屏
                    作者：贛州 盧剛（nklug）
[本人原創(chuàng)，轉(zhuǎn)載請保留署名。2018年4月2日]
  網(wǎng)購了幾個LCD1602液晶屏，用STC驅(qū)動它，開始只是一個點亮了的藍(lán)屏，不見字符，費了一番功夫才成功顯示出字符。現(xiàn)將驅(qū)動LCD1602液晶屏的經(jīng)驗總結(jié)如下，希望對初次使用的朋友有所幫助。
驅(qū)動液晶屏，按下列步驟進(jìn)行：
1、  把的R/W接地（原因后述），調(diào)節(jié)對比度，使屏顯出一行白色矩形塊。


我開始的不成功，是省了V0接的電阻，讓它空著，以為也能顯示字符，只不過不好看罷了，不知大錯特錯。記著一定要接V0腳的調(diào)節(jié)對比度電阻并調(diào)試好，否則只是藍(lán)屏，不出字也不出矩形塊。調(diào)整對比度有兩種方法，介紹較多的是第一種標(biāo)準(zhǔn)接法，可調(diào)電阻用10K的。第二種接法據(jù)自己的實驗，R可用510歐（最后調(diào)試成功后改用3.3K）。
這一步目的是讓它顯示出一行淺白色矩形塊，注意無須太亮。

1602液晶屏只要加上了電壓，調(diào)整好對比度，沒接單片機(jī)也能顯示出一行矩形塊，只有初始化后才會出現(xiàn)兩行。利用這點可作液晶屏好壞的初步判斷。
2、 設(shè)置顯示模式，讓液晶屏顯示出兩行白色矩形塊。（實質(zhì)是寫好寫命令的子程序。）

通常推薦的初始化過程：
延時15ms
寫指令38H
延時5ms
寫指令38H
延時5ms
寫指令38H
延時5ms
（以上都不檢測忙信號）
（以下都要檢測忙信號）
寫指令38H
————————
寫指令08H關(guān)閉顯示
寫指令01H顯示清屏
寫指令06H光標(biāo)移動設(shè)置
寫指令0cH顯示開及光標(biāo)設(shè)置
完畢
我們讓程序完成四次寫38H指令就停下來，后四步暫不執(zhí)行。只要四次寫指令38H成功，液晶屏就會出現(xiàn)兩行矩形塊。為什么要四次呢？不清楚。就照他的辦好了。
能出現(xiàn)兩行矩形塊，說明寫指令的子程序是正確的，后面的事也就好辦了。若不成功，則對照1602屏的寫操作時序，仔細(xì)修改程序。我開始的不成功，第二個原因就是沒弄清時序，胡亂寫沒成功就生搬硬套網(wǎng)上程序。
1602屏寫操作的時序圖：

時序時間參數(shù)：

從時序圖確定子程序步驟如下：①為RS和R/W賦值；②為D0~D7數(shù)據(jù)口賦值，延時后再設(shè)置E；③將E置高電平，E＝1；延時tpw；④將E清零，產(chǎn)生重要的執(zhí)行下降沿；⑤下降沿后要延時tHD2,確保數(shù)據(jù)口在這段時間內(nèi)不變；⑥依靠子程序以后的延時，來滿足E信號周期最小值tc。
我用STC12C5201AD 6M晶振驅(qū)動1602屏，根據(jù)每步程序所要用的時間和時序要求，寫的代碼如下，實際運行通過。
;*****************************
;1602寫命令，命令存在LCD_DAT，
;*****************************                          
PR_CMD:
                    CLR           LCD_RS     ; ①為RS和R/W賦值
                    CLR           LCD_RW           ;實際上R/W腳接地了，此句可無
                    MOV         LCD_DATA,LCD_DAT  ; ②為D0~D7數(shù)據(jù)口賦值

                   SETB        LCD_EN          ;③將E置高電平
                    NOP               ;延時   
                    CLR           LCD_EN          ; ④將E清零，產(chǎn)生重要的下降沿
                    lcall     uS40            ;⑤下降沿后延時
                    RET
將38H改為34H，是一行5*10模式，顯示如下圖：

3、     完成初始化程序的后四步。
資料說寫指令38H后，后面的每步都要檢測忙信號。因為1602屏是個慢性子，上步?jīng)]執(zhí)行完就來下一步，下一步就執(zhí)行不了。我這樣想，若上一步?jīng)]完成，則檢忙這步也應(yīng)該不能運行，檢忙能運行則上一步定是已經(jīng)完成了。很多人說是用延時替代檢忙。我呢？用延時1mS來代替檢忙。
不讀讀忙信號，也不讀數(shù)據(jù)了（不用命令9和命令11），則可直接將R/W接地，還可省一根接線。這就是第一步把R/W接地的原因。
我的初始化過程：
延時15ms
寫指令38H
延時5ms
寫指令38H
延時5ms
寫指令38H
延時5ms
寫指令38H
延時1mS
寫指令08H關(guān)閉顯示
延時1mS
寫指令01H顯示清屏
延時1mS
寫指令06H光標(biāo)移動設(shè)置
延時1mS
寫指令0cH顯示開及光標(biāo)設(shè)置
延時1mS
完畢
后面的五步都將原來的檢測忙改為延時，試驗結(jié)果延時160uS不夠，延時1mS至5mS都行，其余沒試。
我試驗過，整個初始化過程中，只用第一步寫38H指令和最后一步寫指令0CH也可以，中間六步省去也行。為保險其見，仍寫八個指令。
4、  顯示字符。
寫數(shù)據(jù)子程序與寫命令子程序基本相同，僅R/S的值不同。運行本子程序前先延時1mS，確保前一步運行已經(jīng)完成。
;*****************************
;1602寫數(shù)據(jù)，數(shù)據(jù)存在LCD_DAT
;*****************************
PR_DATA:
                    SETB       LCD_RS          ;RS高 數(shù)據(jù)
                    CLR           LCD_RW          ; 實際上R/W腳接地了，此句可無
                    MOV         LCD_DATA,LCD_DAT

                    SETB         LCD_EN          ;先置高           
                    nop                              ;延時
                    CLR           LCD_EN           ;產(chǎn)生下降沿 執(zhí)行
                    lcall   us40
                    RET
寫字符成功，屏的白色塊上就會出現(xiàn)更亮的字符，所以調(diào)對比度時白色塊不要調(diào)得太亮了。

5、  再次調(diào)整對比度。
調(diào)v0腳上的電阻，使得白色塊消失，只留下的清晰字符。我原是用一個510歐電阻接地，現(xiàn)改為用一個3.3K電阻接地。若是用第一種接法，旋轉(zhuǎn)一下中間觸點位置就行了。
液晶屏A，K分別接電源正負(fù)點亮背景燈，可在電源正與A之間串一個10~15歐電阻，適當(dāng)降低點亮度，延長燈壽命。
這是試驗程序顯示了幾個字母的樣子：

6、  總結(jié)：先設(shè)置好硬件（顯出白色矩形塊），再把握好時序?qū)懗绦颉?/div>
能顯示字符，自然也就能在實際應(yīng)用中顯示時間電壓之類的數(shù)據(jù)了。
7、  我的試驗程序：
  1. ;STC12C5201AD6M晶體 驅(qū)動LCD1602屏
  2. ;作者：贛州 盧剛（nklug）
  3. ;2018年3月
  4. ;*******************

  6. ;端口引腳定義
  7. LCD_RS               BIT            P2.6         ;1602數(shù)據(jù)命令選擇端口
  8. LCD_RW             BIT            P2.7         ;1602讀寫選擇端口
  9. LCD_EN              BIT            P3.7         ;1602使能端口
  10. LCD_DATA         EQU          P1                      ;1602數(shù)據(jù)端口

  12. ;變量聲明
  13. ALL_FLAG EQU          20H                   ;標(biāo)志位
  14. LCD_FLAG          EQU          ALL_FLAG.7      ;1602讀忙標(biāo)志位
  15. LCD_DAT            EQU          30H                   ;1602數(shù)據(jù)命令字  
  16. DELAYED            EQU          31H                   ;延時字


  19. ORG 0000H
  20. SJMPSTART
  21. ORG  0030H


  24. START:
  25.      lcall LCD_INIT     ;初始化液晶

  27.      lcall uS160  
  28.      MOV lcd_dat,#84H  ;寫在何位置
  29.      lcall PR_CMD
  30.      mov 50H,#3

  32.      lcall uS160   
  33.      mov LCD_DAT,#01101110B    ;字母n的代碼
  34.      lcall PR_DATA

  36.     lcall uS160   
  37.      mov LCD_DAT,#01101011B    ;字母k的代碼
  38.      lcall PR_DATA

  40.          lcall uS160   
  41.      mov LCD_DAT,#01101100B    ;字母l的代碼
  42.      lcall PR_DATA

  44.          lcall uS160   
  45.      mov LCD_DAT,#01110101B    ;字母u的代碼
  46.      lcall PR_DATA
  47.          lcall uS160   
  48.      mov LCD_DAT,#01100111B    ;字母g的代碼
  49.      lcall PR_DATA

  51.     AJMP $
  52. ;***************
  53. ;1602初始化
  54. ;***************
  55. LCD_INIT:
  56.                     MOV                  DELAYED,#15
  57.                     LCALL       DELAY1MS
  58.                     MOV                  LCD_DAT,#38H
  59.                     LCALL       PR_CMD

  61.                     MOV                  DELAYED,#5
  62.                     LCALL       DELAY1MS                     
  63.                     MOV                  LCD_DAT,#38H
  64.                     LCALL       PR_CMD

  66.                     MOV                  DELAYED,#5
  67.                     LCALL       DELAY1MS
  68.                     MOV                  LCD_DAT,#38H      ;上三次下一次設(shè)38H，在運行過多次的片子試過僅用第一次設(shè)38H也是可以的。
  69.                     LCALL       PR_CMD               ;估計這是多次初始化后的原故，為保險還是這樣多次的設(shè)置38H好。
  70.            ;*****上面要重復(fù)3次*****
  71.            ;*****下面設(shè)置的間隔若用延時160uS則不行，用1mS至5mS都可****     
  72.                     MOV                  DELAYED,#1
  73.                     LCALL       DELAY1MS
  74. ;                            LCALL uS160
  75.                     MOV                  LCD_DAT,#38H  ;#00111000B 使用8位數(shù)據(jù)，顯示兩行，使用5×7的字型
  76.                     LCALL       PR_CMD

  78.                     MOV                  DELAYED,#1
  79.                     LCALL       DELAY1MS
  80. ;                            LCALL uS160   
  81.                     MOV                  LCD_DAT,#08H   ;顯示關(guān)無光標(biāo) 光標(biāo)閃    無也可以
  82.                     LCALL       PR_CMD

  84.                     MOV                  DELAYED,#1
  85.                     LCALL       DELAY1MS
  86. ;                            LCALL uS160   
  87.                     MOV                  LCD_DAT,#01H   ;#00000001H    ;清屏    無也可以
  88.                     LCALL       PR_CMD  

  90.                     MOV                  DELAYED,#1
  91.                     LCALL       DELAY1MS
  92. ;                            LCALL uS160
  93.                     MOV                  LCD_DAT,#06H  ;;字符不動，光標(biāo)自動右移一格    無也可以
  94.                     LCALL       PR_CMD

  96.                     MOV                  DELAYED,#1
  97.                     LCALL       DELAY1MS
  98. ;                            LCALL uS160
  99.                     MOV                  LCD_DAT,#00001100B  ;顯示器開，無光標(biāo)
  100.                     LCALL       PR_CMD
  101.                     RET

  103. ;*******************************
  104. ;1602寫數(shù)據(jù)，數(shù)據(jù)存在LCD_DAT
  105. ;*******************************
  106. PR_DATA:
  107.                     SETB         LCD_RS          ;RS高 數(shù)據(jù)
  108.                     CLR           LCD_RW          ;RW低 寫
  109.                     MOV                  LCD_DATA,LCD_DAT
  110.                     
  111.                     SETB         LCD_EN          ;先置高           
  112.                    nop           ;延時
  113.                     CLR           LCD_EN           ;產(chǎn)生下降沿 執(zhí)行
  114.                     lcall   us40
  115.                     RET

  117. ;********************************
  118. ;1602寫命令，命令存在LCD_DAT
  119. ;*******************************  
  120. PR_CMD:
  121.                     CLR           LCD_RS
  122.                     CLR           LCD_RW           
  123.                     MOV                  LCD_DATA,LCD_DAT
  124.                     
  125.                  SETB         LCD_EN          ;先置高
  126.                     NOP
  127.                     CLR           LCD_EN
  128.                     lcall   uS40
  129.                     RET



  133. ;;*****************************************
  134. ;延時，延時時間＝1毫秒*次數(shù)   次數(shù)在DELAYED
  135. ;*****************************************               
  136. DELAY1MS:         ;6.000MHz 1ms
  137.      mov R7,#6
  138. D_1:mov  R6,#200
  139. D_2: djnzR6,D_2
  140.     djnz R7,D_1
  141.     djnz DELAYED,DELAY1MS
  142.     ret  
  143. ;***********
  144. ;160uS延時
  145. ;***********
  146. uS160:
  147.         mov 42H,#192
  148. us160_a:   
  149.         djnz 42h,us160_a
  150. ret
  151. ;***********
  152. ;40uS延時
  153. ;***********
  154. uS40:
  155.         mov 42H,#192
  156. us40_a:   
  157.         djnz 42h,us40_a
  158. ret

  160. END
復(fù)制代碼






歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1