|
|
本帖最后由 liuqq 于 2015-5-22 00:02 編輯
- ;溫度傳感器18B20匯編程序,采用器件默認(rèn)的12位轉(zhuǎn)化,最大轉(zhuǎn)化時(shí)間750微秒
- ;將溫度數(shù)據(jù)通過串口發(fā)送出去，波特率2400
- ;本程序?qū)锳T89C51實(shí)驗(yàn)開發(fā)板編寫.適合12晶振
- ;本程序經(jīng)過驗(yàn)證,可以顯示溫度+/-和兩位整數(shù)溫度和兩位小數(shù)溫度數(shù)據(jù)
- DOT EQU 30H
- ZHENGSHU EQU 31H
- FLAG1 EQU 38H ;是否檢測到DS18B20的標(biāo)志位
- ;定義溫度數(shù)據(jù)
- DIS_1 EQU 32H ;符號
- DIS_2 EQU 33H ;十位
- DIS_3 EQU 34H ;個(gè)位
- DIS_4 EQU 35H ;小數(shù)點(diǎn)后第一位
- DIS_5 EQU 36H ;小數(shù)點(diǎn)后第二位
- WDDATA BIT P2.2 ;定義DS18B20的數(shù)據(jù)腳為P2.2端口
- ORG 0000H
- ;以下為主程序進(jìn)行CPU中斷方式設(shè)置
- CLR EA ;關(guān)閉總中斷
- MOV SCON,#50H ;設(shè)置成串口1方式
- MOV TMOD,#20H ;波特率發(fā)生器T1工作在模式2上
- MOV TH1,#0F3H ;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
- MOV TL1,#0F3H ;預(yù)置初值(按照波特率2400BPS預(yù)置初值)
- SETB TR1 ;啟動(dòng)定時(shí)器T1
- ;以上完成串口2400通訊初始化設(shè)置
- ;-------------------------
- ; 主程序
- ;-------------------------
- MAIN:
- LCALL INIT_1820 ;調(diào)用復(fù)位DS18B20子程序
- MAIN1:
- LCALL GET_TEMPER;調(diào)用讀溫度子程序
- LCALL FORMULA ;通過公式計(jì)算,小數(shù)點(diǎn)后顯示兩位
- LCALL BCD
- LCALL DISPLAY ;調(diào)用串口顯示子程序
- LCALL DELAY500 ;延時(shí)0.5秒
- LCALL DELAY500 ;延時(shí)0.5秒
- LCALL DELAY500 ;延時(shí)0.5秒
- AJMP MAIN1
- ;-------------------------
- ; DS18B20復(fù)位初始化程序
- ;-------------------------
- INIT_1820:
- SETB WDDATA
- NOP
- CLR WDDATA
- ;主機(jī)發(fā)出延時(shí)540微秒的復(fù)位低脈沖
- MOV R0,#36
- LCALL DELAY
- SETB WDDATA;然后拉高數(shù)據(jù)線
- NOP
- NOP
- MOV R0,#36
- TSR2:
- JNB WDDATA,TSR3;等待DS18B20回應(yīng)
- DJNZ R0,TSR2
- LJMP TSR4 ; 延時(shí)
- TSR3:
- SETB FLAG1 ; 置標(biāo)志位,表示DS1820存在
- LJMP TSR5
- TSR4:
- CLR FLAG1 ; 清標(biāo)志位,表示DS1820不存在
- LJMP TSR7
- TSR5:
- MOV R0,#06BH
- TSR6:
- DJNZ R0,TSR6 ;復(fù)位成功!時(shí)序要求延時(shí)一段時(shí)間
- TSR7:
- SETB WDDATA
- RET
- ;-------------------
- ; 讀出轉(zhuǎn)換后的溫度值
- ;-------------------
- GET_TEMPER:
- SETB WDDATA ; 定時(shí)入口
- LCALL INIT_1820 ;先復(fù)位DS18B20
- JB FLAG1,TSS2
- RET ; 判斷DS1820是否存在?若DS18B20不存在則返回
- TSS2:
- MOV A,#0CCH ; 跳過ROM匹配
- LCALL WRITE_1820
- MOV A,#44H ; 發(fā)出溫度轉(zhuǎn)換命令
- LCALL WRITE_1820
- MOV R0,#50 ;等待AD轉(zhuǎn)換結(jié)束,12位的話750微秒.
- LCALL DELAY
- LCALL INIT_1820 ;準(zhǔn)備讀溫度前先復(fù)位
- MOV A,#0CCH ; 跳過ROM匹配
- LCALL WRITE_1820
- MOV A,#0BEH ; 發(fā)出讀溫度命令
- LCALL WRITE_1820
- LCALL READ_18200; 將讀出的九個(gè)字節(jié)數(shù)據(jù)保存到60H-68H
- RET
- ;----------------------------------
- ;寫DS18B20的子程序(有具體的時(shí)序要求)
- ;----------------------------------
- WRITE_1820:
- MOV R2,#8 ;一共8位數(shù)據(jù)
- CLR C
- WR1:
- CLR WDDATA
- MOV R3,#6
- DJNZ R3,$
- RRC A
- MOV WDDATA,C
- MOV R3,#24
- DJNZ R3,$
- SETB WDDATA
- NOP
- DJNZ R2,WR1
- SETB WDDATA
- RET
- ;--------------------------------------------------
- ; 讀DS18B20的程序,從DS18B20中讀出九個(gè)字節(jié)的數(shù)據(jù)
- ;--------------------------------------------------
- READ_18200:
- MOV R4,#9
- MOV R1,#60H ; 存入60H開始的九個(gè)單元
- RE00:
- MOV R2,#8
- RE01:
- CLR C
- SETB WDDATA
- NOP
- NOP
- CLR WDDATA
- NOP
- NOP
- NOP
- SETB WDDATA
- MOV R3,#09
- RE10:
- DJNZ R3,RE10
- MOV C,WDDATA
- MOV R3,#23
- RE20:
- DJNZ R3,RE20
- RRC A
- DJNZ R2,RE01
- MOV @R1,A
- INC R1
- DJNZ R4,RE00
- RET
- ;------------------------
- ;溫度計(jì)算子程序
- ;------------------------
- FORMULA: ; 按公式：T實(shí)際=(T整數(shù)-0.25)+( M每度-M剩余)/ M每度
- ;計(jì)算出實(shí)際溫度，整數(shù)部分和小數(shù)部分分別存于ZHENGSHU單元和DOT單元
- ;將61H中的低4位移入60H中的高4位，得到溫度的整數(shù)部分，并存于ZHENGSHU單元
- MOV 29H,61H
- MOV A,60H
- MOV C,48H
- RRC A
- MOV C,49H
- RRC A
- MOV C,4AH
- RRC A
- MOV C,4BH
- RRC A
- MOV ZHENGSHU,A
- ; ( M每度-M剩余)/ M每度,小數(shù)值存于A中
- MOV A,67h
- SUBB A,66h
- MOV B,#64H
- MUL AB
- MOV R4,B
- MOV R5,A
- MOV R7,67H
- LCALL DIV457
- MOV A,R3
- ;再減去0.25，實(shí)際應(yīng)用中減去25
- SUBB A,#19H
- MOV DOT,A ;小數(shù)部分存于DOT中
- MOV A,ZHENGSHU
- SUBB A,#00H ;整數(shù)部分減去來自小數(shù)部分的借位
- MOV ZHENGSHU,A
- MOV C,4BH
- JNC ZHENG ;是否為負(fù)數(shù)
- CPL A
- INC A
- MOV DIS_1,#2DH ; 零度以下時(shí),第一位顯示"-"號
- MOV ZHENGSHU,A
- ZHENG:
- MOV DIS_1,#2BH ; 零度以上時(shí),第一位顯示"+"號
- RET
- ;------------------------
- ;雙字節(jié)除以單字節(jié)子程序
- ;------------------------
- DIV457: CLR C
- MOV A,R4
- SUBB A,R7
- JC DV50
- SETB OV ;商溢出
- RET
- DV50: MOV R6,#8 ;求平均值（R4R5／R7－→R3）
- DV51: MOV A,R5
- RLC A
- MOV R5,A
- MOV A,R4
- RLC A
- MOV R4,A
- MOV F0,C
- CLR C
- SUBB A,R7
- ANL C,/F0
- JC DV52
- MOV R4,A
- DV52: CPL C
- MOV A,R3
- RLC A
- MOV R3,A
- DJNZ R6,DV51
- MOV A,R4 ;四舍五入
- ADD A,R4
- JC DV53
- SUBB A,R7
- JC DV54
- DV53: INC R3
- DV54: CLR OV
- RET
- ;---------------------
- ;轉(zhuǎn)換成非壓縮的BCD碼
- ;---------------------
- BCD: MOV A,ZHENGSHU
- MOV B,#0AH
- DIV AB
- ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
- MOV DIS_2,A
- MOV DIS_3,B
- MOV A,DIS_3
- ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
- MOV DIS_3,A
- MOV A,DOT
- MOV B,#0AH
- DIV AB
- ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
- MOV DIS_4,A
- MOV DIS_5,B
- MOV A,DIS_5
- ORL A,#00110000B ;轉(zhuǎn)換成ASCII碼
- MOV DIS_5,A
- RET
- ;----------------------
- ;串口顯示數(shù)據(jù)子程序
- ;----------------------
- DISPLAY:
- CLR TI
- MOV A,DIS_1
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示+/-
- CLR TI
- MOV A,DIS_2
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第一位
- CLR TI
- MOV A,DIS_3
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示整數(shù)第二位
- CLR TI
- MOV A,#2EH
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)點(diǎn)
- CLR TI
- MOV A,DIS_4
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
- CLR TI
- MOV A,DIS_5
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示小數(shù)第一位
- CLR TI
- MOV A,#0DH;換行
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
- CLR TI
- MOV A,#0AH;換行
- MOV SBUF,A
- JNB TI,$ ;發(fā)送給PC,通過串口調(diào)試助手顯示
- RET
- ;----------------------
- ;延時(shí)子程序
- ;----------------------
- ;為保證DS18B20的嚴(yán)格I/O時(shí)序，需要做較精確的延時(shí)
- ;在DS18B20操作中，用到的延時(shí)有15 μs，90 μs，270 μs，540 μs
- ;因這些延時(shí)均為15 μs的整數(shù)倍，因此可編寫一個(gè)DELAY15（n）函數(shù)
- DELAY: ;11.05962M晶振
- LOOP: MOV R1,#06H
- LOOP1: DJNZ R1,LOOP1
- DJNZ R0,LOOP
- RET
- ;500毫秒延時(shí)子程序，占用R4、R5
- DELAY500:MOV R4,#248
- DA222:MOV R5,#248
- DJNZ R5,$
- DJNZ R4,DA222
- RET
- END
|
|
