標(biāo)題: 51單片機(jī)匯編版本，關(guān)于工作寄存器R1在程序運(yùn)行過程中無緣無故被修改的問題 [打印本頁(yè)]
作者: anyint    時(shí)間: 2017-11-14 17:27
標(biāo)題: 51單片機(jī)匯編版本，關(guān)于工作寄存器R1在程序運(yùn)行過程中無緣無故被修改的問題
附上軟件代碼：TEMP EQU 07H        ;地址不要亂定 R7

硬件上：P3.0、P3.1口接了按鍵，P1口接了LED燈

問題：程序當(dāng)中第一種模式ONE，里面的延時(shí)部分，有一個(gè)工作寄存器R1，在按鍵處理子程序KEYPRO中修改了之后，程序應(yīng)該是一直保持修改之后的值的，但是顯示的子程序循環(huán)執(zhí)行幾個(gè)來回后，R1發(fā)生了改變，好像恢復(fù)到初值了，顯示（流水燈）的速度又快了。請(qǐng)教大佬們，R1工作寄存器的值變化是什么原因造成的？小弟不才，希望是代碼錯(cuò)了，求大佬們指點(diǎn)迷津，感激不盡

  1. ORG 000H
  2.                         AJMP MAIN
  3. ORG 100H
  4. ;********;
  5. ;主程序;
  6. ;********;
  7. MAIN:                MOV R0,#000H        ;初始化LED模式為0
  8.                         MOV R1,#00AH        ;初始化LED的速度        
  9.                         MOV R2,#0FEH        ;LED初始狀態(tài)        
  10.                         MOV R5,#0FFH
  11. WHILE:                LCALL KEYSCAN        ;按鍵掃描
  12. S1:                        LCALL KEYPRO        ;按鍵處理
  13. S2:                    LCALL SHOW                ;顯示函數(shù)
  14. JMPEND:                AJMP WHILE
  15. ;********;
  16. ;顯示子程序;
  17. ;********;
  18. SHOW:                MOV A,R0
  19.                         RL A
  20.                         MOV DPTR,#JMPTAB
  21.                         JMP @A+DPTR
  22.                         RET
  23. ;********;
  24. ;按鍵掃描子程序;
  25. ;********;                        ;03H = 0000 0011B
  26. KEYSCAN:        MOV P3,#03H                ;給端口置高電平，讀取端口狀態(tài)必須先置端口為高電平
  27.                         MOV A,P3                ;讀入P3的狀態(tài)也就是按鍵的狀態(tài)
  28.                         ORL A,#0FCH                ;0FCH = 1111 1100B
  29.                         CPL A                        ;取反
  30.                         JZ        S2                        ;如果A鍵態(tài)為00，則無按鍵填過直接做顯示部分        
  31.                         MOV TEMP,A                ;保存臨時(shí)鍵值
  32.                         LCALL        DELAY10MS;消抖
  33.                         MOV A,P3
  34.                         ORL A,#0FCH
  35.                         CPL A
  36.                         CJNE A,TEMP,S2  ;判斷如果第二次讀取的按鍵值和第一次讀取的按鍵值不相等
  37.                         MOV R5,A                ;保存鍵值

  39.                         RET
  40. ;********;
  41. ;按鍵處理子程序;
  42. ;********;        
  43. KEYPRO:                MOV A,R5                        ;把按鍵值給A
  44.                         CJNE A,#001H,IFK2        ;如果鍵狀態(tài)為K1，則
  45.                         CJNE R0,#002H,K1PRO        ; R0 = 0000 0000B    #0000 0010B
  46.                         MOV R0,#000H
  47.                         SJMP KEYPROEND
  48. IFK2:                CJNE A,#002H,KEYPROEND
  49.                         CJNE R1,#0FAH,K2PRO
  50.                         MOV R1,#00AH
  51.                         SJMP KEYPROEND
  52. K1PRO:                INC R0
  53.                         SJMP KEYPROEND
  54. K2PRO:                MOV A,R1
  55.                         ADD A,#00AH
  56.                         MOV R1,A
  57.                         SJMP KEYPROEND
  58. KEYPROEND:        RET
  59. ;********;
  60. ;延時(shí)10ms子程序;
  61. ;********;
  62. DELAY10MS:                        ;@11.0592MHz
  63.                         PUSH 30H
  64.                         PUSH 31H
  65.                         MOV 30H,#18
  66.                         MOV 31H,#230
  67. NEXT:
  68.                         DJNZ 31H,NEXT
  69.                         DJNZ 30H,NEXT
  70.                         POP 31H
  71.                         POP 30H
  72.                         RET               
  73. ;********;
  74. ;分支1子程序;
  75. ;********;
  76. ONE:                        
  77.                         MOV A,R2                        ;R2是P1初始狀態(tài)LED 1111 1110B = 0FEH
  78.                         MOV P1,A
  79.                         MOV A,R1
  80.                         MOV R3,A
  81.                         ;MOV P1,A
  82. L1:                        LCALL DELAY10MS
  83.                         DJNZ R3,L1

  85.                         MOV A,R2
  86.                         RL A
  87.                         MOV R2,A
  88.                         AJMP JMPEND
  89. ;********;
  90. ;分支2子程序;
  91. ;********;
  92. TWO:                MOV P1,#00FH
  93.                         SJMP $
  94.                         AJMP JMPEND
  95. ;********;
  96. ;跳轉(zhuǎn)程序表;
  97. ;********;
  98. JMPTAB:                AJMP ONE
  99.                         AJMP TWO
  100.                         END
