19課:單片機(jī)定時(shí)器、中斷試驗(yàn)

ID:1 · 發(fā)表于 2013-5-21 03:14

我們?cè)趯W(xué)單片機(jī)時(shí)我們第一個(gè)例程就是燈的閃爍，那是用延時(shí)程序做的，現(xiàn)在回想起來(lái)，這樣做不很恰當(dāng)，為什么呢？我們的主程序做了燈的閃爍，就不能再干其它的事了，難道單片機(jī)只能這樣工作嗎？當(dāng)然不是，我們能用定時(shí)器來(lái)實(shí)現(xiàn)燈的閃爍的功能。例1：查詢方式
ORG 0000H
AJMP START
ORG 30H
START:
MOV P1,#0FFH ;關(guān)所燈
MOV TMOD,#00000001B ;定時(shí)/計(jì)數(shù)器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即數(shù)5536
SETB TR0 ;定時(shí)/計(jì)數(shù)器0開(kāi)始運(yùn)行
LOOP:JBC TF0,NEXT ;如果TF0等于1，則清TF0并轉(zhuǎn)NEXT處
AJMP LOOP ;不然跳轉(zhuǎn)到LOOP處運(yùn)行
NEXT:CPL P1.0
MOV TH0,#15H
MOV TL0,#9FH;重置定時(shí)/計(jì)數(shù)器的初值
AJMP LOOP
END AJMP LOOP
END
鍵入程序，看到了什么？燈在閃爍了，這可是用定時(shí)器做的，不再是主程序的循環(huán)了。簡(jiǎn)單地分析一下程序，為什么用JBC呢？TF0是定時(shí)/計(jì)數(shù)器0的溢出標(biāo)記位，當(dāng)定時(shí)器產(chǎn)生溢出后，該位由0變1，所以查詢?cè)撐痪涂芍顣r(shí)時(shí)間是否已到。該位為1后，要用軟件將標(biāo)記位清0，以便下一次定時(shí)是間到時(shí)該位由0變1，所以用了JBC指令，該指位在判1轉(zhuǎn)移的同時(shí)，還將該位清0。
以上程序是能實(shí)現(xiàn)燈的閃爍了，可是主程序除了讓燈閃爍外，還是不能做其他的事��！不，不對(duì)，我們能在LOOP：……和AJMP LOOP指令之間插入一些指令來(lái)做其他的事情，只要保證執(zhí)行這些指令的時(shí)間少于定時(shí)時(shí)間就行了。那我們?cè)谟密浖訒r(shí)程序的時(shí)候不是也能用一些指令來(lái)替代DJNZ嗎？是的，但是那就要求你精確計(jì)算所用指令的時(shí)間，然后再減去對(duì)應(yīng)的DJNZ循環(huán)次數(shù)，很不方便，而現(xiàn)在只要求所用指令的時(shí)間少于定時(shí)時(shí)間就行，顯然要求低了。當(dāng)然，這樣的辦法還是不好，所以我們常用以下的辦法來(lái)實(shí)現(xiàn)。
程序2：用中斷實(shí)現(xiàn)
ORG 0000H ,http://www.torrancerestoration.com
AJMP START
ORG 000BH ;定時(shí)器0的中斷向量地址
AJMP TIME0 ;跳轉(zhuǎn)到真正的定時(shí)器程序處
ORG 30H
START:
MOV P1,#0FFH ;關(guān)所燈
MOV TMOD,#00000001B ;定時(shí)/計(jì)數(shù)器0工作于方式1
MOV TH0,#15H
MOV TL0,#0A0H ;即數(shù)5536
SETB EA ;開(kāi)總中斷允許
SETB ET0 ;開(kāi)定時(shí)/計(jì)數(shù)器0允許
SETB TR0 ;定時(shí)/計(jì)數(shù)器0開(kāi)始運(yùn)行
LOOP: AJMP LOOP ;真正工作時(shí),這里可寫任意程序
TIME0: ;定時(shí)器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
CPL P1.0
MOV TH0,#15H
MOV TL0,#0A0H ;重置定時(shí)常數(shù)
POP PSW
POP ACC
RETI
END
上面的例程中，定時(shí)時(shí)間一到，TF0由0變1，就會(huì)引發(fā)中斷，CPU將自動(dòng)轉(zhuǎn)至000B處尋找程序并執(zhí)行，由于留給定時(shí)器中斷的空間只有8個(gè)字節(jié)，顯然不足以寫下所有有中斷處理程序，所以在000B處安排一條跳轉(zhuǎn)指令，轉(zhuǎn)到實(shí)際處理中斷的程序處，這樣，中斷程序能寫在任意地方，也能寫任意長(zhǎng)度了。進(jìn)入定時(shí)中斷后，首先要保存當(dāng)前的一些狀態(tài)，程序中只演示了保存存ACC和PSW，實(shí)際工作中應(yīng)該根據(jù)需要將可能會(huì)改變的單元的值都推入堆棧進(jìn)行保護(hù)（本程序中實(shí)際不需保存護(hù)任何值，這里只作個(gè)演示）。
上面的兩個(gè)單片機(jī)程序運(yùn)行后，我們發(fā)現(xiàn)燈的閃爍非�？�，根本分辨不出來(lái)，只是視覺(jué)上感到燈有些晃動(dòng)而已，為什么呢？我們能計(jì)算一下，定時(shí)器中預(yù)置的數(shù)是5536，所以每計(jì)60000個(gè)脈沖就是定時(shí)時(shí)間到，這60000個(gè)脈沖的時(shí)間是多少呢？我們的晶體震蕩器是12M，所以就是60000微秒，即60毫秒，因此速度是非�？斓摹Ｈ绻蚁雽�(shí)現(xiàn)一個(gè)1S的定時(shí)，該怎么辦呢？在該晶體震蕩器瀕率下，最長(zhǎng)的定時(shí)也就是65。536個(gè)毫秒��！上面給出一個(gè)例程。
ORG 0000H
AJMP START
ORG 000BH ;定時(shí)器0的中斷向量地址
AJMP TIME0 ;跳轉(zhuǎn)到真正的定時(shí)器程序處
ORG 30H
START:
MOV P1,#0FFH ;關(guān)所燈
MOV 30H,#00H ;軟件計(jì)數(shù)器預(yù)清0
MOV TMOD,#00000001B ;定時(shí)/計(jì)數(shù)器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數(shù)15536
SETB EA ;開(kāi)總中斷允許
SETB ET0 ;開(kāi)定時(shí)/計(jì)數(shù)器0允許
SETB TR0 ;定時(shí)/計(jì)數(shù)器0開(kāi)始運(yùn)行
LOOP: AJMP LOOP ;真正工作時(shí),這里可寫任意程序
TIME0: ;定時(shí)器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
INC 30H
MOV A,30H
CJNE A,#20,T_RET ;30H單元中的值到了20了嗎?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清軟件計(jì)數(shù)器
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時(shí)常數(shù)
POP PSW
POP ACC
RETI
END
先自己分析一下，看看是怎么實(shí)現(xiàn)的？這里采用了軟件計(jì)數(shù)器的概念，思路是這樣的，先用定時(shí)/計(jì)數(shù)器0做一個(gè)50毫秒的定時(shí)器，定時(shí)是間到了以后并不是立即取反P10，而是將軟件計(jì)數(shù)器中的值加1，如果軟件計(jì)數(shù)器計(jì)到了20，就取反P10，并清掉軟件計(jì)數(shù)器中的值，不然直接返回，這樣，就變成了20次定時(shí)中斷才取反一次P10，因此定時(shí)時(shí)間就延長(zhǎng)了成了20*50即1000毫秒了。
這個(gè)思路在工程中是非常有用的，有的時(shí)候我們需要若干個(gè)定時(shí)器，可51中總共才有2個(gè)，怎么辦呢？其實(shí)，只要這幾個(gè)定時(shí)的時(shí)間有一定的公約數(shù)，我們就能用軟件定時(shí)器加以實(shí)現(xiàn)，如我要實(shí)現(xiàn)P10口所接燈按1S每次，而P11口所接燈按2S每次閃爍，怎么實(shí)現(xiàn)呢？對(duì)了我們用兩個(gè)計(jì)數(shù)器，一個(gè)在它計(jì)到20時(shí)，取反P10，并清零，就如上面所示，另一個(gè)計(jì)到40取反P11，然后清0，不就行了嗎？這部份的程序如下
ORG 0000H
AJMP START
ORG 000BH ;定時(shí)器0的中斷向量地址
AJMP TIME0 ;跳轉(zhuǎn)到真正的定時(shí)器程序處
ORG 30H
START:
MOV P1,#0FFH ;關(guān)所燈
MOV 30H,#00H ;軟件計(jì)數(shù)器預(yù)清0
MOV TMOD,#00000001B ;定時(shí)/計(jì)數(shù)器0工作于方式1
MOV TH0,#3CH
MOV TL0,#0B0H ;即數(shù)15536
SETB EA ;開(kāi)總中斷允許
SETB ET0 ;開(kāi)定時(shí)/計(jì)數(shù)器0允許
SETB TR0 ;定時(shí)/計(jì)數(shù)器0開(kāi)始運(yùn)行
LOOP: AJMP LOOP ;真正工作時(shí),這里可寫任意程序
TIME0: ;定時(shí)器0的中斷處理程序
PUSH ACC
PUSH PSW ;將PSW和ACC推入堆棧保護(hù)
INC 30H
INC 31H ;兩個(gè)計(jì)數(shù)器都加1
MOV A,30H
CJNE A,#20,T_NEXT ;30H單元中的值到了20了嗎?
T_L1: CPL P1.0 ;到了,取反P10
MOV 30H,#0 ;清軟件計(jì)數(shù)器
T_NEXT:
MOV A,31H
CJNE A,#40,T_RET ;31h單元中的值到40了嗎?
T_L2:
CPL P1.1
MOV 31H,#0 ;到了,取反P11,清計(jì)數(shù)器,返回
T_RET:
MOV TH0,#15H
MOV TL0,#9FH ;重置定時(shí)常數(shù)
POP PSW
POP ACC
RETI
END
您能用定時(shí)器的辦法實(shí)現(xiàn)前面講的流水燈嗎？試試看。

