找回密碼
 立即注冊

QQ登錄

只需一步，快速開始

搜索
查看: 14908|回復(fù): 10
收起左側(cè)

我制作的電動車充電保護器 含單片機源碼與電路原理圖

  [復(fù)制鏈接]
ID:286600 發(fā)表于 2018-3-2 10:08 | 顯示全部樓層 |閱讀模式
下面是此電瓶車充電保護器作品的外觀圖：
IMG_20180301_095151.jpg
這是一個電瓶車充電器的附加裝置，不對充電器做任何變動，而是將充電器插在該保護器上連成一體代替原充電器進行電瓶車的充電。
功能：1、充電達到設(shè)定的電壓，自動斷電停充，防過充。
      2、滿十小時自動停充電，電瓶有故障充不到設(shè)定電壓，經(jīng)十小時也停充。
      3、能根據(jù)氣溫設(shè)定充電電壓檔次，能記憶設(shè)定的檔次，無須每次設(shè)定。
      4、用二進制數(shù)循環(huán)顯示電壓的十位個位小數(shù)位值。
用法：將充電器插在該保護器上連成一體，代替原充電器進行電瓶車的充電。插上220V交流后在15秒內(nèi)左右慢搖保護器，使內(nèi)置水銀開關(guān)接通又斷開（按鍵作用），溫度檔次依次增加，共分1~8檔，對應(yīng)環(huán)境溫度是5℃－40℃。水銀開關(guān)斷開15秒后進入充電程序，水銀開關(guān)不再起作用。
       充足電的斷充電指示可從原充電器指示燈看出，不另加指示燈。
讀電壓：顯示過程是－－四燈全亮（提示開始）、滅、十位、滅、個位、滅、小數(shù)一位、滅，循環(huán)不斷。用四位二進制數(shù)表示0到9，讀出數(shù)不難，記得四燈分別代表8、4、2、1，將亮燈的數(shù)相加就是了。0也顯示為滅，可從時間上判別出來。
例：54.9顯示為
       ○○○○  開始
　　●○●○  5
       ●○●●  4
       ○●●○  9
為省事沒用數(shù)碼管，自己用的東西，簡單實用為好。四個發(fā)光管也合用一個限流電阻，單片機復(fù)位用的電容電阻也省了，晶振也省了。

工作原理：用手機充電器拆來的電路板為裝置提供5V電源。單片機AD轉(zhuǎn)換測電壓，每15秒進行一次。測得的電壓與設(shè)定的終止電壓比較，達到了就給繼電器模塊送一信號，收到信號繼電器就斷開充電器電源。單片機同時計時，滿十時也發(fā)出停充電信號，滿十天自動重啟單片機進行充電管理（暑假長時間人不在家也沒問題了）。
    為避免單片機工作電壓變動對電壓測量的影響，用TL431提供一個基準(zhǔn)電壓，P1.1對其進行AD轉(zhuǎn)換。電瓶電壓1/15分壓后用P1.0進行AD轉(zhuǎn)換，然后用下式算出電瓶電壓。
         十五分之一電瓶電壓:基準(zhǔn)電壓＝電瓶AD值:基準(zhǔn)電壓的AD值