復(fù)制代碼
作者: yzwzfyz    時(shí)間: 2017-11-15 13:35
請(qǐng)教一下，堆棧存從哪里開始？堆棧里的數(shù)據(jù)何時(shí)會(huì)發(fā)生變化？
作者: anyint    時(shí)間: 2017-11-15 21:43
yzwzfyz 發(fā)表于 2017-11-15 13:35
請(qǐng)教一下，堆棧存從哪里開始？堆棧里的數(shù)據(jù)何時(shí)會(huì)發(fā)生變化？

查閱一下51匯編的書籍，堆棧的一開始初始化的地址我忘記，堆棧地址可以改的，給sp賦值即可。MOV SP,060H。堆棧的數(shù)據(jù)，當(dāng)你調(diào)用子程序了就會(huì)壓棧，返回的時(shí)候就出棧。或者直接對(duì)堆棧進(jìn)行操作PUSH或者POP
作者: anyint    時(shí)間: 2017-11-15 21:56
問題已找到，謝謝老師和同學(xué)以及論壇的大佬們。這個(gè)代碼邏輯上應(yīng)該對(duì)的，但是存在一個(gè)問題就是主程序明明調(diào)用了按鍵掃描子程序 LCALL KEYSCAN，但是在這個(gè)按鍵掃描的子程序里，我寫了一個(gè)判斷數(shù)據(jù)是否相等跳轉(zhuǎn)的命令 CJNE A,TEMP,S2，而這個(gè)跳轉(zhuǎn)的地址S2確實(shí)主程序里的，因此在按鍵子程序還沒有RET返回就已經(jīng)跳轉(zhuǎn)到另外一個(gè)子程序里面了，此時(shí)堆棧就溢出，調(diào)用了卻沒有執(zhí)行返回，調(diào)用的時(shí)候會(huì)壓棧的，那么返回就是出棧，如果沒有返回就會(huì)使得堆棧溢出，程序多跑幾次直接復(fù)位�？偨Y(jié)就是：調(diào)用了子程序一定要返回，不能調(diào)用了子程序再跳轉(zhuǎn)到另外一個(gè)子程序，這樣返回那句命令就廢了。（如果調(diào)用了子程序，在自己的子程序里跳轉(zhuǎn)是可以的）哈哈開心解決了一個(gè)很不容易發(fā)現(xiàn)的問題。再一次感謝老師同學(xué)以及論壇的大佬們。

附上正確的代碼：

TEMP EQU 07H        ;地址不要亂定 R7
ORG 000H
                        AJMP MAIN
ORG 100H
;********;
;主程序;
;********;
MAIN:                MOV R0,#000H        ;初始化LED模式為0
                        MOV R1,#00AH        ;初始化LED的速度       
                        MOV R2,#0FEH        ;LED初始狀態(tài)       
                        MOV R5,#0FFH        ;初始化鍵代碼
                        MOV R6,#008H        ;初始化計(jì)數(shù)器
WHILE:                LCALL KEYSCAN        ;按鍵掃描
                        LCALL KEYPRO        ;按鍵處理
                             LCALL KEYAGIN        ;按鍵彈起
                        AJMP SHOW                ;顯示函數(shù)
JMPEND:                AJMP WHILE
;********;
;顯示子程序;
;********;
SHOW:                MOV A,R0
                        RL A
                        MOV DPTR,#JMPTAB
                        JMP @A+DPTR