ID:229981 · 發(fā)表于 2018-3-8 23:33

跟著例子做的定時(shí)器中斷實(shí)現(xiàn)流水燈實(shí)驗(yàn)，歡迎指正錯(cuò)誤（沒(méi)鎖大寫通篇小寫，湊活著看看吧

）

org 0000h
ajmp start
org 000bh
ajmp time0
org 30h
start:
  mov p1,#0feh             ；賦值11111110b，為了實(shí)現(xiàn)流水，先打開(kāi)了一顆燈
  mov 30h,#00h
  mov tmod,#00000001b
  mov th0,#3ch
  mov tl0,#0b0h
  setb ea
  setb et0
  setb tr0
loop:ajmp loop
time0:
  push acc
  push psw
  inc 30h
  mov a,30h
  cjne a,20,t_next
  t_0:
mov a,p1
rl a                      ；左移一位
mov p1,a
mov 30h,#0
  t_next:
mov th0,#15h
mov tl0,#9fh

  pop psw
  pop acc
  reti
end

ID:52972 · 發(fā)表于 2013-8-15 11:14

非常好，謝謝

ID:44124 · 發(fā)表于 2013-8-17 15:06

學(xué)習(xí)了，謝謝分享。

ID:61875 · 發(fā)表于 2014-6-5 14:09