實測TL431穩(wěn)壓后是2.524伏，程序中采用的具體算法是：
      電瓶電壓伏特數(shù)＝(電瓶AD值×37+電瓶AD值×86÷100）÷基準(zhǔn)電壓AD值   
被除數(shù)是兩個8位，除數(shù)是一個8位，我是用循環(huán)做減法的辦法來求商。具體見源碼。
      分壓電阻的調(diào)整，借助萬用表反復(fù)細心調(diào)精密可調(diào)電阻，使阻值之比為14:1。
材料：單片機STC12C5204AD  繼電器模塊，手機充電器，交流插座等。

電路原理圖：

單片機電路圖

單片機電路圖

接線示意圖：

組裝接線示意圖

組裝接線示意圖

制作過程：

裝飾邊角料做的外殼

裝飾邊角料做的外殼 IMG_2.jpg

拆解手機充電器

拆解手機充電器

繼電器模塊

繼電器模塊 IMG_5.jpg IMG_6.jpg IMG_7.jpg IMG_9.jpg

單片機正面

單片機正面

單片機背面

單片機背面

組裝好

組裝好 IMG_20180301_095125.jpg

單片機編程源碼如下:
  1.                                                                  ;1/15取樣，單片機工作電壓約5V，能測電壓達75V。
  2. ;改成最多充電10小時。十天后重啟。
  3. ;使用EEPROM保存溫度檔。                                                                                                                                                                                                ;2016年7月6日修改：
  4. ;使用汞開關(guān)設(shè)定溫度檔，使用EEPROM保存溫度檔。
  5. ;開機16秒內(nèi)（大約）按鍵設(shè)定溫度檔數(shù)，若不按鍵，則默認上次的檔數(shù)。有1，2，3，4，5，6，7，8共八檔。
  6. ;設(shè)溫度檔后接通220V
  7. ;從溫度5度起為第1檔，10度為第2檔，15度為第3檔，……35度為第7檔，40度為第8 檔，0檔同第8檔。停下不按鍵約15秒自動進入下一環(huán)節(jié)。

  9. ;顯示電瓶伏特數(shù)，按四燈亮、黑、十位、黑、個位、黑、小數(shù)位、黑，循環(huán)顯示。四燈亮和黑是半秒，數(shù)字是1秒
  10. ;20H.0設(shè)置溫度檔[WENDU]子程序控制位，初值賦1，在等待按鍵的子程序[xunhuan]中清0.僅在開機初用一次。
  11. ;20H.2 顯示控制位.走時置1，顯示后清0，使得半秒進行一次顯示。
  12. ;20H.3 秒標(biāo)志
  13. ;21H.0
  14. ;21H.2 [Tuoliu]程序控制位，使程序只運行一次。
  15. ;21H.3
  16. ;21H.4是電瓶正常標(biāo)志，初值賦1（正常），檢測到電瓶充滿或不正常將其清0，清0后要重啟才能置1.
  17. ;21H.6充電10小時標(biāo)志，初值為1，充電達10小時將其清0.清0后要重啟才能置1.
  18. ;22H.0 走時用的20ms標(biāo)志，在中斷置1，走時中清0。
  19. ;22H.3 時標(biāo)志
  20. ;22H.5 每15秒運行一次的標(biāo)志位，走時置1.
  21. ;22H.7
  22. ;用檢測到的電壓AD值與設(shè)定的終止電壓AD值進行比較，確定電瓶滿或不正常（電壓太低或無電瓶）關(guān)斷220V供電。
  23. ;開機接通220V，電瓶充滿（或不正常）關(guān)斷，充電10小時關(guān)斷，十天后單片機重啟。

  25. ;P1.0--A/D轉(zhuǎn)換
  26. ;P1.1--A/D轉(zhuǎn)換測TL431電壓
  27. ;P1.2--鍵，每按一次溫度檔數(shù)加1，在0－－8之中循環(huán)，停下不按鍵約15秒自動進入下一環(huán)節(jié)。
  28. ;P1.7,P1.6,P1.5,P1.4接LED做溫度檔顯示，點亮分別表示8,4，2，1，二進制數(shù)。
  29. ;P3.2--通過光耦控制220V通斷 0－通  1－斷
  30. ;***************

  32. ;***
  33. U_zhongzhixiao  EQU 5EH  ;終止電壓小數(shù)寄存器
  34. U_zhongzhizheng EQU 5FH  ;終止電壓整數(shù)寄存器
  35. JSHQ_WEI EQU 65H        ;顯示第幾位計數(shù)器
  36. XUN_JSHQ EQU 67H        ;循環(huán)次數(shù)
  37. wendudang  EQU  68H     ;溫度檔數(shù)
  38. v_ZH   EQU 5DH         ;電瓶伏特整數(shù)寄存器
  39. V_XAO  EQU 5CH         ;電瓶伏特小數(shù)寄存器
  40. TL431_AD   EQU  5BH     ;TL431的AD值
  41. TL431_AD1  EQU  5AH     ;TL431的AD值(第一次）
  42. jiace_adzhi1 EQU 58H    ;第一次檢測到的AD值
  43. ;xiu_adzhi  EQU  6CH     ;(修)終止電壓AD值
  44. Jiace_ADzhi EQU 59H     ;檢測AD值  檢測到的AD值
  45. JSHQ_15   EQU  6EH      ;15秒計數(shù)器
  46. JSHQ_20mS  EQU  70H     ;20mS計數(shù)器  計20mS的個數(shù)
  47. JSHQ_S     EQU  71H     ;半秒計數(shù)器
  48. JSHQ_M     EQU  72H     ;分計數(shù)器
  49. JSHQ_H     EQU  73H     ;時計數(shù)器
  50. ;60H,61H,62H,63H,64H 用在顯緩中
  51. beichushugao  equ  75h     ;被除數(shù)高位
  52. beichushudi  EQU  76H    ;被除數(shù)低位
  53. chushu     EQU  77H     ;除數(shù)
  54. zhengshang  EQU 78H     ;整數(shù)商
  55. XIAOSHUSHANG  EQU 79H    ;小數(shù)商
  56. YUSHU      EQU  7AH     ;余數(shù)
  57. LSSHU     EQU  7BH     ;臨時存
  58. DISHU  EQU 7CH         ;低數(shù) 第二次的被除數(shù)的低位
  59. GAOSHU  EQU 7DH        ;高數(shù) 第二次的被除數(shù)的高位

  61. ADC_CONTR EQU 0BCH     ;ADC控制寄存器
  62. ADC_RES   EQU 0BDH     ;A/D轉(zhuǎn)換結(jié)果寄存器
  63. P1ASF  EQU 09DH       ;p1口模擬功能控制寄存器
  64. WDT_CONTR EQU 0C1H    ;看門狗
  65. ;AUXR DATA 8EH         ;選擇1T與12T的寄存器

  67. IAP_CONTR EQU 0C7H      ;下載/復(fù)位控制器

  69. jian  EQU  p1.2         ;鍵
  70. kong  EQU  p3.2         ;控 220V   0－通  1－斷
  71. p1m1  equ  91h
  72. p1m0  equ  92h
  73. ;EEPROM有關(guān)的寄存器
  74. dat       equ     0C2H               
  75. drh       equ     0C3H               
  76. drl       equ     0C4H                  
  77. cmd       equ     0C5H               
  78. trig      equ     0C6H               
  79. contr     equ     0C7H
  80. ;****************

  82.         ORG   0000H
  83.         AJMP  START
  84.         ORG          000BH
  85.         LJMP  TIME_0
  86. ;        ORG   001BH

  88.         ORG   0030H
  89. START:
  90. ;其它初始化寫在此     
  91.    MOV P1M1,#00000011B
  92.    MOV P1M0,#00000000B    ;P1.0 P1.1兩個高阻輸入做AD     
  93.    MOV P1,#00001111B
  94.     setb kong          ;斷220V交流 設(shè)溫度檔后接通

  96.         MOV 22H,#00100000B    ;檢測標(biāo)志 1－檢 0－不檢 每15秒檢測AD一次和處理顯緩一次的標(biāo)志位，走時置1，處理顯緩后清0
  97.         MOV 21H,#01010000B   ;21h.4 電瓶 1－能充  0－不能充電（含無、充滿）  
  98.                                ;21H.6  初值1，充電10小時清0 。

  100. ;*用計數(shù)器0  初步設(shè)置定時中斷    20MS中斷  20毫秒@10.911MHz
  101.     MOV SP,#80H                     ;設(shè)置堆棧區(qū)域
  102. ;           ANL AUXR,#7FH                ;定時器時鐘12T模式  默認是12T模式 省略本句
  103.         MOV        TMOD,#00010001B         ;定時器0定時器1都是 16位
  104.         MOV        TL0,#0F7H
  105.         MOV        TH0,#0B8H               

  107.         SETB EA
  108.         SETB        ET0
  109.         SETB        TR0              ;開放中斷
  110.         
  111.         setb 20h.0          ;控制設(shè)置溫度檔程序的循環(huán)用
  112. ;*****************
  113. ;設(shè)置溫度檔   從EEPROM中讀出保存值，一段時間內(nèi)不按鍵，則使用該檔值；如按鍵則改之，停下不動，過會兒保存并啟用。
  114.      LCALL  DOUEEPROM    ;讀EEPROM中的保存值
  115. WENDU:
  116.      jnb 20H.0,WENDUret       ;0－跳

  118.      LCALL  doujian       ;讀鍵和健值處理
  119.      LCALL  XIANSHI       ;顯示
  120.      LCALL  xunhuan       ;循環(huán) 次數(shù)
  121.      AJMP WENDU
  122. WENDUret:
  123.      LCALL clear_write     ;先擦除EEPROM再寫EEPROM保存溫度檔，然后關(guān)閉EEPROM
  124.      nop
  125. ;********************
  126. ;設(shè)AD檔  據(jù)wendudang中數(shù)字，設(shè)定終止電壓
  127. ADdang:
  128.      MOV A,wendudang
  129.      cjne a,#1,ADdang1
  130.      MOV U_zhongzhizheng,57
  131.      mov U_zhongzhixiao,1      ;對應(yīng)是57.11V   5度以下
  132.         JMP ADdangRET     
  133. ADdang1:
  134.      cjne a,#2,ADdang2
  135.      MOV U_zhongzhizheng,56
  136.      mov U_zhongzhixiao,6        ;對應(yīng)是56.64V   10度以下
  137.         JMP ADdangRET
  138. ADdang2:
  139.      cjne a,#3,ADdang3
  140.      MOV U_zhongzhizheng,56
  141.      mov U_zhongzhixiao,1        ;對應(yīng)是56.16V   15度以下
  142.         JMP ADdangRET        
  143. ADdang3:
  144.      cjne a,#4,ADdang4
  145.      MOV U_zhongzhizheng,55
  146.      mov U_zhongzhixiao,6        ;對應(yīng)是55.68V   20度以下
  147.         JMP ADdangRET        
  148. ADdang4:
  149.      cjne a,#5,ADdang5
  150.      MOV U_zhongzhizheng,55
  151.      mov U_zhongzhixiao,2        ;對應(yīng)是55.20V   25度以下
  152.         JMP ADdangRET        
  153. ADdang5:
  154.      cjne a,#6,ADdang6
  155.      MOV U_zhongzhizheng,54
  156.      mov U_zhongzhixiao,7         ;對應(yīng)是54.72V   30度以下
  157.         JMP ADdangRET
  158. ADdang6:
  159.      cjne a,#7,ADdang7
  160.      MOV U_zhongzhizheng,54
  161.      mov U_zhongzhixiao,2         ;對應(yīng)是54.24V   35度以下
  162.         JMP ADdangRET
  163. ADdang7:
  164.      cjne a,#8,ADdang8
  165.      MOV U_zhongzhizheng,53
  166.      mov U_zhongzhixiao,7          ;對應(yīng)是53.76V   40度以下
  167.         JMP ADdangRET
  168. ADdang8:             ;剩下的就是 a=0了    同a=8 檔           
  169.      MOV U_zhongzhizheng,53
  170.      mov U_zhongzhixiao,7          ;對應(yīng)是53.76V   40度以下

  172. ADdangRET:
  173.      clr kong     ;接通220V
  174.         nop
  175.         NOP
  176.     ;進入主程序之前不能有RET，否則運行到此止。
  177. ;*****************
  178. ;主程序
  179. ZhuPRO:
  180.      LCALL PRO_ZOUSHI         ;走時   統(tǒng)計20mS的個數(shù)，計時，設(shè)立半秒標(biāo)志、分標(biāo)志、時標(biāo)志 檢測標(biāo)志
  181.      LCALL  KAIJISHISHU   ;開機時數(shù)   開機10小時停充電，開機240小時重新啟動單片機。
  182. jnb 22h.5,zhu_a
  183.         clr 22h.5             ;每15秒一次的標(biāo)志位，走時置1，在此清0
  184.      lcall  jiaceTL431       ;檢測TL431做基準(zhǔn)電壓的AD值
  185.       LCALL  jiacesheding   ;檢測(電瓶）設(shè)定      測出電瓶AD
  186.      LCALL  JISUAN         ;計算 電瓶電壓伏特數(shù)＝(電瓶AD值×37+電瓶AD值×0.5）÷基準(zhǔn)電壓AD值 求出伏特整數(shù)和小數(shù)
  187.      LCALL  probijiao    ;比較     電瓶電壓與基準(zhǔn)電壓做比較 標(biāo)記是否充滿電
  188.      lcall XIANhuan           ;顯緩 存放好要顯示的十位、個位、小數(shù)位
  189. zhu_a:
  190.      LCALL  xiu_V      ;顯示電瓶電壓
  191.      
  192.      lcall  PROKongZhi     ;控制      充滿斷電 十小時斷電
  193.      mov WDT_CONTR,#00111110B      ;喂狗
  194.      jmp  ZhuPRO

  196. ;*************************** WENDU 溫度 設(shè)溫度檔 *********************************
  197. ;DOUEEPROM    ;讀EEPROM中0000H處的保存值
  198. DOUEEPROM:
  199.                     mov     contr,#84h ;設(shè)定操作時間
  200.                     mov     cmd,#01h   ;設(shè)定讀操作
  201.                     mov     drl,#00h     ;設(shè)定存儲單元地址低四位
  202.                     mov     drh,#00h    ;設(shè)定存儲單元地址高四位 這里設(shè)0000h，也可選用其他單元
  203.                     mov     trig,#5Ah  ;準(zhǔn)備觸發(fā)
  204.                     mov     trig,#0A5h  ;觸發(fā)
  205.                     nop
  206.                     mov     wendudang,dat         ;讀數(shù)據(jù)寫到RAM指定處
  207. ;                    mov     wendudang,A        ;讀數(shù)據(jù)寫到RAM指定處

  209. DOUEEPROMret:
  210.         ret
  211. ;*************
  212. ;doujian       ;讀鍵
  213. doujian:
  214.          setb jian
  215.          nop
  216.          nop
  217.          lcall DELAY         
  218.          JB jian,doujianret          ;未按下(p1.2),  1-跳
  219.          lcall DELAY                ;延時
  220.          JB jian,doujianret
  221.          inc wendudang               ;溫度檔加1
  222.          mov XUN_JSHQ,#0            ;循環(huán)計數(shù)清0
  223.          mov a,#9
  224.          cjne a,wendudang,doujian_1  ; 分0，1，2，3，4，5，6，7,8九檔，最高8檔
  225.          mov wendudang,#0

  227. doujian_1:
  228.          nop
  229.          jb jian,doujian_1       ;1-跳 等待釋放鍵
  230.          lcall DELAY
  231.          lcall DELAY
  232. doujianret:
  233.    ret

  235. ;****************
  236. ;XIANSHI    ;顯示
  237. XIANSHI:
  238.         mov a,wendudang
  239.         cpl a          ;取反
  240.         swap a         ;高低四位交換
  241.         ANL A,#11110000B   ;獲高四位
  242.         mov R0,a

  244.         mov a,p1
  245.         anl a,#00001111B   ;獲低四位
  246.         orl a,R0           ;整合高低八位
  247.         mov p1,a           ;驅(qū)動LED
  248. XIANSHIret:
  249.     ret
  250. ;****************   
  251. ;xunhuan       ;循環(huán) 次數(shù)
  252. xunhuan:
  253.       lcall DELAY      ;延時
  254.       INC XUN_JSHQ     ;循環(huán)計數(shù)加1
  255.       mov a,XUN_JSHQ
  256.       cjne a,#200,xunhuanret
  257.       mov XUN_JSHQ,#0
  258.       clr 20h.0         ;停止按鍵后循環(huán)200次約？？秒，結(jié)束設(shè)溫度檔程序

  260. xunhuanret:
  261.      RET
  262. ;******************
  263. ;延時 0.04秒
  264.     DELAY:
  265.             MOV     R7,#250
  266.     D1:     MOV     R6,#250
  267.                     DJNZ    R6,$
  268.                     DJNZ    R7,D1
  269.             RET
  270. ;*****************
  271. ;先擦除再寫入，然后關(guān)閉
  272. clear_write:
  273.               mov    contr,#84h  ;設(shè)定操作時間
  274.               mov    cmd,#03h    ;設(shè)定擦除操作
  275.               mov    drl,#00h    ;設(shè)定存儲單元地址低四位
  276.               mov    drh,#00h    ;設(shè)定存儲單元地址高四位 這里設(shè)0000h

  278.               mov    trig,#5AH   ;準(zhǔn)備觸發(fā)      
  279.               mov    trig,#0A5h   ;觸發(fā)
  280.               nop
  281.               nop
  282. ;---------寫-------------------
  283. write:
  284.                    mov     contr,#84h   ;設(shè)定操作時間
  285.                    mov     cmd,#02h     ;設(shè)定寫操作
  286.                    mov     drl,#00h     ;設(shè)定存儲單元地址低四位
  287.                    mov     drh,#00h     ;設(shè)定存儲單元地址高四位 這里設(shè)0000h
  288. ;      MOV A,wendudang
  289.                    mov     dat,wendudang         ;wendudang中為準(zhǔn)備寫入的數(shù)據(jù)
  290.                    mov     trig,#5AH    ;準(zhǔn)備觸發(fā)
  291.                    mov     trig,#0A5H   ;觸發(fā)
  292.                    nop
  293.                    nop
  294. ;=========關(guān)閉EEPROM====================
  295. off:  
  296.           mov     contr,#0     ;禁止操作
  297.           mov     cmd,#0   ;去除操作命令
  298.           mov     trig,#0   ;防止命令誤觸發(fā)
  299.           mov    drl,#0         ;指向非EEPROM區(qū)
  300.           mov    drh,#80H        ;指向非EEPROM區(qū)
  301.            ret
  302.    
  303. ;*********************************** 充電有關(guān)的計時 ******************************



  307. ;****************
  308. ;走時   統(tǒng)計20mS的個數(shù)，計時，設(shè)立半秒標(biāo)志、分標(biāo)志、時標(biāo)志
  309. PRO_ZOUSHI:
  310.      JNB 22H.0,PROARET     ;20mS標(biāo)志位
  311.      INC JSHQ_20MS
  312.      CLR 22H.0   
  313.      mov A,#25             ;25個20mS為半秒
  314.      CJNE A,JSHQ_20mS,PROARET
  315.      MOV JSHQ_20mS,#0
  316.      inc jshq_S
  317.      setb 20h.2         ;控制顯示的半秒標(biāo)志
  318. PROA_1:
  319.   MOV A,#30
  320.   CJNE A,JSHQ_S,PROARET
  321.        MOV JSHQ_S,#0
  322.   SETB 22H.5   ;15秒檢測一次
  323.   INC JSHQ_15
  324.   MOV A,#4
  325.   CJNE A,JSHQ_15,PROARET
  326.      MOV JSHQ_15,#0
  327.      INC JSHQ_M
  328.      MOV A,#60             ;60分為1小時
  329.      CJNE A,JSHQ_M,PROARET
  330.      MOV JSHQ_M,#0
  331.      setb 22h.3       ;時標(biāo)志

  333. PROARET:
  334.      RET

  336. ;********************
  337. ;開機時數(shù)   開機10小時停充電，開機240小時重新啟動單片機。
  338. KAIJISHISHU:
  339.     JNB 22H.3,KAIJISHISHURET
  340.     clr 22h.3
  341.     INC JSHQ_H
  342.     MOV A,#10         ;最多充電10小時
  343.     CJNE A,JSHQ_H,KAIJISHISHU_1
  344.     CLR 21H.6        ;初值1，充電10小時清0。
  345.     setb kong          ;斷220V交流
  346.     JMP KAIJISHISHURET
  347. KAIJISHISHU_1:
  348.     mov a,#240         ;十天重啟
  349.     cjne a,jshq_h,KAIJISHISHURET
  350.     MOV IAP_CONTR,#00100000B  ;熱重啟
  351. KAIJISHISHURET:
  352.      RET
  353. ;*******************
  354. ;檢測設(shè)定    每15秒進行一次     兩次測電壓相同 確定占空比  溫度檢測沒使用
  355. jiacesheding:
  356. ;          MOV P1,#11111111B           ;關(guān)顯示 再延時 防止電壓波動對AD轉(zhuǎn)換的影響
  357. ;          LCALL DELAY                 ;延時0.4秒
  358. dianya:
  359.       lcall PRO_ad   ;AD轉(zhuǎn)換測電瓶電壓
  360.       MOV jiace_adzhi1,jiace_adzhi
  361.       mov jiace_adzhi,#0
  362.       lcall PRO_ad  ;AD轉(zhuǎn)換測電瓶電壓  
  363. BiJiao:                 ;比較兩次測電壓結(jié)果 同－進入下一步 不同－重測
  364.       mov a,jiace_adzhi1
  365.       cjne a,jiace_adzhi,dianya
  366.       
  367. jiaceshedingret:
  368.      ret

  370. ;********************
  371. ;AD轉(zhuǎn)換測電瓶電壓
  372. PRO_ad:
  373.       MOV P1ASF,#0000001B   ;P1.0做AD檢測
  374.      MOV ADC_RES,#0                ;轉(zhuǎn)換結(jié)果寄存器清零
  375.      MOV ADC_CONTR,#11100000B  
  376.      nop
  377.      nop
  378.      nop
  379.      nop
  380.      mov a,#11101000b
  381.      MOV ADC_CONTR,A            ;開始A/D轉(zhuǎn)換
  382.       NOP                        ;在質(zhì)詢之前一定等候
  383.       NOP
  384.       NOP
  385.       NOP
  386. WAIT:      
  387.     MOV        A,ADC_CONTR        ;等候完成的標(biāo)志
  388.     JNB        ACC.4,WAIT        ;轉(zhuǎn)換完成標(biāo)志位 不是1就轉(zhuǎn)           
  389.     MOV        ADC_CONTR,#01100000B                ;關(guān)轉(zhuǎn)換 清標(biāo)志位  
  390.    
  391.     MOV jiace_adzhi,ADC_RES       ;讀出AD值保存

  393. PRO_adRET:
  394.       RET

  396. ;********************
  397. jiaceTL431:
  398. ;          MOV P1,#11111111B           ;關(guān)顯示 再延時 防止電壓波動對AD轉(zhuǎn)換的影響
  399. ;          LCALL DELAY                 ;延時0.4秒
  400. dianyaTL:
  401.       lcall prTL431_ad   ;AD轉(zhuǎn)換測TL431的AD
  402.       MOV TL431_AD1,TL431_AD
  403.       mov TL431_AD,#0
  404.       lcall prTL431_ad  ;AD轉(zhuǎn)換測TL431的AD
  405. BiJiaoTL:                 ;比較兩次測電壓結(jié)果 同－進入下一步 不同－重測
  406.       mov a,TL431_AD1
  407.       cjne a,TL431_AD,dianyaTL

  409. jiaceTL431ret:
  410.      ret
  411. ;******************
  412. ;AD轉(zhuǎn)換測TL431
  413. prTL431_ad:
  414.       MOV P1ASF,#0000010B   ;P1.1做AD檢測
  415.      MOV ADC_RES,#0                ;轉(zhuǎn)換結(jié)果寄存器清零
  416.      MOV ADC_CONTR,#11100001B  
  417.      nop
  418.      nop
  419.      nop
  420.      nop
  421.      mov a,#11101001b
  422.      MOV ADC_CONTR,A            ;開始A/D轉(zhuǎn)換
  423.       NOP                        ;在質(zhì)詢之前一定等候
  424.       NOP
  425.       NOP
  426.       NOP
  427. TL431WAIT:      
  428.     MOV        A,ADC_CONTR        ;等候完成的標(biāo)志
  429.     JNB        ACC.4,TL431WAIT        ;轉(zhuǎn)換完成標(biāo)志位 不是1就轉(zhuǎn)           
  430.     MOV        ADC_CONTR,#11100001B                ;關(guān)轉(zhuǎn)換 清標(biāo)志位  
  431.    
  432.     MOV TL431_AD,ADC_RES       ;讀出AD值保存

  434. TL431_adRET:
  435.       RET

  437. ;*******************
  438. ;比較 ;通過電瓶電壓整數(shù)與終止電壓整數(shù)比較，電瓶電壓小數(shù)與終止電壓小數(shù)比較，確定并標(biāo)記電瓶有無充滿.
  439. probijiao:
  440.       clr c
  441.       mov a,v_ZH   ;電瓶電壓整數(shù)
  442.       CJNE A,U_zhongzhizheng,bijiao_1     ;電瓶電壓整數(shù)與終止電壓整數(shù)比較
  443.       MOV A,V_XAO
  444.       CJNE A,U_zhongzhixiao,bijiao_1     ;電瓶電壓小數(shù)與終止電壓小數(shù)比較
  445.       
  446. bijiao_0:      
  447.        clr 21h.4     ;電瓶正常標(biāo)志位  1--正常  0－－充滿（或不能充電）   
  448.        JMP bijiao_ret
  449. bijiao_1:
  450.       JC bijiao_0  ;超過終止電壓 C=1
  451.       
  452. bijiao_ret:
  453.       ret      
  454.       
  455. ;******************
  456. ; ;控制充斷電
  457. PROKongZhi:
  458.       jb 21h.4,pro_a     ;電瓶正常標(biāo)志 1－正常 0－不正常 無電瓶 或充滿
  459.       setb kong      ;通過光耦控制220V通斷 0－通  1－斷
  460. pro_a:
  461.       JB 21H.6,PROKongZhiRET                     
  462.       setb kong      ;通過光耦控制220V通斷 0－通  1－斷      
  463. PROKongZhiRET:
  464.       RET
  465. ;****************
  466. ;顯緩
  467. XIANhuan:
  468.        MOV A,v_ZH    ;電瓶伏特整數(shù)
  469.        MOV B,#10
  470.        DIV AB
  471.        MOV 61H,B            ;個位
  472.        MOV 60H,A            ;十位
  473.        MOV 62H,V_XAO        ;小數(shù)
  474.       
  475.        MOV 63H,#0          ;黑屏的數(shù)字
  476.        mov 64h,#00001111B   ;四燈全亮

  478. XIANhuan_ret:
  479.        ret

  481. ;***************  
  482. ; xiu_V 顯伏特數(shù) 十、個位、小數(shù)位分別顯示，每位顯示2秒，黑屏1秒，三位顯示完黑屏3秒。
  483. xiu_V:
  484.        JNB 20H.2,XianZ   ;每秒運行一次
  485.        CLR 20H.2

  487.       INC JSHQ_WEI
  488.        MOV A,#11
  489.        CJNE A,JSHQ_WEI,xiu_V_1
  490.        MOV JSHQ_WEI,#0      
  491.         mov R1,60H           ;顯十位
  492.         LCALL PROXIAN
  493.       JMP xiu_VRET
  494. xiu_V_1:  
  495.         MOV A,#1            ;顯示十位
  496.        CJNE A,JSHQ_WEI,xiu_V_2
  497.        nop                  ;保持原顯示就行了
  498.         ;mov R1,60H
  499.         ;LCALL PROXIAN
  500. XianZ:  jmp  xiu_VRET           ;中間跳板
  501. xiu_V_2:  
  502.         MOV A,#2     ;黑屏
  503.        CJNE A,JSHQ_WEI,xiu_V_3      
  504.         mov R1,63H
  505.         LCALL PROXIAN
  506.       JMP xiu_VRET        
  507. xiu_V_3:  
  508.         MOV A,#3     ;顯示個位
  509.        CJNE A,JSHQ_WEI,xiu_V_4     
  510.         mov R1,61H
  511.         LCALL PROXIAN
  512.       JMP xiu_VRET        
  513. xiu_V_4:  
  514.         MOV A,#4     ;顯示個位
  515.        CJNE A,JSHQ_WEI,xiu_V_5     
  516.         nop                  ;保持原顯示就行了
  517.         ;mov R1,61H
  518.         ;LCALL PROXIAN
  519.       JMP xiu_VRET        
  520. xiu_V_5:  
  521.         MOV A,#5     ;黑屏
  522.        CJNE A,JSHQ_WEI,xiu_V_6      
  523.         mov R1,63H
  524.         LCALL PROXIAN
  525.       JMP xiu_VRET        
  526. xiu_V_6:  
  527.         MOV A,#6    ;顯示小數(shù)位
  528.        CJNE A,JSHQ_WEI,xiu_V_7     
  529.         mov R1,62H
  530.         LCALL PROXIAN
  531.       JMP xiu_VRET        
  532. xiu_V_7:  
  533.         MOV A,#7     ;顯示小數(shù)位
  534.        CJNE A,JSHQ_WEI,xiu_V_8     
  535.         nop                  ;保持原顯示就行了
  536.         ;mov R1,62H
  537.         ;LCALL PROXIAN
  538.       JMP xiu_VRET        
  539. xiu_V_8:  
  540.         MOV A,#8     ;黑屏
  541.        CJNE A,JSHQ_WEI,xiu_V_9      
  542.         mov R1,63H
  543.         LCALL PROXIAN
  544.       JMP xiu_VRET        
  545. xiu_V_9:  
  546.         MOV A,#9     ;四燈全亮
  547.        CJNE A,JSHQ_WEI,xiu_V_10     
  548.         mov R1,64H
  549.         LCALL PROXIAN
  550.        JMP xiu_VRET      
  551. xiu_V_10:
  552.        nop                   ;保持原顯示就行了
  553.         ;mov R1,63H     ;黑屏
  554.         ;LCALL PROXIAN

  556. xiu_VRET:
  557.        RET
  558. ;***************

  560. ;顯示     
  561. PROXIAN:
  562.         MOV A,R1
  563.         cpl a          ;取反
  564.         swap a         ;高低四位交換
  565.         ANL A,#11110000B   ;獲高四位
  566.         mov R0,a

  568.         mov a,p1
  569.         anl a,#00001111B   ;獲低四位
  570.         orl a,R0           ;整合高低八位
  571.         mov p1,a           ;驅(qū)動LED     
  572.         RET
  573. ;*******************************
  574. ;計算 jì suàn   電瓶電壓伏特數(shù)＝(電瓶AD值×37+電瓶AD值×0.86）÷基準(zhǔn)電壓AD值   TL431穩(wěn)壓后是2.524伏
  575. ;求出伏特整數(shù)和一位小數(shù)
  576. JISUAN:
  577.       MOV v_ZH,#0        ;存伏特整數(shù) 先清0
  578.       mov V_XAO,#0       ;伏特小數(shù) 先清0   
  579.       mov r2,#0
  580.       mov r3,#0
  581. ;電瓶AD值×37      
  582.       MOV A,Jiace_ADzhi  ;電瓶AD值
  583.       MOV B,#37
  584.       MUL AB
  585.       MOV R2,A          ;37倍的積的低8位 存R2
  586.       MOV R3,B          ;37倍的積的高8位 存R3
  587. ;電瓶AD值×86     
  588.       MOV A,Jiace_ADzhi
  589.       mov b,#86        ;
  590.       MUL AB           ;86倍的積高位在B低位在A 高位在B
  591. ;除以100
  592.       MOV beichushugao,B     ;被除數(shù)高位
  593.       MOV beichushudi,A      ;被除數(shù)低位
  594.       MOV chushu,#100        ;除數(shù)
  595.       mov zhengshang,#0      ;整數(shù)商
  596.       mov XIAOSHUSHANG,#0    ;小數(shù)商
  597.       mov YUSHU,#0           ;余數(shù)
  598.       
  599.   LCALL PROCHU
  600.       ;電瓶AD值×0.86的整數(shù)部分已經(jīng)在zhengshang
  601. ;電瓶AD值×37與電瓶AD值×0.86兩積之和
  602.       mov a,zhengshang
  603.       ADD A,R2                 
  604.       MOV R2,A
  605.       JNC  JISUAN_1     ;0-跳
  606.       INC R3
  607.       clr c            ;以上完成了(電瓶AD值×37+電瓶AD值×0.86）  值的高位在R3，低位在R2
  608. JISUAN_1:            
  609. ;下面用減法代除法做[÷基準(zhǔn)電壓AD值]部分
  610.       MOV beichushugao,R3     ;被除數(shù)高位
  611.       MOV beichushudi,R2     ;被除數(shù)低位
  612.       MOV chushu,TL431_AD        ;除數(shù)
  613.       mov zhengshang,#0
  614.       mov XIAOSHUSHANG,#0
  615.       mov YUSHU,#0      
  616.       
  617. LCALL PROCHU
  618.       MOV v_ZH,zhengshang     ;伏特整數(shù)
  619.       MOV V_XAO,XIAOSHUSHANG  ;伏特小數(shù)  
  620. RET
  621. ;*********************
  622. ;除法 被除數(shù)有高8位低8位，除數(shù)只有8位，商有8位整數(shù)1位小數(shù)
  623. ;beichushugao     ;被除數(shù)高位
  624. ;beichushudi      ;被除數(shù)低位
  625. ;chushu        ;除數(shù)
  626. ;zhengshang  EQU 78H     ;整數(shù)商
  627. ;XIAOSHUSHANG  EQU 79H    ;小數(shù)商
  628. ;YUSHU      EQU  7AH     ;余數(shù)
  629. ;LSSHU     EQU  7BH     ;臨時存
  630. ; DISHU   低位 第二次的被除數(shù)低位
  631. ;GAOSHU   高位 第二次的被除數(shù)高位
  632. PROCHU:
  633.       MOV A,#0
  634.       CJNE A,beichushugao,PROCHU_0   ;高位不是0 跳
  635.       MOV A,beichushudi
  636.       jmp PROCHU_A        ;跳到高位是0，求低位的商
  637. PROCHU_0:              ;求高位不是0部分的商
  638.       MOV A,beichushudi
  639. PROCHU_01:      
  640.       SUBB A,chushu
  641.       INC zhengshang
  642.       JNC PROCHU_01      
  643.       DJNZ beichushugao,PROCHU_01
  644. PROCHU_A:            ;高位是0，求低位的商
  645.     ;  MOV  LSSHU,A    ;備份
  646.       SUBB A,chushu
  647.       INC zhengshang
  648.       JNC PROCHU_A     ;c=0 循環(huán)再減
  649.       CLR C            ;有借位，表示多減了一次
  650.    ;   DEC zhengshang   ;恢復(fù)
  651.    ;   MOV A,LSSHU      ;恢復(fù)
  652.      ;*************求小數(shù)**********
  653.       MOV B,#10        ;求小數(shù)，先將被除數(shù)乘10
  654.       MUL AB
  655.       MOV GAOSHU,B       ;高位
  656.       MOV DISHU,A      ;低位
  657. PROCHU_B:
  658.       MOV A,#0
  659.       CJNE A,GAOSHU,PROCHU_B0
  660.       MOV A,DISHU
  661.       JMP PROCHU_C   ;跳到高位是0 求低位商
  662. PROCHU_B0:
  663.       MOV A,DISHU
  664. PROCHU_B01:
  665.       SUBB A,chushu
  666.       INC XIAOSHUSHANG
  667.       JNC PROCHU_B01      
  668.       DJNZ GAOSHU,PROCHU_B01
  669. PROCHU_C:    ;高位是0 求低位商           
  670.       MOV  LSSHU,A
  671.       SUBB A,chushu
  672.       INC XIAOSHUSHANG
  673.       JNC PROCHU_C     ;c=0 循環(huán)再減
  674.       CLR C            ;有借位，表示多減了一次
  675. ;      DEC XIAOSHUSHANG   ;恢復(fù)   實測顯示數(shù)據(jù)偏小所以刪此句
  676.       MOV A,LSSHU      ;恢復(fù)
  677.       MOV YUSHU,A    ;余數(shù)
  678. ret
  679. ;****************      
  680.       
  681. ;**********************************************************************
  682. TIME_0:   ;20毫秒@10.911MHz
  683.         PUSH        ACC
  684.         PUSH        PSW
  685.         MOV        TL0,#0F7H        
  686.         MOV        TH0,#0B8H
  687.         SETB 22H.0          ;20mS標(biāo)志  專供走時用
  688.         POP        PSW
  689.         POP        ACC
  690.         RETI
  691. ;************************
  692. pppuuu:
  693. nop
  694. nop
  695. nop
  696. nop
  697. nop
  698. nop
  699. nop
  700. nop
  701.   nop
  702. nop
  703. nop
  704. nop
  705.   nop
  706. nop
  707. nop
  708. nop
  709.   nop
  710. nop
  711. nop
  712. nop
  713.   nop
  714. nop
  715. nop
  716. nop
  717.   nop
  718. nop
  719. nop
  720. nop
  721.   nop
  722. nop
  723. nop
  724. nop
  725.   nop
  726. nop
  727. nop
  728. nop
  729.   nop
  730. nop
  731. nop
  732. nop
  733.   nop
  734. nop
  735. nop
  736. nop
  737.   nop
  738. nop
  739. nop
  740. nop
  741.   nop
  742. nop
  743. nop
  744. nop
  745. lcall START
  746. nop
  747. nop
  748. nop

  750. ……………………

  752. …………限于本文篇幅 余下代碼請從51黑下載附件…………
復(fù)制代碼
0.png
所有資料51hei提供下載:
源碼和hex.rar (8.02 KB, 下載次數(shù): 41)

評分

參與人數(shù) 1黑幣 +100 收起 理由
admin + 100 共享資料的黑幣獎勵！

查看全部評分

回復(fù)

使用道具 舉報

ID:286600 發(fā)表于 2018-3-3 10:34 | 顯示全部樓層
若配個脈沖電源對電瓶充電，這是個很好的配件。普通充電器用的是開關(guān)電源無脈沖。老式變壓器整流不濾波是脈沖，但要注意變壓器輸出電壓不要太高了，據(jù)我的經(jīng)驗48V電瓶不要超過46伏，45V比較合適，46×1.41已經(jīng)超過普通充電器轉(zhuǎn)燈前的電壓了。（有的說法是變壓器次級輸出電壓要比電瓶標(biāo)稱值高1到2V，我不認可。）
      普通充電器轉(zhuǎn)燈后電壓是55.6V左右，冬天不用此保護也可。夏天環(huán)境溫度高，電瓶充到55.6V就過充了。此保護器第8檔，充到53.7V就停充電，可有效地進行保護。
     鉛電瓶有負溫度系數(shù)，冬天充電終止電壓高些，夏天低些。
回復(fù)

使用道具 舉報

ID:265635 發(fā)表于 2018-3-3 15:12 | 顯示全部樓層
全匯編，贊一下！
回復(fù)

使用道具 舉報

ID:286600 發(fā)表于 2018-3-8 10:39 | 顯示全部樓層
少有人關(guān)注本貼。
1、看來群里人真富，都開汽車沒人騎電動車了。
2、用匯編的人也越來越少了。
回復(fù)

使用道具 舉報

ID:162136 發(fā)表于 2018-3-21 16:04 | 顯示全部樓層
看到全是匯編，我贊一個。
回復(fù)

使用道具 舉報

ID:295097 發(fā)表于 2018-3-21 16:26 | 顯示全部樓層
什么時候才能變成你這么厲害

回復(fù)

使用道具 舉報

ID:91721 發(fā)表于 2019-6-25 11:57 | 顯示全部樓層
全匯編，贊一下！
回復(fù)

使用道具 舉報

ID:165363 發(fā)表于 2019-6-26 09:43 | 顯示全部樓層
匯編的啊，有點難看懂。
回復(fù)

使用道具 舉報

ID:159857 發(fā)表于 2020-5-14 21:49 | 顯示全部樓層

全匯編，贊一下！樓主厲害！
回復(fù)

使用道具 舉報

ID:733231 發(fā)表于 2020-5-18 19:53 | 顯示全部樓層


全匯編，贊一下！樓主厲害！向你學(xué)習(xí)~~~
回復(fù)

使用道具 舉報

ID:58628 發(fā)表于 2025-4-9 11:10 來自手機 | 顯示全部樓層
有沒有誰有網(wǎng)上賣的那種電動車充電保護器，檢測輸入側(cè)的電流原理種程序
回復(fù)

使用道具 舉報

您需要登錄后才可以回帖 登錄 | 立即注冊

本版積分規(guī)則

手機版|小黑屋|51黑電子論壇 |51黑電子論壇6群 QQ 管理員QQ:125739409;技術(shù)交流QQ群281945664

Powered by 單片機教程網(wǎng)

快速回復(fù) 返回頂部 返回列表