[原創(chuàng)]詳細介紹用51單片機解密任何遙控器

  首先說一下 想寫這個帖子 看到論壇上有關(guān)于遙控器方面的帖子 但是都沒有很詳細的介紹 而且是已經(jīng)有完整的波形 僅僅介紹了解碼部分 而沒有分析波形數(shù)據(jù)方面的介紹 ，因此有了寫一篇完整的關(guān)于遙控器方面的文章的沖動 此貼對新手可能有點困難不過 不要緊 我會以最通俗的方式來解釋 如果有不明白的 建議去看看書 ，自己努力 沒有不可能的事 別人能做到 你也一定行，關(guān)于紅外遙控的基礎(chǔ)理論，大家可以到這個貼去看下http://www.torrancerestoration.com/mcu/184.html，里面有詳細的介紹。在這里我僅把一些關(guān)鍵的帶出來 關(guān)于硬件電路 那么拋開那么多文字介紹 最后意思就是說 你家里的遙控板 也就是發(fā)射部分 是把所有的封裝好了的 比如鍵盤矩陣、編碼調(diào)制、LED紅外發(fā)送器 等等 那么接受部分 SM0038 3個腳 一個腳地 一個腳電源 一個腳信號腳 接到 單片機隨便個P口上（此處是P3。6） OK 硬件部分就搞定了當(dāng)然還有數(shù)碼管顯示 ，這些肯定不用說你都能搞定吧，我這剛好有一塊51hei單片機學(xué)習(xí)板是在www.torrancerestoration.com的論壇買的，這些東東都有,所以就不用自己去搭電路那么麻煩了），那么 我們想 我們按一下遙控板 大家看到 有個燈閃了一下 然后OVER 那么 我們現(xiàn)在要做的就是在燈閃了那一下之后讓 單片機來讀它的鍵碼 然后不同的鍵碼來干不同的事 ，本文 是向大家解釋一種方法 當(dāng)然如果你知道遙控器的編碼 那么 我想寫解碼程序應(yīng)該是很簡單的事 而我的意思是說我們現(xiàn)在從0開始 拿到任何一種遙控板 那怕不知道它的型號 但是 大家想 即使它什么型號都沒寫 但是按一下不同的鍵 它的發(fā)射的脈沖 肯定不一樣 無非就是引導(dǎo)碼 然后 地址碼 鍵碼 驗證碼 因為不同的遙控板 它所定義的規(guī)則不一樣 （這里說一點題外話 其實在讀出波型后 大家就可以看出這個遙控板最開始設(shè)計時的人的意思 或者說考慮 它的這個設(shè)計方式是否是最好的 是否穩(wěn)定 是否具有通用性 或者說 日本的和中國的設(shè)計師 在設(shè)計時他們所考慮的 名牌和 雜牌的 他們在設(shè)計時所考慮的 等等 這些其實也是件很有意思的事 就像偷窺到一個人的內(nèi)心世界一樣 扯遠了 。。--）
  下面我們來說說本問利用51單片機軟件解密的方法 首先大家看了我剛才貼出來的連接 應(yīng)該知道了 編碼無非就是低電平高電平。但是我們知道一點 它肯定是有規(guī)律的 （這里申明一下 如果你能找到它的PDF 上面寫好了它的波形 或者你在網(wǎng)上找到了前人把某型號的遙控器的波形已經(jīng)分析出來了那么你完全可以把這篇帖子當(dāng)水貼 跳過 我這里的目的是想通過一種方法 一種 完整的分析方法  就像醫(yī)生拿起手術(shù)刀 解開它的內(nèi)部 看常人所不能看到的東西 最終能把一種很通用的東西 把它的內(nèi)部原理能夠完全的理解 一切從簡單學(xué)起 做起 以后凡是涉及到 這種 類型的東西 相信你會更加自信 而不是只滿足做一個課程設(shè)計 一個老師布置的作業(yè) 扯遠了。。  ）
  具體我們怎么記錄這種規(guī)律  很簡單 我們用定時器把每個高低電平的時間記下來 然后顯示在數(shù)碼管上 設(shè)置2秒顯示一個數(shù)據(jù) 然后用EXCLE記錄下來
再用鉛筆 或者 隨便什么畫圖軟件 把它的波形畫出來 標上 低電平 高電平 再對比下不同的鍵的區(qū)別 一切就豁然開朗了
 現(xiàn)在舉 實際的例子
萬能遙控板大家應(yīng)該都知道吧

           dec r1
           jb   p3.6,$          ;等待變低 , 即等待按鍵
next:      setb tr1             ;啟動定時器1
           jnb p3.6,$   ;  等待變高，以測量低電平時間寬度
           clr tr1      ;關(guān)閉定時器1                             ;1US
           inc r5       ;時間值個數(shù)加1                           ;1
           inc r1                                                ;1
           mov @r1,th1  ;存低電平時間值 ，先存高8位，后存低8位   ;2US
           inc r1                                                ;1
           mov @r1,tl1                                           ;2
           mov th1,#0   ;重賦初值                                ;2
           mov tl1,#13  ;13為停止T1到重啟T1經(jīng)過的時間            ;2
           setb tr1     ;重新啟動定時器                          ;1
           jb p3.6,$    ;等待變低
           clr tr1      ;關(guān)閉定時器1                             ;1
           inc r5                                                ;1
           inc r1                                                ;1
           mov @r1,th1  ;存高電平時間值                          ;2
           inc r1                                                ;1
           mov @r1,tl1                                           ;2
           mov th1,#0   ;重賦初值                                ;2
           mov tl1,#15  ;15為停止T1到重啟T1經(jīng)過的時間            ;2
           ajmp next    ;循環(huán)檢測，直到T1在遙控器無鍵按下時溢出時產(chǎn)生中斷   ;2
           ajmp $
