找回密碼
 立即注冊

QQ登錄

只需一步，快速開始

搜索
查看: 14061|回復(fù): 5
打印 上一主題 下一主題
收起左側(cè)

單片機ADC0809 8路數(shù)據(jù)采集 查詢和中斷法 帶匯編程序和proteus仿真

[復(fù)制鏈接]
跳轉(zhuǎn)到指定樓層
樓主
ID:137190 發(fā)表于 2016-9-27 20:27 | 只看該作者 回帖獎勵 |倒序瀏覽 |閱讀模式
51單片機驅(qū)動單片機ADC0809做的數(shù)據(jù)采集系統(tǒng)原理圖如下（注意proteus中沒有ADC0809采用ADC0808代替也是一樣的）：


所有的資料打包下載： ADC0809 8路數(shù)據(jù)采集系統(tǒng).zip (52.37 KB, 下載次數(shù): 200)


    AT89C51采用內(nèi)部的12MHz晶振，
ALE引腳的頻率是單片機時鐘周期頻率
的1/6，即2MHz。要想使ADC0808得到
500KHz的時鐘基準(zhǔn)，必須要把ALE輸出
進行4分頻，這樣ADC0808才能可靠的
工作。這里由于仿真軟件的原故，所以
直接給ADC0808的CLOCK端加了一個
500KHz的時鐘信號。
控制線如下：
（1）、P0.0、P0.1、P0.2控制ADC0808
的8個通道。
（2）、P2.7和/WR、/RD控制ADC0808
的啟動、地址鎖存和輸出