謝謝樓主軟件通過(guò)下載試驗(yàn)收獲很大。

ID:63706 · 發(fā)表于 2014-7-15 15:35

支持樓主

ID:11942 · 發(fā)表于 2015-1-4 10:05

#在學(xué)習(xí)了非常好這里快支持樓主速回復(fù)#

ID:73372 · 發(fā)表于 2015-2-7 17:21

怎么感覺(jué)有點(diǎn)難，是不是我太笨了？

ID:73372 · 發(fā)表于 2015-2-7 17:31

我有一頭小毛驢我從來(lái)也不騎

ID:69582 · 發(fā)表于 2015-4-21 10:21

我想要c語(yǔ)言的，，，，

ID:77523 · 發(fā)表于 2015-4-23 08:37

感謝分享～�。�！

ID:73815 · 發(fā)表于 2015-6-2 14:16

此文講解非常清楚初學(xué)者一看一目了然加快了初學(xué)者學(xué)習(xí)決心

ID:73815 · 發(fā)表于 2015-6-2 14:25

1說(shuō)理清楚使學(xué)者一目了然

ID:89451 · 發(fā)表于 2015-9-6 20:24

好，非常感謝。謝謝

ID:99529 · 發(fā)表于 2015-12-19 12:06

wsfa aewfaewf

