標(biāo)題: 使用單片機(jī)制作的測速表 [打印本頁]
作者: 358801249    時(shí)間: 2016-6-7 14:54
標(biāo)題: 使用單片機(jī)制作的測速表
　測速是工農(nóng)業(yè)生產(chǎn)中經(jīng)常遇到的問題，學(xué)會使用單片機(jī)技術(shù)設(shè)計(jì)測速儀表具有很重要的意義。
              要測速，首先要解決是采樣的問題。在使用模擬技術(shù)制作測速表時(shí)，常用測速發(fā)電機(jī)的方法，即將測速發(fā)電機(jī)的轉(zhuǎn)軸與待測軸相連，測速發(fā)電機(jī)的電壓高低反映了轉(zhuǎn)速的高低。使用單片機(jī)進(jìn)行測速，可以使用簡單的脈沖計(jì)數(shù)法。只要轉(zhuǎn)軸每旋轉(zhuǎn)一周，產(chǎn)生一個(gè)或固定的多個(gè)脈沖，并將脈沖送入單片機(jī)中進(jìn)行計(jì)數(shù)，即可獲得轉(zhuǎn)速的信息。
         
          　　一、脈沖信號的獲得
              可以有多種方式來獲得脈沖信號，這些方法有各自的應(yīng)用場合。下面逐一進(jìn)行分析。
         
          1．霍爾傳感器
              霍爾傳感器是對磁敏感的傳感元件，常用于開關(guān)信號采集的有CS3020、CS3040等，這種傳感器是一個(gè)3端器件，外形與三極管相似，只要接上電源、地，即可工作，輸出通常是集電極開路（OC）門輸出，工作電壓范圍寬，使用非常方便。如圖1所示是CS3020的外形圖，將有字面對準(zhǔn)自己，三根引腳從左向右分別是Vcc，地，輸出。
           
            圖1 CS3020外形圖
          　　使用霍爾傳感器獲得脈沖信號，其機(jī)械結(jié)構(gòu)也可以做得較為簡單，只要在轉(zhuǎn)軸的圓周上粘上一粒磁鋼，讓霍爾開關(guān)靠近磁鋼，就有信號輸出，轉(zhuǎn)軸旋轉(zhuǎn)時(shí)，就會不斷地產(chǎn)生脈沖信號輸出。如果在圓周上粘上多粒磁鋼，可以實(shí)現(xiàn)旋轉(zhuǎn)一周，獲得多個(gè)脈沖輸出。在粘磁鋼時(shí)要注意，霍爾傳感器對磁場方向敏感，粘之前可以先手動接近一下傳感器，如果沒有信號輸出，可以換一個(gè)方向再試。
              這種傳感器不怕灰塵、油污，在工業(yè)現(xiàn)場應(yīng)用廣泛。
         
          2．光電傳感器
              光電傳感器是應(yīng)用非常廣泛的一種器件，有各種各樣的形式，如透射式、反射式等，基本的原理就是當(dāng)發(fā)射管光照射到接收管時(shí)，接收管導(dǎo)通，反之關(guān)斷。以透射式為例，如圖2所示，當(dāng)不透光的物體擋住發(fā)射與接收之間的間隙時(shí)，開關(guān)管關(guān)斷，否則打開。為此，可以制作一個(gè)遮光葉片如圖3所示，安裝在轉(zhuǎn)軸上，當(dāng)扇葉經(jīng)過時(shí)，產(chǎn)生脈沖信號。當(dāng)葉片數(shù)較多時(shí)，旋轉(zhuǎn)一周可以獲得多個(gè)脈沖信號。
           
          圖2光電傳感器的原理圖
           
          圖3遮光葉片
         
          3．光電編碼器
              光電編碼器的工作原理與光電傳感器一樣，不過它已將光電傳感器、電子電路、碼盤等做成一個(gè)整體，只要用連軸器將光電傳感器的軸與轉(zhuǎn)軸相連，就能獲得多種輸出信號。它廣泛應(yīng)用于數(shù)控機(jī)床、回轉(zhuǎn)臺、伺服傳動、機(jī)器人、雷達(dá)、軍事目標(biāo)測定等需要檢測角度的裝置和設(shè)備中。如圖4所示，是某光電編碼器的外形。
         
          圖4 成品光電編碼器
         
          　　二、硬件連接
              　測速的方法決定了測速信號的硬件連接，測速實(shí)際上就是測頻，因此，頻率測量的一些原則同樣適用于測速。
              　通常，可以用計(jì)數(shù)法、測脈寬法和等精度法來進(jìn)行測試。所謂計(jì)數(shù)法，就是給定一個(gè)閘門時(shí)間，在閘門時(shí)間內(nèi)計(jì)數(shù)輸入的脈沖個(gè)數(shù)；測脈寬法是利用待測信號的脈寬來控制計(jì)數(shù)門，對一個(gè)高精度的高頻計(jì)數(shù)信號進(jìn)行計(jì)數(shù)。由于閘門與被測信號不能同步，因此，這兩種方法都存在±1誤差的問題，第一種方法適用于信號頻率高時(shí)使用，第二種方法則在信號頻率低時(shí)使用。等精度法則對高、低頻信號都有很好的適應(yīng)性。
              這里為簡化討論，僅采用計(jì)數(shù)法來進(jìn)行測試。
              圖5所示是測速器的電路圖，由六位數(shù)碼管和測速接口組成。其中T0處接的只畫了一只CS3020組成的霍爾傳感器接線圖，如果采用光電傳感器接口也是一樣的，讀者可自行畫出接線圖。
           
          圖5測速計(jì)電路原理圖
         
          　　三、軟件編程
              測量轉(zhuǎn)速，使用霍爾傳感器，被測軸安裝有12只磁鋼，即轉(zhuǎn)軸每轉(zhuǎn)一周，產(chǎn)生12個(gè)脈沖，要求將轉(zhuǎn)速值（轉(zhuǎn)/分）顯示在數(shù)碼管上。
          程序如下：
          DISPBUF EQU 5AH  ;顯示緩沖區(qū)從5AH開始
          SecCoun EQU 59H
          SpCoun EQU 57H ;速度計(jì)時(shí)器單元57H和58H，高位在前（57H單元中）
          Count EQU 56H ;顯示時(shí)的計(jì)數(shù)器
          SpCalc bit 00h ;要求計(jì)算速度的標(biāo)志
          Hidden EQU 16 ;消隱碼
         
          ORG 0000H
          AJMP START
          ORG 1BH
          JMP TIMER1 ;定時(shí)中斷1入口
         
          ORG 30H
          START: MOV SP,#5FH ;設(shè)置堆棧
          MOV P1,#0FFH
          MOV P0,#0FFH
          MOV P2,#0FFH ;初始化，所有顯示器、LED滅
          MOV TMOD,#00010101B ;定時(shí)器T1工作于方式1，定時(shí)器0工作方式1 MOV TH1,#HIGH(65536-4000)
          MOV TL1,#LOW(65536-4000)
          SETB TR1
          SETB ET1 ;開定時(shí)器1中斷
          SETB EA
         
          LOOP: JNB SpCalc,LOOP ;如果未要求計(jì)算，轉(zhuǎn)本身循環(huán)
         
          ;標(biāo)號： ＭＵＬＤ    功能：雙字節(jié)二進(jìn)制無符號數(shù)乘法
          ;入口條件：被乘數(shù)在R2、R3中，乘數(shù)在R6、R7中。
          ;出口信息：乘積在R2、R3、R4、R5中。
          ;影響資源：PSW、A、B、R2～R7    堆棧需求：  ２字節(jié)
          MOV R2,SpCoun
          MOV R3,SpCoun+1
          MOV R6,#0
          MOV R7,#5 ;測得的數(shù)值是每秒計(jì)數(shù)值，轉(zhuǎn)為每分轉(zhuǎn)速（每一轉(zhuǎn)測12次，故乘5而非60）
          CALL MULD
          ;標(biāo)號： ＨＢ２   功能：雙字節(jié)十六進(jìn)制整數(shù)轉(zhuǎn)換成雙字節(jié)ＢＣＤ碼整數(shù)
          ;入口條件：待轉(zhuǎn)換的雙字節(jié)十六進(jìn)制整數(shù)在R6、R7中。
          ;出口信息：轉(zhuǎn)換后的三字節(jié)ＢＣＤ碼整數(shù)在R3、R4、R5中。
          ;影響資源：PSW、A、R2～R7    堆棧需求：  ２字節(jié)
          MOV A,R4
          MOV R6,A
          MOV A,R5
          MOV R7,A ;將乘得的結(jié)果送R6R準(zhǔn)備轉(zhuǎn)換，這里結(jié)果不可能超過2字節(jié)
          CALL HB2
          CBCD:
          MOV DISPBUF,R3 ;最高位
         
          MOV A,R4 ;
          ANL A,#0F0H ;去掉低4位
          SWAP A ;將高4位切換到低4位
          MOV DISPBUF+1,A
         
          MOV A,R4
          ANL A,#0FH
          MOV DISPBUF+2,A
         
          MOV A,R5
          ANL A,#0F0H
          SWAP A
          MOV DISPBUF+3,A
         
          MOV A,R5
          ANL A,#0FH
          MOV DISPBUF+4,A
         
          CLR SpCalc ;清計(jì)算標(biāo)志
          JMP LOOP
         
          ;主程序到此結(jié)束
          TIMER1: PUSH ACC;ACC入棧
          PUSH PSW ;PSW入棧
          SETB RS0 ;工作區(qū)1
          JNB TR0,SETTR0 ;如果T0未運(yùn)行，則開啟T0
          JMP GO1
          SETTR0:
          SETB TR0
          GO1:
          INC SecCoun ;秒計(jì)數(shù)器加1
          MOV A,SecCoun
          CJNE A,#251,Go2 ;如果未到1s則轉(zhuǎn)
          CLR TR0 ;1ｓ到了，則停止T0的運(yùn)行
          MOV SpCoun,TH0
          MOV SpCoun+1,TL0 ;讀取計(jì)數(shù)值
          CLR A
          MOV TH0,A
          MOV TL0,A ;清計(jì)數(shù)器
          SETB SpCalc ;要求主程序計(jì)算速度
          MOV SecCoun,#0 ;清秒計(jì)數(shù)器
          Go2:
          INC COUNT       ;用于顯示的計(jì)數(shù)器
          MOV A,COUNT
          CLR C
          SUBB A,#6
          JZ N1
          JMP N2
          N1: MOV COUNT,#0
          N2: MOV A,#DISPBUF
          ADD A,COUNT
          MOV R0,A ;指向當(dāng)前要顯示的顯示緩沖區(qū)
          MOV A,@R0 ;取第一個(gè)待顯示數(shù)
          MOV DPTR,#DISPTAB ;字形表首地址
          MOVC A,@A+DPTR  ;取字形碼
          MOV P0,A ;將字形碼送P0位（段口）
          MOV A,COUNT
          MOV DPTR,#BitTab ;字位表首地址
          MOVC A,@A+DPTR
          ORL P2,#11111100B   
          ANL P2,A
          MOV TH1,#HIGH(65536-4000)
          MOV TL1,#LOW(65536-4000)
          POP PSW
          POP ACC
          RETI
         
          BitTab: DB 7Fh,0BFH,0DFH,0EFH,0F7H,0FBH
          DISPTAB:DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,88H,83H,0C6H,0A1H,86H,8EH,0FFH
          ……其他數(shù)學(xué)運(yùn)算程序（略）
         
          　　四、程序分析
              主程序在對定時(shí)器、計(jì)數(shù)器、堆棧等進(jìn)行初始化后即判斷標(biāo)志SpCalc是否為1，如果為1，說明要求對數(shù)據(jù)進(jìn)行計(jì)算處理，首先將SpCalc標(biāo)志清零，以保證下次能正常判斷，然后進(jìn)入數(shù)據(jù)處理程序，由于這里的閘門時(shí)間為1s，而顯示要求為轉(zhuǎn)/分，因此，要將測到的數(shù)據(jù)進(jìn)行轉(zhuǎn)換，轉(zhuǎn)換的方法是將測得的數(shù)據(jù)乘以60，但由于轉(zhuǎn)軸上安裝有12只磁鋼，每旋轉(zhuǎn)一周可以得到12個(gè)脈沖，因此，要將測得的數(shù)據(jù)除以12，所以綜合起來，將測得的數(shù)據(jù)乘以5即可得到每分鐘的轉(zhuǎn)速。計(jì)算得到的結(jié)果是二進(jìn)制的整數(shù)，要將數(shù)據(jù)送往顯示緩沖區(qū)需要將該數(shù)轉(zhuǎn)化為BCD碼。運(yùn)算得到的是壓縮BCD碼，需要將其轉(zhuǎn)換為非壓縮BCD碼，從標(biāo)號CBCD開始的一段程序即作了這樣的處理。需要說明的是，這里多位二進(jìn)制乘法和多位二進(jìn)制到BCD碼的轉(zhuǎn)換都是用了現(xiàn)成的成熟子程序，因此，首先將二進(jìn)制數(shù)轉(zhuǎn)換為壓結(jié)合實(shí)際BCD碼，然后再轉(zhuǎn)換成非壓縮BCD碼，看似多寫了些程序，實(shí)際上這對于保證程序的質(zhì)量很有好處。
              定時(shí)器T1用作4ms定時(shí)發(fā)生器，在定時(shí)中斷程序中進(jìn)行數(shù)碼管的動態(tài)掃描，同時(shí)產(chǎn)生1s的閘門信號。1s閘門信號的產(chǎn)生是通過一個(gè)計(jì)數(shù)器Count，每次中斷時(shí)間為4ms，每計(jì)250次即為1s，到了1s后，即清除計(jì)數(shù)器Count，然后關(guān)閉作為計(jì)數(shù)器用的T0，讀出TH0、TL0中的數(shù)值，分別送入SpCoun和SpCoun+1單元，將T0中的值清空，置SpCalc標(biāo)志為1，要求主程序進(jìn)行速度值的計(jì)算。這里還有一個(gè)細(xì)節(jié)，用作1s閘門信號產(chǎn)生的Count每次中斷都會加1，而T0卻有一個(gè)周期是被關(guān)閉的，因此，計(jì)數(shù)值是251而不是250。
              看完這一部份內(nèi)容以后，請讀者自行完成以下工作：
         
              1.試用測脈寬法測試速度（提示：80C51單片機(jī)內(nèi)部有高精度信號源，而其計(jì)數(shù)器又具有門控特性），注意硬件設(shè)計(jì)要略作更改。
         
              2.查找等精度測量原理，試設(shè)計(jì)等精度測量的硬件設(shè)計(jì)并編寫相應(yīng)軟件。

0022、直流電機(jī)測速 中文液晶顯示.rar

95.74 KB, 下載次數(shù): 9, 下載積分: 黑幣 -5





歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1