標(biāo)題: 電壓檢測程序 [打印本頁]
作者: daniu    時(shí)間: 2014-12-26 23:28
標(biāo)題: 電壓檢測程序
  1.           LCD_X  EQU   23H        ;LCD 地址變量（決定文字的在LCD上的顯示位置）
  2.           FSJCQ  EQU   33H        ;TMOD工作方式暫存寄存器
  3.           BJZC   EQU   34H        ;需要比較數(shù)據(jù)暫存寄存器，用于報(bào)警顯示
  4.           BJWX   EQU   35H        ;超標(biāo)設(shè)定值暫存寄存器
  5.           BJJG   EQU   36H        ;偏高設(shè)定值暫存寄存器
  6.           JJCQ   EQU   37H        ;酒精顯示0%暫存寄存器
  7.           YYBZ   EQU   38H        ;語音播放標(biāo)志
  8.           DJSJCQ EQU   39H        ;10S倒計(jì)時(shí)寄存器
  9.           JJCYCS EQU   3AH        ;酒精檢測采樣次數(shù)寄存器
  10.           SHZZ2  EQU   3BH        ;數(shù)據(jù)中轉(zhuǎn)寄存器

  12.           XSYSSJ  DATA   5        ;正常時(shí)顯示延時(shí)時(shí)間
  13.           YWBJCS  EQU   5        ;缺油報(bào)警次數(shù)
  14.           WXBJZ1  EQU   100       ;有害氣體危險(xiǎn)報(bào)警設(shè)定值200PPM
  15.                                   ;實(shí)際設(shè)定值=200（顯示設(shè)定值）/2（修正倍率）
  16.           JGBJZ1  EQU   60        ;有害氣體警告報(bào)警設(shè)定值120PPM
  17.                                   ;實(shí)際設(shè)定值=120（顯示設(shè)定值）/2（修正倍率）
  18.           WXBJZ2  EQU   50        ;酒精危險(xiǎn)報(bào)警設(shè)定值0.05% BAC
  19.                                   ;實(shí)際設(shè)定值=0.05%（顯示設(shè)定值）*1000（顯示位修正）/1（修正倍率）
  20.           JGBJZ2  EQU   20        ;酒精警告報(bào)警設(shè)定值0.02% BAC
  21.                                   ;實(shí)際設(shè)定值=0.02%（顯示設(shè)定值）*1000（顯示位修正）/1（修正倍率）
  22.           XIUZ1   EQU   10        ;有害氣體濃度顯示數(shù)據(jù)修正值，設(shè)置大時(shí)則顯示數(shù)值小，反之顯示大
  23.           XIUZ2   EQU   34        ;酒精濃度顯示數(shù)據(jù)修正值，設(shè)置大時(shí)則顯示數(shù)值小，反之顯示大

  25. ;-----------------------------------------------------------
  26.           LCD_RS    EQU   P4.0    ;LCD 數(shù)據(jù)/命令選擇端
  27.           LCD_RW    EQU   P4.1    ;LCD 讀/寫選擇端
  28.           LCD_EN    EQU   P4.2    ;LCD 使能信號
  29.           LCD_BG    EQU   P4.3    ;LCD 背光控制端
  30.           LCD_SJ    EQU   P0      ;LCD 數(shù)據(jù)

  32.           BITE      EQU   9       ;串口發(fā)送9位數(shù)據(jù)
  33.           FSSZ      EQU   40H     ;主機(jī)發(fā)送的數(shù)據(jù)塊首址
  34.           JSSZ      EQU   50H     ;主機(jī)接收的數(shù)據(jù)塊首址

  36.           YY_DAT    DATA  29H     ;語音段地址存放單元
  37.           YYRST     EQU   P3.3    ;語音模塊復(fù)位信號引腳
  38.           BUSY      EQU   P1.0    ;語音忙控制端，0為正在播放1為沒有播放空閑時(shí)
  39.           YYSDA     EQU   P1.1    ;語音模塊數(shù)據(jù)線引腳

  41. ;===========================================================
  42.           ORG  0000H
  43.           AJMP  MAIN

  45.           ORG  0100H

  47. ;=========================================
  48. ;以下為主程序
  49. ;=========================================
  50. ;以下為油位顯示和報(bào)警程序
  51. MAIN:     MOV  SP,#60H
  52.           CLR  LCD_BG         ;打開LCD背光
  53.           LCALL  SET_LCD      ;初始化 LCD
  54.           CLR A
  55.           MOV  R0,#20H        ;將20H-7FH 單元清零
  56.           MOV  R1,#63
  57. CLEAR:    MOV  @R0,A
  58.           INC  R0
  59.           DJNZ  R1,CLEAR

  61.           MOV A,#5
  62.           MOV DPTR,#1000H     ;查看語音報(bào)警次數(shù)
  63.           MOVX @DPTR,A

  65.           ;MOV 08H,#5

  67. YWJCCX:   LCALL MENU_7        ;顯示菜單1

  69. FFFF:     LCALL YWJC          ;調(diào)用油位檢測程序
  70.           LCALL DYXZ          ;調(diào)用電瓶電壓檢測程序
  71.           LCALL DELAY3
  72.           LCALL DELAY3
  73.           SJMP FFFF

  75. ;***************************************************
  76. ;以下為子程序
  77. ;==============================================
  78. ;以下為LCD顯示有害氣體程序
  79. ;72H-70H 分別存放百位、十位、個(gè)位的數(shù)據(jù)
  80. ;==============================================
  81. CONV400:  MOV  A,73H         ;加載百位數(shù)據(jù)
  82.           MOV  LCD_X,#0      ;設(shè)置顯示位置
  83.           CJNE A,#00H,CONV410
  84.           MOV  A,#" "        ;百位數(shù)等于0顯示空格
  85.           MOV  B,LCD_X
  86.           CALL  LCDP2
  87.           JMP  CONV420

  89. CONV410:  CALL  SHOW_DIG2    ;顯示數(shù)據(jù)

  91. CONV420:  INC  LCD_X         ;調(diào)整顯示地址
  92.           MOV  A,72H         ;十位
  93.           CALL  SHOW_DIG2

  95.           INC  LCD_X         ;調(diào)整顯示地址
  96.           MOV  A,#'.'
  97.           MOV  B,LCD_X
  98.           CALL  LCDP2

  100.           INC  LCD_X         ;調(diào)整顯示地址
  101.           MOV  A,71H         ;十位
  102.           CALL  SHOW_DIG2

  104.           RET
  105. ;=========================================
  106. ;LCD 顯示菜單1
  107. ;=========================================
  108. MENU_7:   MOV  DPTR,#M_OK31  ;指針指到顯示信息區(qū)
  109.           MOV  A,#1          ;顯示在第一行
  110.           CALL  LCD_PRINT
  111.           MOV  DPTR,#M_OK32  ;指針指到顯示信息區(qū)
  112.           MOV  A,#2          ;顯示在第二行
  113.           CALL  LCD_PRINT
  114.           MOV  DPTR,#M_OK33  ;指針指到顯示信息區(qū)
  115.           MOV  A,#3          ;顯示在第二行
  116.           CALL  LCD_PRINT
  117.           MOV  DPTR,#M_OK34  ;指針指到顯示信息區(qū)
  118.           MOV  A,#4          ;顯示在第二行
  119.           CALL  LCD_PRINT
  120.           RET
  121. M_OK31:   DB"油量：          ",0
  122. M_OK32:   DB"        升      ",0
  123. M_OK33:   DB"電瓶電壓：      ",0
  124. M_OK34:   DB"        V       ",0


  127. ;--------------------------------------------------------------------------
  128. ;以下為油位檢測和報(bào)警顯示程序
  129. ;--------------------------------------------------------------------------
  130. YWJC:     MOV R2,#0AH         ;與10號從機(jī)串口通信，多功能板地址為0AH
  131.           MOV R3,#01H         ;主機(jī)要求從機(jī)發(fā)送數(shù)據(jù)塊
  132.           LCALL COM           ;主機(jī)與多功能檢測板串口通信，要求其發(fā)送9個(gè)字節(jié)數(shù)據(jù)塊

  134.           MOV A,JSSZ+3        ;取出傳感器檢測到的電壓讀數(shù)（原始數(shù)據(jù)，16進(jìn)制）
  135.           MOV B,#2            ;顯示修正倍率，原始數(shù)*倍率=LCD顯示值
  136.           LCALL HEX2BCD1      ;調(diào)用數(shù)值轉(zhuǎn)換程序
  137.           MOV YYBZ,#JSSZ+3    ;設(shè)標(biāo)志
  138.           MOV  DPTR,#BJ61     ;顯示油位過低
  139.           LCALL BTT5          ;顯示清屏
  140.           LCALL CONV400       ;調(diào)用LCD顯示程序
  141.           LCALL YWBJ          ;調(diào)用報(bào)警比較程序
  142.           RET

  144. YWBJ:     MOV A,JSSZ+3        ;取出檢測到的電壓讀數(shù)（原始數(shù)據(jù)，16進(jìn)制）
  145.           SUBB A,#19H         ;比較，查看是否是低油位
  146.           JNC BTT6            ;油位沒有過低直接返回

  148.           MOV DPTR,#1000H     ;查看語音報(bào)警次數(shù)
  149.           MOVX A,@DPTR
  150.           JZ YWBJ1            ;等于0FF說明首次打開此段語音
  151.           DEC A               ;沒有播放完允許再播放
  152.           MOV DPTR,#1000H     ;查看語音報(bào)警次數(shù)
  153.           MOVX @DPTR,A

  155.           ;MOV A,08H     ;查看語音報(bào)警次數(shù)
  156.           ;JZ YWBJ1   ;等于0FF說明首次打開此段語音
  157.           ;DEC A               ;沒有播放完允許再播放
  158.           ;MOV 08H,A     ;查看語音報(bào)警次數(shù)

  160.           JNB BUSY,$          ;如果語言正在播放，則等待
  161.           MOV YY_DAT,#38      ;報(bào)出“油位過低請加油”
  162.           LCALL YUYIN         ;開始語音播放

  164. YWBJ1:    LCALL DELAY3        ;延時(shí)
  165.           MOV  DPTR,#BJ60     ;顯示油位過低
  166. BTT5:     MOV  A,#90H         ;設(shè)置 LCD 顯示的地址（第四行）
  167.           CALL  WCOM          ;寫入指令
  168. BLC:      CLR  A              ;填入字符
  169.           MOVC  A,@A+DPTR     ;由信息區(qū)取出字符
  170.           CJNE  A,#0,BLD      ;判斷是否為結(jié)束碼
  171. BTT6:     RET
  172. BLD:      CALL  WDATA         ;寫入數(shù)據(jù)
  173.           INC  DPTR           ;指針加1
  174.           JMP  BLC            ;繼續(xù)填入字符

  176. BJ60:     DB "低油位，請加油  ",0
  177. BJ61:     DB "        升      ",0

  179. ;--------------------------------------------------------------------------
  180. ;以下為電瓶電壓檢測和報(bào)警顯示程序
  181. ;--------------------------------------------------------------------------
  182. DYXZ:     MOV R2,#0AH         ;與10號從機(jī)串口通信，多功能板地址為0AH
  183.           MOV R3,#01H         ;主機(jī)要求從機(jī)發(fā)送數(shù)據(jù)塊
  184.           LCALL COM           ;主機(jī)與多功能檢測板串口通信，要求其發(fā)送9個(gè)字節(jié)數(shù)據(jù)塊
  185. ;電壓比較程序
  186.           MOV A,JSSZ+5        ;取出檢測到的電壓讀數(shù)（原始數(shù)據(jù)，16進(jìn)制）
  187.           SUBB A,#7AH         ;比較，查看電壓是否高于8V
  188.           JC BTT1             ;電壓高于8V小于15.5V顯示電壓值，超過不顯示只報(bào)警
  189.           MOV R1,A            ;送暫存器
  190.           MOV A,JSSZ+5
  191.           SUBB A,#0C2H        ;超過15.5V報(bào)警
  192.           JC BTT2
  193. ;電壓過高
  194.           JNB BUSY,$          ;如果語言正在播放，則等待
  195.           MOV YY_DAT,#20      ;報(bào)出“電瓶電壓過高，請檢查”
  196.           LCALL YUYIN         ;開始語音播放
  197.           MOV  DPTR,#BJ50     ;超標(biāo)顯示的內(nèi)容
  198.           LCALL DYBJXS        ;超過15.5V報(bào)警顯示電壓過高
  199.           SJMP BTT3

  201. ;電壓正常顯示電壓值
  202. BTT2:     MOV  DPTR,#BJ52     ;顯示清屏
  203.           LCALL DYBJXS
  204.           MOV A,R1
  205.           MOV  DPTR,#DAB8     ;電壓值修正（實(shí)際電壓與檢測到的數(shù)值成非線性）
  206.           MOVC  A,@A+DPTR
  207.           MOV B,#100          ;把十進(jìn)制數(shù)值分離出來
  208.           DIV AB
  209.           MOV 73H,A           ;十位
  210.           MOV A,B
  211.           MOV B,#10
  212.           DIV AB
  213.           MOV 72H,A           ;個(gè)位
  214.           MOV 71H,B           ;小數(shù)點(diǎn)后1位
  215.           MOV YYBZ,#JSSZ+5    ;設(shè)標(biāo)志
  216.           LCALL CONV400       ;電壓值顯示
  217.           SJMP BTT3           ;返回主程序
  218. ;電壓過低
  219. BTT1:     JNB BUSY,$          ;如果語言正在播放，則等待
  220.           MOV YY_DAT,#19      ;報(bào)出“電瓶電壓過低，請檢查”
  221.           LCALL YUYIN         ;開始語音播放
  222.           MOV  DPTR,#BJ51     ;未達(dá)到8V報(bào)警電壓過低
  223.           LCALL DYBJXS        ;調(diào)用報(bào)警顯示程序
  224. BTT3:     RET


  227. DYBJXS:   MOV  A,#98H          ;設(shè)置 LCD 顯示的地址（第四行）
  228.           CALL  WCOM           ;寫入指令
  229. BLA:      CLR  A               ;填入字符
  230.           MOVC  A,@A+DPTR      ;由信息區(qū)取出字符
  231.           CJNE  A,#0,BLB       ;判斷是否為結(jié)束碼
  232.           RET
  233. BLB:      CALL  WDATA          ;寫入數(shù)據(jù)
  234.           INC  DPTR            ;指針加1
  235.           JMP  BLA             ;繼續(xù)填入字符

  237. BJ50:     DB "電壓過高，請檢查",0
  238. BJ51:     DB "電壓過低，請檢查",0
  239. BJ52:     DB"        V       ",0


  242. DAB8:                          ;電壓值修正
  243. DB  80,80,81,82,83,84,85,85,
  244. DB  86,87,88,89,90,90,91,91,
  245. DB  92,92,93,93,94,94,95,95,
  246. DB  96,97,98,98,99,100,100,101,
  247. DB  102,103,104,105,105,106,107,108,
  248. DB  109,110,110,111,112,113,114,115,
  249. DB  116,117,118,119,120,121,122,123,
  250. DB  124,125,126,128,130,132,134,135,
  251. DB  137,139,140,142,144,145,148,150,
  252. DB  153,155,158,160,163,165,170,173,
  253. DB  175,178,180,185,190,195,200,205,
  254. DB  0,





  260. ;=========================================
  261. ;以下為兩個(gè)單字節(jié)十六進(jìn)制相乘
  262. ;入口：A*B
  263. ;出口：16位低字節(jié)放A中，高字節(jié)放B中
  264. ;=========================================
  265. HEX2BCD1: MUL AB
  266.           MOV R6,B
  267.           MOV R7,A
  268.           MOV JJCQ,A        ;為顯示0%作準(zhǔn)備
  269. ;=========================================
  270. ;以下為雙字節(jié)十六進(jìn)制整數(shù)轉(zhuǎn)換成雙字節(jié)BCD碼整數(shù)
  271. ;入口條件：待轉(zhuǎn)換的雙字節(jié)十六進(jìn)制整數(shù)在R6、R7中。
  272. ;出口信息：轉(zhuǎn)換后的三字節(jié)BCD碼整數(shù)在R3、R4、R5中。
  273. ;影響資源：PSW、A、R2～R7，堆棧需求：２字節(jié)
  274. ;=========================================
  275.           CLR A             ;BCD碼初始化
  276.           MOV R3,A
  277.           MOV R4,A
  278.           MOV R5,A
  279.           MOV R2,#10H       ;轉(zhuǎn)換雙字節(jié)十六進(jìn)制整數(shù)
  280. HB3:      MOV A,R7          ;從高端移出待轉(zhuǎn)換數(shù)的一位到CY中
  281.           RLC A
  282.           MOV R7,A
  283.           MOV A,R6
  284.           RLC A
  285.           MOV R6,A
  286.           MOV A,R5          ;BCD碼帶進(jìn)位自身相加，相當(dāng)于乘2
  287.           ADDC A,R5
  288.           DA A              ;十進(jìn)制調(diào)整
  289.           MOV R5,A
  290.           MOV A,R4
  291.           ADDC A,R4
  292.           DA A
  293.           MOV R4,A
  294.           MOV A,R3
  295.           ADDC A,R3
  296.           MOV R3,A          ;雙字節(jié)十六進(jìn)制數(shù)的萬位數(shù)不超過6，不用調(diào)整
  297.           DJNZ R2,HB3       ;處理完16bit

  299. ;=========================================
  300. ;以下為把BCD碼提取出并送顯示寄存器70H～73H
  301. ;入口：;三字節(jié)BCD碼整數(shù)在R3（高位為十萬低位為萬）、
  302. ;R4（高位為千低位為百）、R5（高位為十低位為個(gè)）中。
  303. ;出口：73H-70H（舍去十萬、萬位）
  304. ;=========================================
  305.           MOV A,R4
  306.           ANL A,#00001111B
  307.           MOV 73H,A
  308.           MOV A,R5
  309.           ANL A,#11110000B
  310.           SWAP A
  311.           MOV 72H,A
  312.           MOV A,R5
  313.           ANL A,#00001111B
  314.           MOV 71H,A
  315.           MOV 70H,#0
  316.           RET

  318. ;=========================================
  319. ;以下為主機(jī)串行通信程序
  320. ;占用資源：R0～R4,A、40H、50H
  321. ;=========================================
  322. COM:   MOV A,TMOD           ;設(shè)置T1工作方式為方式2、T0工作方式保持不變
  323.        MOV FSJCQ,A
  324.        ORL A,#00101111B
  325.        MOV TMOD,A
  326.        MOV TH1,#0FDH        ;11.0592MHz 晶振,波特率=9600，時(shí)長0.6695
  327.        MOV TL1,#0FDH
  328.        MOV SCON,#0D8H       ;置串行模式3，SM2=1,允許接收
  329.        SETB TR1             ;啟動T1
  330.        LCALL COM1           ;調(diào)用一線發(fā)碼子程序
  331.        MOV TMOD,FSJCQ       ;恢復(fù)T1、T0原先的工作方式
  332.        RET

  334. COM1:   MOV A,R2            ;發(fā)送地址幀
  335.         MOV SBUF,A
  336.         JNB TI,$
  337.         CLR TI
  338.         JNB RI,$            ;等待從機(jī)應(yīng)答
  339.         CLR RI
  340.         MOV A,SBUF
  341.         XRL A,R2
  342.         JNZ MS104           ;判應(yīng)答地址是否相符
  343.         CLR TB8             ;地址符合，準(zhǔn)備發(fā)送命令
  344.         MOV SBUF,R3         ;發(fā)送發(fā)送或接收數(shù)據(jù)命令
  345.         JNB TI,$
  346.         CLR TI
  347.         JNB RI,$            ;等待從機(jī)應(yīng)答
  348.         CLR RI
  349.         MOV A,SBUF          ;取應(yīng)答信息
  350.         JNB ACC.7,MS102     ;判斷是否出錯(cuò)
  351. MS101:  SETB TB8
  352.         MOV SBUF,#0FFH      ;不相符重新聯(lián)絡(luò)
  353.         JNB TI,$
  354.         CLR TI
  355.         SJMP COM1           ;轉(zhuǎn)重發(fā)地址

  357. MS102:  CJNE R3,#00H,MS103  ;判是否要求從機(jī)接收數(shù)據(jù)
  358.         JNB ACC.0,MS101     ;從機(jī)接收數(shù)據(jù)準(zhǔn)備就緒否？
  359.         MOV R0,#FSSZ        ;主機(jī)發(fā)送的數(shù)據(jù)塊首址
  360.         MOV R4,#BITE        ;設(shè)數(shù)據(jù)塊長度(9字節(jié))
  361. LPTX:   MOV SBUF,@R0        ;主機(jī)發(fā)送數(shù)據(jù)塊
  362.         JNB TI,$            ;等待發(fā)送完1幀
  363.         CLR TI
  364.         INC R0              ;修改地址指針
  365.         DJNZ R4,LPTX        ;判數(shù)據(jù)塊是否傳完
  366.         SJMP MS104          ;返回主程序

  368. MS103:  JNB ACC.1,MS101     ;從機(jī)發(fā)送數(shù)據(jù)準(zhǔn)備就緒否？
  369.         MOV R1,#JSSZ        ;主機(jī)接收的數(shù)據(jù)塊首址
  370.         MOV R4,#BITE        ;設(shè)數(shù)據(jù)塊長度(9字節(jié))
  371. LPRX:   JNB RI,LPRX         ;等待接收完1幀
  372.         CLR RI
  373.         MOV A,SBUF          ;取出接收到的字符
  374.         MOV @R1,A
  375.         INC R1
  376.         DJNZ R4,LPRX        ;未接收完則繼續(xù)

  378. MS104:  CLR TR1             ;關(guān)閉T1
  379.         RET

  381. ;=============================================
  382. ;在LCD的第二行顯示數(shù)據(jù)字符
  383. ;A=ASCII 數(shù)據(jù), B=位置變量
  384. ;==============================================
  385. LCDP2:    PUSH  ACC           ;在LCD的第二行顯示字符
  386.           MOV  A,B            ;設(shè)置顯示地址
  387.           MOV R0,YYBZ
  388.           CJNE R0,#JSSZ+3,LCDP3
  389.           ADD  A,#90H         ;設(shè)置LCD的第二行地址90
  390.           SJMP LCDP4
  391. LCDP3:    CJNE R0,#JSSZ+5,LCDP5
  392.           ADD  A,#98H         ;設(shè)置LCD的第四行地址98
  393. LCDP4:    CALL  WCOM          ;寫入命令
  394. LCDP5:    POP  ACC            ;由堆棧取出A
  395.           CALL  WDATA         ;寫入數(shù)據(jù)
  396.           RET
  397. ;-------------------------------------------------------
  398. SHOW_DIG2:                   ;在 LCD 的第二行顯示數(shù)字
  399.           ADD  A,#30H        ;加30H，轉(zhuǎn)換為ASCII碼
  400.           MOV  B,LCD_X       ;確定顯示位置
  401.           CALL  LCDP2        ;送顯示
  402.           RET

  404. ;=================================================
  405. ;對 LCD 做初始化設(shè)置
  406. ;=================================================
  407. SET_LCD:  MOV A,#34H      ;34H--擴(kuò)充指令操作
  408.           CALL  WCOM         ;寫入命令
  409.    MOV A,#30H      ;30H--基本指令操作
  410.           CALL  WCOM         ;寫入命令
  411.    MOV A,#01H      ;清除顯示
  412.           CALL  WCOM         ;寫入命令
  413.           MOV A,#06H      ;指定在資料寫入或讀取時(shí)，光標(biāo)的移動方向
  414.           CALL  WCOM         ;DDRAM 的地址計(jì)數(shù)器(AC)加1
  415.    MOV A,#0CH      ;開顯示,關(guān)光標(biāo),不閃爍
  416.           CALL  WCOM         ;寫入命令
  417.           RET

  419. ;===============================================
  420. ;命令寫入子程序
  421. ;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
  422. ;以8位控制方式將命令寫至LCD
  423. ;===============================================
  424. WCOM:    LCALL CHK_BUSY       ;寫入指令
  425.   CLR LCD_RS
  426.   CLR LCD_RW
  427.   MOV LCD_SJ,A
  428.   SETB LCD_EN
  429.   NOP
  430.   NOP
  431.   CLR LCD_EN
  432.   RET
  433. ;===============================================
  434. ;數(shù)據(jù)寫入子程序
  435. ;RS=H,RW=L,D0-D7=指令碼，E=高脈沖
  436. ;以8位控制方式將數(shù)據(jù)寫至LCD
  437. ;===============================================
  438. WDATA:    MOV  LCD_SJ,A       ;寫入數(shù)據(jù)
  439.           SETB  LCD_RS
  440.           CLR  LCD_RW
  441.           SETB  LCD_EN
  442.           CALL  DE
  443.           CLR  LCD_EN
  444.           CALL  DE
  445.           RET
  446. ;===============================================
  447. ;測LCD忙碌子程序
  448. ;RS=0,RW=1,E=H,D0-D7=狀態(tài)字
  449. ;===============================================
  450. CHK_BUSY: MOV LCD_SJ,#0FFH   ;測忙碌子程序
  451.    CLR LCD_RS
  452.    SETB LCD_RW
  453.    SETB LCD_EN
  454.    JB LCD_SJ.7,$
  455.    CLR LCD_EN
  456.    RET

  458. ;==================================================
  459. ;在LCD的顯示字符串
  460. ;DPTR = 放字符串的地址
  461. ;==================================================
  462. LCD_PRINT:CJNE  A,#1,LINE2  ;判斷是否為第一行
  463. LINE1:    MOV  A,#80H       ;設(shè)置 LCD 的第一行地址
  464.           CALL  WCOM        ;寫入命令
  465.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  466.           MOV  A,#80H       ;設(shè)置 LCD 的第一行地址
  467.           CALL  WCOM        ;寫入命令
  468.           JMP  FILL

  470. LINE2:    CJNE  A,#2,LINE3  ;判斷是否為第二行
  471.           MOV  A,#90H       ;設(shè)置 LCD 的第二行地址
  472.           CALL  WCOM        ;寫入命令
  473.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  474.           MOV  A,#90H       ;設(shè)置 LCD 的第二行地址
  475.           CALL  WCOM
  476.           JMP  FILL

  478. LINE3:    CJNE  A,#3,LINE4  ;判斷是否為第三行
  479.           MOV  A,#88H       ;設(shè)置 LCD 的第三行地址
  480.           CALL  WCOM        ;寫入命令
  481.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  482.           MOV  A,#88H       ;設(shè)置 LCD 的第三行地址
  483.           CALL  WCOM
  484.           JMP  FILL

  486. LINE4:    MOV  A,#98H       ;設(shè)置 LCD 的第四行地址
  487.           CALL  WCOM        ;寫入命令
  488.           CALL  CLR_LINE    ;清除該行字符數(shù)據(jù)
  489.           MOV  A,#98H       ;設(shè)置 LCD 的第四行地址
  490.           CALL  WCOM

  492. FILL:     CLR  A            ;填入字符
  493.           MOVC  A,@A+DPTR   ;由信息區(qū)取出字符
  494.           CJNE  A,#0,LC1    ;判斷是否為結(jié)束碼
  495.           RET

  497. LC1:      CALL  WDATA       ;寫入數(shù)據(jù)
  498.           INC  DPTR         ;指針加1
  499.           JMP  FILL         ;繼續(xù)填入字符
  500. ;===============================================
  501. ;清除一行 LCD 的字符
  502. ;輸入一行空格，來替代原顯示字符
  503. ;===============================================
  504. CLR_LINE: MOV  R0,#16       ;清除該行 LCD 的字符
  505. CL1:      MOV  A,#' '
  506.           CALL  WDATA
  507.           DJNZ  R0,CL1
  508.           RET
  509. ;**********************************************************
  510. ;延時(shí)子程序
  511. ;**********************************************************
  512. DE:      MOV  R7,#229        ;延時(shí) 500 微秒,此條2個(gè)機(jī)器周期
  513.          DJNZ  R7,$
  514.          RET    ;此條2個(gè)機(jī)器周期，總延時(shí)（229*2+2+2）*(12/11.0592)≈500uS

  516. DELAY:   MOV  R5,#20         ;延時(shí)200MS
  517. DELAY1:  MOV  R6,#96         ;100
  518. DL1:     MOV  R7,#96         ;100
  519.          DJNZ  R7,$
  520.          DJNZ  R6,DL1
  521.          DJNZ  R5,DELAY1     ;96*2*48*(12/11.0592)+2*(12/11.0592)≈10000uS=10mS
  522.          RET

  524. DELAY2:  MOV  R6,#10         ;延時(shí)5MS
  525. DL2:     MOV  R7,#229        ;100微秒
  526.          DJNZ  R7,$
  527.          DJNZ  R6,DL2
  528.          DJNZ  R5,DELAY2
  529.          RET

  531. DELAY3:  MOV  R5,#10         ;延時(shí)200MS
  532. DELA:    MOV  R6,#255
  533. DL3:     MOV  R7,#255
  534.          DJNZ  R7,$
  535.          DJNZ  R6,DL3
  536.          DJNZ  R5,DELA
  537.          RET
  538. ;**********************************************************
  539. ;語音驅(qū)動和播放程序
  540. ;**********************************************************
  541. ;50H為語音段地址暫存器，1到210段，實(shí)際用到40
  542. ;50H為E0H～E7H時(shí)分別代表自低往高的8級音量
  543. ;在語音播放過程中發(fā)送F2H至50H可循環(huán)播放當(dāng)前地址語音
  544. ;發(fā)送FEH至50H停止播放語音
  545. ;****************************************************
  546. YUYIN: MOV A,TMOD          ;設(shè)置T1工作方式為方式1、T0工作方式保持不變
  547.        MOV FSJCQ,A
  548.        ORL A,#00011111B
  549.        MOV TMOD,A
  550.        MOV R6,#08H         ;發(fā)碼8位循環(huán)數(shù)據(jù)
  551.        LCALL ONE_LINE      ;調(diào)用一線發(fā)碼子程序
  552.        MOV TMOD,FSJCQ          ;恢復(fù)T1、T0原先的工作方式
  553.        RET

  555. ONE_LINE:                  ;////一線發(fā)碼子程序
  556.        SETB YYRST          ;復(fù)位
  557.        MOV R7,#2           ;延時(shí)2MS
  558.        LCALL DELAY1MS
  559.        CLR YYRST           ;延時(shí)使系統(tǒng)穩(wěn)定
  560.        MOV R7,#6           ;延時(shí)6MS
  561.        LCALL DELAY1MS
  562.        CLR YYSDA           ;喚醒語音芯片
  563.        MOV R7,#17          ;延時(shí)17MS
  564.        LCALL DELAY1MS
  565.        MOV A,YY_DAT

  567. LP1:   SETB YYSDA
  568.        RRC A               ;分辨50H內(nèi)的數(shù)據(jù)各位是高電平還是低電平
  569.        JNC DIDIANPIN       ;高電平用高:低=2:1的脈寬表示
  570.        LCALL DELAY200US
  571.        LCALL DELAY200US
  572.        LCALL DELAY200US
  573.        CLR YYSDA
  574.        LCALL DELAY200US
  575. LP2:   DJNZ R6,LP1         ;查看數(shù)據(jù)是否發(fā)完，未發(fā)完繼續(xù)發(fā)
  576.        MOV R6,#08H
  577.        SETB YYSDA
  578.        RET

  580. DIDIANPIN:                 ;低電平用高:低=1:2的脈寬表示
  581.        LCALL DELAY200US
  582.        CLR YYSDA
  583.        LCALL DELAY200US
  584.        LCALL DELAY200US
  585.        LCALL DELAY200US
  586.        SJMP LP2

  588. ;以下為延時(shí)子程序
  589. DELAY200US:                ;延時(shí)200US子程序，晶振11.0592MHz，方式1
  590.        MOV  TH1,#0FFH
  591.        MOV  TL1,#47H
  592.        SETB TR1
  593. LOP1:  JBC  TF1,NEXT1
  594.        SJMP LOP1
  595. NEXT1: CLR TR1
  596.        RET

  598. DELAY1MS:MOV  TH1,#0FCH    ;延時(shí)1ms子程序
  599.        MOV  TL1,#66H
  600.        SETB TR1
  601. LOP2:  JBC  TF1,NEXT2
  602.        SJMP LOP2
  603. NEXT2: DJNZ R7,DELAY1MS
  604.        CLR TR1
  605.        RET


  608.          END
復(fù)制代碼






歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1