ADC0809 8路數(shù)據(jù)采集源碼：
  1. ;本程序用到單元(30H~34H,3DH,3EH)
  2. ;(30H~34H)用于存放顯示數(shù)據(jù)，(30H~33H)用于存放測量數(shù)據(jù)，34H用于存放通道號
  3. ;R1用于存放0809檢測出來的8個數(shù)據(jù)
  4. ;(3DH、3EH)用于存放0809檢測出來數(shù)據(jù)計算結(jié)果
  5.       ORG 0000H
  6.       AJMP MAIN
  7.       ORG 0013H
  8.       AJMP INT1
  9.       ORG 0030H
  10. ;======================================
  11. ;主程序
  12. MAIN: MOV R0,#30H      ;存放數(shù)據(jù)首地址
  13.       MOV R2,#0FH      ;計算數(shù)據(jù)存放單元個數(shù)
  14.       CLR A
  15. QING: MOV @R0,A        ;將數(shù)據(jù)存放單元清零
  16.       INC R0
  17.       DJNZ R2,QING
  18.       MOV R4,#08H      ;8路計數(shù)初值
  19.       MOV 34H,#00H     ;初始通道顯示單元為1號通道
  20.       SETB IT1         ;INT1置為邊沿觸發(fā)
  21.       SETB EA          ;開中斷
  22.       SETB EX1         ;允許INT1中斷
  23.       MOV DPTR,#7FF8H  ;指向0809通道0
  24.       MOV A,#00H       ;此指令可缺省
  25.       MOVX @DPTR,A     ;啟動A/D轉(zhuǎn)換
  26. HERE: ACALL JI_SUAN
  27.       AJMP HERE        ;等待中斷
  28. ;==========================================
  29. ;中斷子程序
  30. INT1: CLR EX1
  31.       PUSH PSW         ;保護現(xiàn)場
  32.       MOVX A,@DPTR     ;讀A/D轉(zhuǎn)換結(jié)果
  33.       MOV R1,A         ;存數(shù)據(jù)
  34.       INC DPTR         ;更新通道
  35.       MOV A,34H
  36.       INC A
  37.       MOV 34H,A
  38.       DJNZ R4,LOOP     ;巡回未完繼續(xù)
  39.       MOV R4,#08H      ;重新賦初值
  40.       MOV DPTR,#7FF8H
  41. LOOP:
  42.       MOVX @DPTR,A     ;啟動A/D轉(zhuǎn)換
  43.       POP PSW
  44.       RETI             ;返回中斷

  46. ;========================================
  47. ;數(shù)據(jù)計算
  48. JI_SUAN:
  49.       MOV A,R1
  50.       MOV B,#20        ;基準(zhǔn)電壓為5伏，分辨率為5/256約為20毫伏
  51.       MUL AB           ;顯示數(shù)值單位為毫伏
  52.       MOV R7,A         ;測量出來的數(shù)據(jù)乘20毫伏即為實際電壓值，但還是十六進制
  53.       MOV A,B          ;高位存放在R6里，低位存放在R7里
  54.       MOV R6,A
  55.       MOV R5,#16
  56. ;=========================================
  57. ;雙字節(jié)十六進制轉(zhuǎn)雙字節(jié)BCD碼
  58. SBIN_SBCD:
  59.       MOV 3DH,#00H     ;數(shù)據(jù)計算結(jié)果清零
  60.       MOV 3EH,#00H
  61. SBIN_SBCD1:
  62.       MOV A,R7  ;R7左移一位并送回
  63.       RLC A
  64.       MOV R7,A
  65.       MOV A,R6  ;R6左移一位并送回
  66.       RLC A
  67.       MOV R6,A
  68.       MOV A,3DH
  69.       ADDC A,3DH
  70.       DA A       ;T_S乘2并調(diào)整后送回
  71.       MOV 3DH,A
  72.       MOV A,3EH
  73.       ADDC A,3EH
  74.       DA A       ;T_M乘2并調(diào)整后送回
  75.       MOV 3EH,A
  76.       DJNZ R5,SBIN_SBCD1 ;循環(huán)運行24次得到BCD碼結(jié)果
  77. ;=====================================
  78. ;雙字節(jié)BCD碼制轉(zhuǎn)4個單字節(jié)BCD碼
  79. SBCD_DBCD:
  80.       MOV A,3DH
  81.       MOV B,A
  82.       ANL A,#0FH ;將T_S里面的數(shù)據(jù)存放寄存器B里后再進行與操作得到低四位
  83.       MOV 30H,A  ;并存放到數(shù)碼管顯示的第一位地址40H里面
  84.       MOV A,B
  85.       SWAP A     ;從寄存器取回原來保存的數(shù)，再進行高低位互換
  86.       ANL A,#0FH ;進行與操作后得到高四位
  87.       MOV 31H,A  ;最后存放到數(shù)碼管顯示的第二位地址41H里面
  88.       MOV A,3EH  ;同上
  89.       MOV B,A
  90.       ANL A,#0FH
  91.       MOV 32H,A
  92.       MOV A,B
  93.       SWAP A
  94.       ANL A,#0FH
  95.       MOV 33H,A

  97. ;=======================================
  98. ;顯示子程序

  100. DIS:     MOV R5,#50      ;顯示循環(huán)次數(shù)，即改變顯示延時刷新時間
  101. DIS1:    MOV R1,#30H      ;把顯示數(shù)據(jù)第一位放在R0里
  102.          MOV R2,#04H      ;把顯示的位碼放在R1里
  103.          MOV R3,#05H      ;把顯示的長度放在R2里
  104. DIS2:    MOV A,@R1
  105.          ANL A,#0FH       ;屏蔽顯示數(shù)據(jù)的高四位
  106.          MOV B,A
  107.          MOV A,R2
  108.          ANL A,#0FH       ;屏蔽位碼的高四位
  109.          SWAP A
  110.          ORL A,B
  111.          MOV P0,A         ;送總顯示數(shù)據(jù)到P0顯示
  112.          LCALL DELY4ms    ;調(diào)用延時4ms
  113.          INC R1           ;取下一個顯示數(shù)據(jù)
  114.          DEC R2
  115.          DJNZ R3,DIS2     ;四位顯示晚后重新開始顯示
  116.          DJNZ R5,DIS1
  117.          MOV A,34H        ;顯示完后判斷通道好是否為8
  118.          CJNE A,#08H,HUI
  119.          MOV 34H,#00H
  120. HUI:     SETB EX1         ;顯示完畢再允許中斷
  121.          RET
  122. ;=====================================
  123. ;延時子程序
  124. DELY4ms: MOV R6,#8         ;延時4毫秒
  125. D1:      MOV R7,#248
  126.          DJNZ R7,$
  127.          DJNZ R6,D1
  128.          RET
  129.          END
復(fù)制代碼

