標題: 最簡單的單片機數(shù)字鐘匯編程序+電路圖 [打印本頁]
作者: daniu    時間: 2014-12-27 17:09
標題: 最簡單的單片機數(shù)字鐘匯編程序+電路圖

  1. ;===============================================================
  2. ;程序編寫人：張培、蘭建文   
  3. ;編寫地點：51hei單片機培訓機構(gòu)
  4. ;時間：2009年6月19日下午  星期四
  5. ;功能：本程序?qū)崿F(xiàn)工業(yè)控制數(shù)字鐘功能。
  6. ;P3口實現(xiàn)對數(shù)碼管的片選功能
  7. ;==========================開始初始化===========================
  8. PIANXUAN      EQU    P3
  9. SHUCHU        EQU    P2
  10. MIAO          EQU    30H
  11. FEN           EQU    31H
  12. SHI           EQU    32H
  13. SHUZI    EQU    33H
  14. C_0           BIT    20H.0
  15.       ORG    0000H
  16.       JMP    START
  17.        ORG    000BH
  18.       JMP    T0_1
  19.       ORG    0030H
  20.    START:
  21.            CALL   INIT
  22.       MOV    MIAO,#00
  23.       MOV    FEN,#59
  24.       MOV    SHI,#23
  25.       MOV    DPTR,#TAB
  26.       MOV     R2,#5
  27.     MAIN:
  28.          JNB    C_0,$
  29.       CLR    C_0
  30.    LL:   CALL   DISPLAY
  31.          CALL   SHIJIAN
  32.       JMP    MAIN      
  33. ;========================時間子程序=============================
  34. ;輸入:"30H、31H、32H"
  35. ;輸出:無
  36. ;實現(xiàn)的功能：時分秒的計算。
  37. ;===============================================================
  38.       SHIJIAN:
  39.      DJNZ    R2,TIAOCHU
  40.      MOV     R2,#50
  41.       CPL     P3.6
  42.      INC     MIAO
  43.      MOV     R3,MIAO
  44.      CJNE    R3,#60,TIAOCHU
  45.      MOV     MIAO,#00
  46.      INC     FEN
  47.      MOV     R3,FEN
  48.      CJNE    R3,#60,TIAOCHU
  49.      MOV     FEN,#00
  50.      INC     SHI
  51.      MOV     R3,SHI
  52.      CJNE    R3,#24,TIAOCHU
  53.      MOV     SHI,#00
  54.    TIAOCHU:RET
  55. ;========================顯示子程序=============================
  56. ;輸入:"A"
  57. ;輸出:"P0口"
  58. ;實現(xiàn)的功能：把A的數(shù)輸出到P0口顯示,十位和個位分開顯示
  59. ;===============================================================
  60.        DISPLAY:MOV   SHUZI,MIAO
  61.            CALL  JISUAN
  62.      MOVC  A,@A+DPTR
  63.      MOV   SHUCHU,A         ;顯示十位
  64.      MOV   PIANXUAN,#10H    ;片選
  65.                CALL  DELAY
  66.      MOV   PIANXUAN,#00
  67.    
  68.      MOV   A,B              
  69.      MOVC   A,@A+DPTR
  70.        MOV   SHUCHU,A         ;顯示個位
  71.      MOV   PIANXUAN,#20H    ;片選
  72.      CALL  DELAY            ;延時
  73.      MOV   PIANXUAN,#00
  74.            
  75.      MOV   SHUZI,FEN
  76.            CALL  JISUAN         
  77.            MOVC  A,@A+DPTR
  78.      MOV   SHUCHU,A         ;顯示十位
  79.      MOV   PIANXUAN,#04H    ;片選
  80.                CALL  DELAY
  81.      MOV   PIANXUAN,#00
  82.    
  83.      MOV   A,B              
  84.      MOVC   A,@A+DPTR
  85.        MOV   SHUCHU,A         ;顯示個位
  86.      MOV   PIANXUAN,#08H    ;片選
  87.      CALL  DELAY            ;延時
  88.      MOV   PIANXUAN,#00
  89.      
  90.      MOV   SHUZI,SHI
  91.      CALL  JISUAN
  92.      MOVC  A,@A+DPTR
  93.      MOV   SHUCHU,A         ;顯示十位
  94.      MOV   PIANXUAN,#01H    ;片選
  95.                CALL  DELAY
  96.      MOV   PIANXUAN,#00
  97.      
  98.      MOV   A,B              
  99.      MOVC   A,@A+DPTR
  100.        MOV   SHUCHU,A         ;顯示個位
  101.      MOV   PIANXUAN,#02H    ;片選
  102.      CALL  DELAY            ;延時
  103.      MOV   PIANXUAN,#00
  104.                RET
  105. ;========================計算子程序=============================
  106. ;輸入:30H
  107. ;輸出:"A和B"
  108. ;實現(xiàn)的功能：把30H的數(shù)據(jù)的十位和個位分離出來
  109. ;===============================================================
  110.           JISUAN:MOV   A,SHUZI      ;數(shù)據(jù)放在A中  
  111.      MOV   B,#10        ;除數(shù)放在B中
  112.      DIV   AB           ;商放在A中，余數(shù)放在B中
  113.      RET
  114. ;====================定時中斷0服務子程序========================
  115. ;輸入:無
  116. ;輸出:無
  117. ;實現(xiàn)的功能：實現(xiàn)定時20MS，影響標中斷志位BIT
  118. ;===============================================================
  119.    T0_1:MOV    TL0,50H          ;設(shè)置定時初值
  120.         MOV    TH0,51H
  121.         SETB   C_0            ;定時標志位清0
  122.      RETI
  123. ;========================中斷設(shè)置子程序=========================
  124. ;輸入:無
  125. ;輸出:無
  126. ;實現(xiàn)的功能：初始化設(shè)置定時器，設(shè)置初值
  127. ;===============================================================
  128.             INIT:MOV    TMOD,#01H      ;定時器0工作方式1
  129.         MOV    DPTR,#65536-20000
  130.      MOV    50H,DPL
  131.      MOV    51H,DPH
  132.          MOV    TL0,50H    ;設(shè)置定時初值
  133.         MOV    TH0,51H
  134.      MOV    IE,#82H       ;開定時器中斷0
  135.      SETB   TR0        ;開定時器0
  136.      RET
  137. ;========================延時程序===============================
  138. ;輸入；無
  139. ;輸出: 無
  140. ;實現(xiàn)的功能：延時一段時間
  141. ;===============================================================
  142.           DELAY:   
  143.           MOV  R6,#80
  144.       LL7:MOV  R7,#60
  145.         DJNZ R7,$
  146.           DJNZ R6,LL7
  147.     RET
  148. ;=====================共陽查表數(shù)據(jù)==============================
  149.       TAB:DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H
  150. ;=======================程序結(jié)束================================
  151.     END
復制代碼







歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1