;-----------------------------------------
 ;定時器1中斷程序
 ;在遙控器無鍵按下時產(chǎn)生中斷，便依次將BMHCQ中的高低電平時間值轉(zhuǎn)換為BCD碼并顯示出來
;-----------------------------------------
t1zd:
          setb tr0       ;啟動T0
          clr tr1        ;關(guān)閉T1
          setb et0       ;T0開中斷
          mov a,r5
          mov r2,a
          mov r3,#0
          lcall hextoxcq
          lcall display
          jb yszt,$           ;延時一段時間，以便記錄顯示的時間值
          setb yszt
          mov r0,#bmhcq
dispnext: mov a,@r0           ;從BMHCQ中依次取出時間值（16位）調(diào)BTOD子程序?qū)⑵滢D(zhuǎn)換為5位BCD碼并放入XCQ中再調(diào)顯示子程序顯示
          mov r3,a  ;取高8位
          inc r0
          mov a,@r0
          mov r2,a   ;取低8位
          inc r0
          ;lcall BtoD      ;將高電平或低電平時間值轉(zhuǎn)為BCD碼放于XCQ中
          lcall HEXtoXCQ   ;將高電平或低電平時間值轉(zhuǎn)為十六進制的LED碼放于XCQ中
          lcall display   ;顯示
          cpl p2.5        ;改變批示燈的狀態(tài)，以此說明顯示內(nèi)容的改變
          jb    yszt,$    ;延時，以便抄錄時間值
          setb  yszt
          djnz r5,dispnext ;獲取的時間值沒顯示完則繼續(xù)
          sjmp $           ;顯示完畢，在此踏步
          reti
         
 HEXtoXCQ:
          push 00h
          mov r0,#xcq
          mov a,r2
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov a,r2
          swap a
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
         
          mov a,r3
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov a,r3
          swap a
          anl a,#0fH
          mov dptr,#LED
          movc a,@a+dptr
          mov @r0,a
          inc r0
          mov @r0,#7eh
          inc r0
          mov @r0,#7eh
          pop 00H
          ret
 led:    db 7eh,30h,6dh,79h,33h,5bh,5fh,70h,7fh,7bh,77h,1fh,4eh,3dh,4fh,47h                         

;---------------------------------------------
;將存于R3R2中高電平或低電平時間值轉(zhuǎn)為BCD碼放于XCQ中
;---------------------------------------------
BtoD:
         push 00h
         mov r0,#BCD
         mov r4,#3
bd0:     mov @r0,#0       ;BCD緩沖區(qū)清0
         inc r0
         djnz r4,bd0
         mov r6,#16
bd1:     clr c            ;將R3R2中的16位二進制值轉(zhuǎn)換為三字節(jié)BCD碼存入BCD緩沖區(qū)中
         mov a,r3
         rlc a
         mov r3,a
         mov a,r2
         rlc a
         mov r2,a
         mov r4,#3
         mov r1,#bcd
BD3:     mov a, @r1
         addc a,@r1
         da a
         mov @r1,a
         inc r1
         djnz r4,bd3
         djnz r6,bd1
         mov r0,#xcq      ;將轉(zhuǎn)換結(jié)果從BCD緩沖中存入XCQ中
         mov r1,#bcd
         mov r4,#3
bd4:     mov a,@r1
         xchd a,@r0
         inc r0
         swap a
         xchd a,@r0
         inc r0
         inc r1
         djnz r4,bd4
         pop 00h
         ret

通過上面的程序我們讀出了按下一個鍵后的編碼的本質(zhì)的東西
  那么動手把 圖畫下來 找規(guī)律 解碼 
我把我例子長虹解碼后的波形圖 發(fā)出來

 01。JPG 是脈沖開始時所有鍵前8個完全一樣的高低脈沖

02.jpg (88.76 KB, 下載次數(shù): 204)

下載附件

2009-5-7 17:31 上傳

02。JPG 大家注意看按不同的鍵 中間只是有3個脈沖在變化 是EXCLE的 W列-AC列 而這3位數(shù)值就是我們解碼的關(guān)鍵 01。JPG 中8位數(shù) 大家應(yīng)該看出 所有鍵都是一樣的11100010 后面02。JPG中我們把鍵碼整理出來就是 
按1鍵 00000000  00H
按2鍵 00010000  10H
按3鍵 00001000  08H
按4鍵 00011000  18H
按5鍵 。。。。。
后面就不寫了
為了大家清晰可見 我把畫出的最后的波形圖03。JPG 貼出來 大家看下規(guī)律 

03.jpg (32.53 KB, 下載次數(shù): 201)

下載附件

2009-5-7 17:32 上傳

然后我們 來分析應(yīng)該怎么解碼 我相信到了這一步應(yīng)該很簡單了吧 比如在這個例子中 我們發(fā)現(xiàn) 后面的鍵碼改變的部分完全是重復(fù)