ADC0808中斷檢測源碼：
  1. ;占用單元R0,R1,A,DPTR,30H~37H
  2. ORG 0000H
  3. AJMP MAIN
  4. ORG 0013H
  5. AJMP INT1
  6. ORG 0030H
  7. MAIN: MOV R0,#30H      ;數(shù)據(jù)暫存區(qū)首地址
  8.       MOV R1,#08H      ;8路計數(shù)初值
  9.       SETB IT1         ;INT1置為邊沿觸發(fā)
  10.       SETB EA          ;開中斷
  11.       SETB EX1         ;允許INT1中斷
  12.       MOV DPTR,#7FF8H  ;指向0808通道0
  13.       MOV A,#00H       ;此指令可缺省
  14.       MOVX @DPTR,A     ;啟動A/D轉(zhuǎn)換
  15. HERE: NOP
  16.       AJMP HERE        ;等待中斷

  18. INT1: PUSH PSW
  19.       MOVX A,@DPTR     ;讀A/D轉(zhuǎn)換結(jié)果
  20.       MOV @R0,A        ;存數(shù)
  21.       INC DPTR         ;更新通道
  22.       INC R0           ;更新暫存單元
  23.       DJNZ R1,HUI      ;巡回未完繼續(xù)
  24.       MOV R0,#30H      ;數(shù)據(jù)暫存區(qū)首地址
  25.       MOV R1,#08H      ;8路計數(shù)初值
  26.       MOV DPTR,#7FF8H  ;指向0808通道0
  27. HUI:  MOVX @DPTR,A     ;再次啟動A/D轉(zhuǎn)換
  28.       POP PSW
  29.       RETI             ;返回中斷
復(fù)制代碼

ADC0808查詢檢測源程序：
  1. ;占用單元R0,R1,A,DPTR,30H~37H
  2. ORG 0000H
  3. AJMP MAIN
  4. ORG 0030H
  5. MAIN: MOV R0,#30H    ;數(shù)據(jù)暫存區(qū)首地址
  6.       MOV R1,#08H    ;8路計數(shù)初值
  7.       MOV DPTR,#7FF8H;指向0808通道0
  8.       MOV A,#00H     ;此指令可缺省
  9.       MOVX @DPTR,A   ;啟動A/D轉(zhuǎn)換
  10. L1:   JB P3.3,L1     ;查詢INT1是否為0
  11.       MOVX A,@DPTR   ;若INT1為0，者轉(zhuǎn)換結(jié)束，讀出數(shù)據(jù)
  12.       MOV @R0,A      ;存數(shù)
  13.       INC DPTR       ;更新通道
  14.       INC R0         ;更新暫存單元
  15.       MOVX @DPTR,A   ;再次啟動A/D轉(zhuǎn)換
  16.       DJNZ R1,L1     ;判斷8路查詢是否完畢
  17.       AJMP MAIN      ;跳回重新開始
  18.       END
復(fù)制代碼
分享到:  QQ好友和群QQ好友和群 QQ空間QQ空間 騰訊微博騰訊微博 騰訊朋友騰訊朋友
收藏收藏3 分享淘帖 頂頂1 踩踩
回復(fù)

使用道具 舉報

沙發(fā)
ID:187913 發(fā)表于 2017-4-9 22:49 | 只看該作者
謝謝樓主分享
回復(fù)

使用道具 舉報

板凳
ID:200970 發(fā)表于 2017-5-15 15:59 | 只看該作者
謝謝樓主，很有用..
回復(fù)

使用道具 舉報

地板
ID:200970 發(fā)表于 2017-5-15 16:00 | 只看該作者
感謝樓主
回復(fù)

使用道具 舉報

5#
ID:728732 發(fā)表于 2020-6-17 10:50 | 只看該作者
樓主有C語言版本的程序嗎，沒學(xué)過匯編
回復(fù)

使用道具 舉報

6#
ID:219315 發(fā)表于 2021-6-25 10:20 | 只看該作者
居然還有人在用匯編，很懷舊啊！
回復(fù)

使用道具 舉報

您需要登錄后才可以回帖 登錄 | 立即注冊

本版積分規(guī)則

手機版|小黑屋|51黑電子論壇 |51黑電子論壇6群 QQ 管理員QQ:125739409;技術(shù)交流QQ群281945664

Powered by 單片機教程網(wǎng)

快速回復(fù) 返回頂部 返回列表