;********;
;按鍵掃描子程序;
;********;                        ;03H = 0000 0011B
KEYSCAN:                MOV P3,#03H                ;給端口置高電平，讀取端口狀態(tài)必須先置端口為高電平
                        MOV A,P3                ;讀入P3的狀態(tài)也就是按鍵的狀態(tài)
                        ORL A,#0FCH                ;0FCH = 1111 1100B
                        CPL A                        ;取反
                        JZ        ONKEY                        ;如果A鍵態(tài)為00，則無按鍵填過直接做顯示部分       
                        MOV TEMP,A                ;保存臨時(shí)鍵值
                        LCALL        DELAY10MS;消抖
                        MOV A,P3
                        ORL A,#0FCH
                        CPL A
                        CJNE A,TEMP,ONKEY  ;判斷如果第二次讀取的按鍵值和第一次讀取的按鍵值不相等
                        MOV R5,A                ;保存鍵值
                        AJMP KSEND
ONKEY:            MOV R5,#000H
KSEND:            RET
;********;
;按鍵處理子程序;
;********;       
KEYPRO:                MOV A,R5                        ;把按鍵值給A
                        CJNE A,#000H,DOWNKEY
                        AJMP KEYPROEND
DOWNKEY:        CJNE A,#001H,IFK2        ;如果鍵狀態(tài)為K1，則
                        CJNE R0,#003H,K1PRO        ;
                        MOV R0,#000H
                        MOV R2,#0FEH
                        SJMP KEYPROEND
IFK2:                        CJNE A,#002H,KEYPROEND
                        CJNE R1,#0FAH,K2PRO
                        MOV R1,#00AH
                        SJMP KEYPROEND
K1PRO:                INC R0
                        MOV R2,#0FEH
                        SJMP KEYPROEND
K2PRO:                MOV A,R1
                        ADD A,#00AH
                        MOV R1,A
                        SJMP KEYPROEND
KEYPROEND:        RET
;********;
;按鍵彈起子程序;
;********;       
KEYAGIN:           MOV A,R5
                        CJNE A,#000H,KEYTQ
                        AJMP NOKEYTQ
KEYTQ:                MOV P3,#03H
KEYTA:                MOV A,P3
                        ORL A,#0FCH
                        CPL  A
                        CJNE A,TEMP,KEYCH
                        SJMP KEYTA
KEYCH:                    NOP
NOKEYTQ:           RET
;********;
;延時(shí)10ms子程序;
;********;
DELAY10MS:                        ;@11.0592MHz
                        PUSH 30H
                        PUSH 31H
                        MOV 30H,#18
                        MOV 31H,#230
NEXT:
                        DJNZ 31H,NEXT
                        DJNZ 30H,NEXT
                        POP 31H
                        POP 30H
                        RET               
;********;
;分支1子程序;
;********;
ONE:                       
                        MOV A,R2                        ;R2是P1初始狀態(tài)LED 1111 1110B = 0FEH
                        MOV P1,A
                        MOV A,R1
                        MOV R3,A
L1:                        LCALL DELAY10MS
                        DJNZ R3,L1

                        MOV A,R2
                        RL A
                        MOV R2,A
                        AJMP JMPEND
;********;
;分支2子程序;
;********;
TWO:                MOV A,R2
                        CLR C
                        MOV P1,A
                        MOV A,R1
                        MOV R3,A
L2:                        LCALL DELAY10MS
                        DJNZ R3,L2
                        MOV A,R2
                        RLC A
                        MOV R2,A
                        DJNZ R6,TWOEND
                        MOV R6,#009H
                        MOV R2,#0FFH
TWOEND:                AJMP JMPEND
;********;
;分支3子程序;
;********;
THREE:                MOV P1,#00FH
                        MOV A,R1
                        MOV R3,A
L3:                        LCALL DELAY10MS
                        DJNZ R3,L3
                        MOV P1,#0F0H
                        MOV A,R1
                        MOV R3,A
L4:                        LCALL DELAY10MS
                        DJNZ R3,L4
                        AJMP JMPEND
;********;
;分支4子程序;
;********;
FOUR:                MOV P1,#0C3H
                        MOV A,R1
                        MOV R3,A
L5:                        LCALL DELAY10MS
                        DJNZ R3,L5
                        MOV P1,#03CH
                        MOV A,R1
                        MOV R3,A
L6:                        LCALL DELAY10MS
                        DJNZ R3,L6
                        AJMP JMPEND
;********;
;跳轉(zhuǎn)程序表;
;********;
JMPTAB:                AJMP ONE
                        AJMP TWO
                        AJMP THREE
                        AJMP FOUR
                        END



歡迎光臨 (http://www.torrancerestoration.com/bbs/) Powered by Discuz! X3.1