ID:107365 · 發(fā)表于 2016-4-6 16:25

回帖支持！

ID:84465 · 發(fā)表于 2016-6-26 14:32

看君一貼編程實(shí)例，勝讀十天書。謝謝樓主，學(xué)習(xí)了，

ID:144161 · 發(fā)表于 2016-10-24 09:04

很好，謝謝

ID:90566 · 發(fā)表于 2016-11-15 23:14

怎么不是C呀！

ID:150292 · 發(fā)表于 2016-12-17 14:16

目測(cè)匯編的用最必要的步驟實(shí)現(xiàn)，省去了不必要的步驟

ID:191531 · 發(fā)表于 2017-4-20 11:22

很棒

ID:227622 · 發(fā)表于 2017-8-16 19:44

非常詳細(xì)

ID:241273 · 發(fā)表于 2017-10-20 15:08

匯編看著舒不舒服，但簡(jiǎn)單直接

ID:241899 · 發(fā)表于 2017-10-22 19:33

學(xué)習(xí)了，謝謝分享

。

ID:237160 · 發(fā)表于 2017-11-23 09:48

看著匯編代碼腦袋疼

ID:269211 · 發(fā)表于 2018-2-7 23:24

學(xué)習(xí)了，謝謝分享

ID:281214 · 發(fā)表于 2018-2-11 22:13

謝謝老師！受益非淺。

ID:145504 · 發(fā)表于 2018-4-30 09:08

可惜不是c寫的，看不懂

ID:93625 · 發(fā)表于 2018-6-26 13:54

繼續(xù)學(xué)習(xí)，感謝樓主了。

ID:442473 · 發(fā)表于 2019-1-29 12:33

沒(méi)學(xué)匯編

ID:691354 · 發(fā)表于 2020-2-12 14:47

樓主能解釋一下那個(gè)END AJMP LOOP啥意思嗎，還有他后面的END是多余的

ID:691354 · 發(fā)表于 2020-2-12 18:44

ORG 0000H AJMP START ORG 000BH AJMP TIME0 ORG 30H START: MOV P2,#0FEH MOV 30H,#00H MOV TMOD,#00000001B MOV TH0,#15H MOV TL0,#0A0H SETB ET0 SETB EA SETB TR0 LOOP: AJMP LOOP TIME0: PUSH ACC PUSH PSW INC 30H MOV A,30H CJNE A,#20,T_L1 T_L2: MOV A,P2 RL A MOV P2,A MOV 30H,#00H T_L1: MOV TH0,#15H MOV TL0,#9FH POP PSW POP ACC RETI END

ID:126173 · 發(fā)表于 2020-3-9 22:57

就喜歡匯編代碼的簡(jiǎn)潔有力，清晰明了

ID:280454 · 發(fā)表于 2021-11-3 16:08

是不是少了一句？31H沒(méi)有賦初值吧？？

帳號(hào)		自動(dòng)登錄	找回密碼
密碼			立即注冊(cè)

19課:單片機(jī)定時(shí)器、中斷試驗(yàn)

瀏覽過(guò)的版塊

19課:單片機(jī)定時(shí)器、中斷試驗(yàn)