標題: LM032L液晶 8051 LCD Driver仿真及程序 [打印本頁]
作者: HolizeJamie    時間: 2016-3-21 09:00
標題: LM032L液晶 8051 LCD Driver仿真及程序

ISIS 7 Professional
自帶的電路仿真圖，壓縮包里面有hex文件，可以直接打開使用
  1. ; LCD Display Driver Demo.
  2. ; Timing code assumes 1.2MHz Clock

  4. ;LCD Registers addresses
  5. LCD_CMD_WR        equ         0
  6. LCD_DATA_WR        equ        1
  7. LCD_BUSY_RD        equ        2
  8. LCD_DATA_RD        equ        3

  10. ;LCD Commands
  11. LCD_CLS                equ        1
  12. LCD_HOME        equ        2
  13. LCD_SETMODE        equ        4
  14. LCD_SETVISIBLE        equ        8
  15. LCD_SHIFT        equ        16
  16. LCD_SETFUNCTION        equ        32
  17. LCD_SETCGADDR        equ        64
  18. LCD_SETDDADDR        equ        128

  20. ;Reset vector
  21.         org 0000h
  22.         jmp start


  25. ;Start of the program
  26.         org 0100h

  28. string1a:db ' !! A M A Z I N G !! '
  29.          db 0
  30. string1b:db '!! A M A Z I N G !! '
  31.          db 0
  32. string2:db ' A virtual LM032L... '
  33.         db 0

  35. string3:db ' driven by a virtual '
  36.         db 0
  37. string4:db '   8051 processor!'
  38.         db 0

  40. start:        mov A,#038h
  41.         call wrcmd

  43. loop:        mov A,#LCD_SETVISIBLE+6         ;Make the display & blink visible:
  44.         call wrcmd

  46.         mov R7,#2
  47. loop2:
  48.         mov DPTR,#string1a
  49.         call wrstr

  51.         mov DPTR,#200
  52.         call wtms

  54.         mov A,#LCD_CLS                        ;Clear screen
  55.         call wrcmd

  57.         mov DPTR,#string1b
  58.         call wrstr

  60.         mov DPTR,#200
  61.         call wtms

  63.         mov A,#LCD_CLS                        ;Clear screen
  64.         call wrcmd

  66.         djnz R7,loop2

  68.         mov DPTR,#string1a
  69.         call wrstr

  71.         mov DPTR,#400
  72.         call wtms

  74.         mov A,#LCD_SETDDADDR+64
  75.         call wrcmd

  77.         mov DPTR,#string2
  78.         call wrslow

  80.         mov DPTR,#200
  81.         call wtms

  83.         mov A,#LCD_CLS                        ;Clear screen
  84.         call wrcmd

  86.         mov DPTR,#string3
  87.         call wrslow

  89.         mov A,#LCD_SETDDADDR+64
  90.         call wrcmd

  92.         mov DPTR,#string4
  93.         call wrslow

  95.         mov A,#LCD_SETVISIBLE+7                ;Show the blink cursor as well.
  96.         call wrcmd

  98.         mov DPTR,#2000
  99.         call wtms

  101.         mov A,#LCD_CLS                        ;Clear screen
  102.         call wrcmd

  104.         jmp loop


  107. ;Sub routine to write null terminated string at DPTR in program ram.
  108. wrstr:        mov R0,#LCD_DATA_WR
  109. wrstr1:        clr A
  110.         movc A,@A+DPTR
  111.         jz wrstr2
  112.         movx @R0,A
  113.         call wtbusy
  114.         inc DPTR
  115.         push DPL
  116.         push DPH
  117.         pop DPH
  118.         pop DPL       
  119.         jmp wrstr1
  120. wrstr2:        ret

  122. ;Sub routine to write null terminated string at DPTR in program ram. Slowly
  123. wrslow:        mov R0,#LCD_DATA_WR
  124. wrslw1:        clr A
  125.         movc A,@A+DPTR
  126.         jz wrslw2
  127.         movx @R0,A
  128.         call wtbusy
  129.         inc DPTR
  130.         push DPL
  131.         push DPH
  132.         mov DPTR,#100
  133.         call wtms
  134.         pop DPH
  135.         pop DPL       
  136.         jmp wrslw1
  137. wrslw2:        ret


  140. ;Sub routine to write command:
  141. wrcmd:        mov R0,#LCD_CMD_WR
  142.         movx @R0,A
  143.         jmp wtbusy


  146. ;Sub routine to write character:
  147. wrchar:        mov R0,#LCD_DATA_WR
  148.         movx @R0,A

  150. ;Subroutine to wait for busy clear
  151. wtbusy: mov R1,#LCD_BUSY_RD
  152.         movx A,@r1
  153.         jb ACC.7,wtbusy
  154.         ret

  156. ;Wait for number of seconds in A
  157. wtsec:        push ACC
  158.         call wtms
  159.         pop ACC
  160.         dec A
  161.         jnz wtsec
  162.         ret

  164. ;Wait for number of milliseconds in DPTR
  165. wtms:   xrl DPL,#0FFh                        ;Can't do DEC DPTR, so do the loop by forming 2's complement
  166.         xrl DPH,#0FFh                        ;and incrementing instead.
  167.         inc DPTR
  168. wtms1:        mov TL0,#09Ch                        ;100 ticks before overflow = 1ms at 1.2MHz Clock
  169.         mov TH0,#0FFh       
  170.         mov TMOD,#1                        ;Timer 0 mode 1
  171.         setb TCON.4                        ;Timer 0 runs
  172. wtms2:        jnb TCON.5,wtms2       
  173.         clr TCON.4                        ;Timer 0 stops
  174.         clr TCON.5
  175.         inc DPTR
  176.         mov A,DPL
  177.         orl A,DPH
  178.         jnz wtms1
  179.         ret

  181.        
  182.         END
復制代碼


8051 LCD Driver.zip

11.57 KB, 下載次數(shù): 7, 下載積分: 黑幣 -5





歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1