找回密碼
 立即注冊

QQ登錄

只需一步，快速開始

搜索
查看: 6001|回復(fù): 0
打印 上一主題 下一主題
收起左側(cè)

51單片機(jī)匯編語言實(shí)現(xiàn)交通燈 代碼有詳細(xì)注釋

[復(fù)制鏈接]
跳轉(zhuǎn)到指定樓層
樓主
用51單片機(jī)實(shí)現(xiàn)一個(gè)交通燈的控制
交通燈的變化模式為：初始化狀態(tài)為東西紅燈都亮→延遲 3s 變?yōu)闁|西方向綠燈，南北方向紅燈→過 20S 后，東西方向變黃燈，南北方向依然是紅燈→過 3S，東西方向變紅燈，南北方向變綠燈→過 30S 后，東西方向依然為紅燈，南北方向變黃燈→過 3S 后變?yōu)闁|西綠燈， 南北紅燈，依次循環(huán)。

交通燈模塊電路板如圖
其中， J0 和 J0’是電源插座， POWER 為電源開關(guān)， P0 為 P0.0~P0.7 插座，對就數(shù)碼管段碼（a～f）， P1 為 P1.0~P1.7 插。
P1.0 連接?xùn)|西紅燈， P1.1 連接南北紅燈， P1.2 連接?xùn)|西綠燈， P1.3 連接南北綠燈， P1.4連接?xùn)|西黃燈， P1.5 連接南北黃燈， P1.6 連接?xùn)|西車 ， P1.7 連接南北車； P2.0 為 LED1和 LED3 的位選， P2.1 為 LED2 和 LED4 的位選， P2.2 為 LED5 和 LED7 的位選， P2.3 為LED6 和 LED8 的位選； P3.2 東西緊急按鈕， P3.3 南北緊急按鈕
當(dāng)按下緊急按鈕，對應(yīng)的通路會(huì)變?yōu)槌＞G，同時(shí)本方向表示車的LED亮起，用以表示有救護(hù)車通過等緊急情況
通過匯編語言基于KEILC51實(shí)現(xiàn)
通過實(shí)際觀察發(fā)現(xiàn)  由于按鍵是中斷實(shí)現(xiàn)，故沒有添加去抖，導(dǎo)致按下緊急按鈕后可能沒有進(jìn)入中斷狀態(tài)，這個(gè)可以通過數(shù)碼管的顯示來判斷，當(dāng)數(shù)碼管顯示暫停，說明進(jìn)入緊急中斷；當(dāng)再次按下時(shí)，數(shù)碼管繼續(xù)跑數(shù)字，則退出了中斷。還有一點(diǎn)做的不太好，沒有做好現(xiàn)場保存，當(dāng)退出緊急中斷的時(shí)候，紅綠燈無法立刻恢復(fù)到原狀態(tài)，當(dāng)此狀態(tài)時(shí)間跑過，LED會(huì)直接顯示下一個(gè)狀態(tài)。
初學(xué)單片機(jī)的新手歡迎各位大佬指正
代碼放入了附件部分 備有詳細(xì)的注釋


單片機(jī)源程序如下:
  1.         ORG 0000H;程序起始地址
  2.         LJMP START;初始化標(biāo)號(hào)
  3.         ORG 0003H;外部中斷地址--東西緊急按鈕觸發(fā)
  4.         LJMP DXJJ;東西緊急標(biāo)號(hào)
  5.         ORG 0013H;外部中斷地址--南北緊急按鈕觸發(fā)
  6.         LJMP NBJJ;南北緊急標(biāo)號(hào)
  7.         ORG 000BH;定時(shí)器T0中斷地址        
  8.         LJMP OT         ;定時(shí)器T0標(biāo)號(hào)
  9.         ORG 0100H;程序起始位置
  10. START:        SETB EA         ;中斷允許        
  11.         SETB ET0 ;允許定時(shí)器T0中斷
  12.         CLR IT0 ;設(shè)置外部中斷為電平觸發(fā)
  13.         CLR IT1 ;同上
  14.         SETB EX0 ;允許外部中斷
  15.         SETB EX1 ;同上
  16.         SETB PX0 ;設(shè)置外部中斷優(yōu)先級(jí)高于定時(shí)器中斷
  17.         SETB PX1 ;
  18.         CLR PT0         ;
  19.         MOV TMOD,#01H;設(shè)置定時(shí)器模式1
  20.         MOV TH0,#3CH ;
  21.         MOV TL0,#0B0H;設(shè)置定時(shí)器初值--50ms
  22.         SETB TR0     ;開啟定時(shí)器        

  24. MAIN:        MOV R0,#20;設(shè)置R0 記錄20個(gè)50ms 產(chǎn)生1s
  25.         MOV R1,#56;設(shè)置主時(shí)間判斷時(shí)間軸 表示循環(huán)周期
  26.         MOV R2,#3 ;
  27.         MOV R3,#3 ;東西南北初始紅燈時(shí)間為3S
  28.         MOV R4,#0FCH;初始全紅 1111 1100
  29.         MOV 70H,#0;判斷是否按下了緊急按鈕的標(biāo)志位 0 第一次按（進(jìn)入緊急狀態(tài)） 1 第二次按（退出緊急狀態(tài)）
  30.         MOV R7,#00H ;判斷是要執(zhí)行緊急程序還是正常交通燈顯示  00H正常交通燈 01H 東西緊急 02H南北緊急
  31. XS:        LCALL DISPLAY;調(diào)用顯示程序
  32.         LJMP XS     ;循環(huán)進(jìn)行顯示
  33.         SJMP [        DISCUZ_CODE_3        ]nbsp;     ;死循環(huán) 保護(hù)程序執(zhí)行？ 可能沒用

  35. OT:        CJNE R7,#00H,PD ;R7不等于0跳轉(zhuǎn)判斷是哪個(gè)緊急，R7=0 說明未中斷正常跑程序
  36. ZCP:        DJNZ R0,OVER2;        ;R0 不為零說明沒有記夠20個(gè)50ms即沒有產(chǎn)生1s，跳出中斷等待下一次50ms產(chǎn)生中斷信號(hào)
  37.         MOV TH0,#3CH ;
  38.         MOV TL0,#0B0H;記完一次50ms 重新裝載定時(shí)器初值
  39.         DEC R1        ;進(jìn)入此部分說明已經(jīng)經(jīng)過了1s 那么總時(shí)間-1
  40.         DEC R2        ;顯示時(shí)間-1
  41.         DEC R3        ;顯示時(shí)間-1
  42. KK1:        CJNE R1,#53,KK2        ;判斷是否經(jīng)過了3s 到達(dá)了第一個(gè)狀態(tài)（初始狀態(tài)全紅為第狀態(tài)）
  43.         MOV R2,#20        ;
  44.         MOV R3,#23        ;賦值顯示
  45.         MOV R4,#0F9H;DX綠，NB紅 1111 1001
  46.         LJMP OVER2
  47. KK2:        CJNE R1,#33,KK3        ;判斷是否又經(jīng)過了20s 到達(dá)了第二個(gè)狀態(tài)
  48.         MOV R2,#3        ;賦值顯示
  49.         MOV R4,#0EDH;DX黃，NB紅 1110 1101
  50.         LJMP OVER2
  51. KK3:        CJNE R1,#30,KK4        ;判斷是否又經(jīng)過了3s 到達(dá)了第三個(gè)狀態(tài)
  52.         MOV R2,#33        ;
  53.         MOV R3,#30        ;賦值顯示
  54.         MOV R4,#0F6H;DX紅，NB綠 1111 0110
  55.         LJMP OVER2
  56. KK4:        CJNE R1,#0,OVER1 ;判斷是否又經(jīng)過了30s 到達(dá)了第四個(gè)狀態(tài)   此時(shí)為了跳出中斷 還不能重新賦值記錄50ms的個(gè)數(shù) 采用了OVER1和OVER2
  57.         MOV R3,#3        ;賦值顯示
  58.         MOV R4,#0DEH;DX紅，NB黃 1101 1110
  59.         MOV R1,#56        ;重新賦值總時(shí)間
  60. OVER1:        MOV R0,#20        ;重新賦值20 以產(chǎn)生1s
  61. OVER2:        RETI                 ;跳出中斷 如果用ERT是跳出子程序調(diào)用 兩者有區(qū)別！

  63. PD:        CJNE R7,#01H,NB;判斷是哪種緊急 01H 是DX緊急  02H是NB緊急
  64. DX:        MOV R4,#0B9H;DXJJ將東西車和綠燈打開，將南北燈變紅 1011 1001
  65.         MOV P2,#0FFH;關(guān)掉數(shù)碼管選通 達(dá)到暫停數(shù)碼管效果
  66.         RETI
  67. NB:        MOV R4,#76H;NBJJ將南北車和南北綠燈打開，將東西燈變紅 0111 0110
  68.         MOV P2,#0FFH;關(guān)掉數(shù)碼管選通 達(dá)到暫停數(shù)碼管效果
  69.         RETI

  71. DXJJ:        JB 70H,OFF1;判斷是否第一次按下緊急按鈕
  72. ON1:        CPL 70H           ;按下一次后就翻轉(zhuǎn) 下次就能檢測出是第二次
  73.         MOV R7,#01H;第一次按下說明開啟中斷 那么進(jìn)入緊急狀態(tài) 緊急狀態(tài)標(biāo)志變?yōu)?01H表示產(chǎn)生東西中斷
  74.         LJMP OUT1
  75. OFF1:        CPL 70H           ;如果要關(guān)掉中斷那么也要對標(biāo)志位取反 下次就能檢測出是要開啟
  76.         MOV R7,#00H;第二次按下說明是關(guān)閉中斷 緊急標(biāo)志變?yōu)?00H進(jìn)入正常交通燈顯示
  77. OUT1:        RETI

  79. NBJJ:        JB 70H,OFF2;道理同上
  80. ON2:        CPL 70H
  81.         MOV R7,#02H
  82.         LJMP OUT2
  83. OFF2:        CPL 70H
  84.         MOV R7,#00H
  85. OUT2:        RETI

  87. DISPLAY:MOV DPTR,#TAB;東西的數(shù)碼管十位顯示
  88.         MOV A,R2;
  89.         MOV B,#10
  90.         DIV AB
  91.         MOVC A,@A+DPTR;
  92.         MOV P2,#11111101B;
  93.         MOV P0,A
  94.         LCALL YS
  95.         MOV DPTR,#TAB;東西的數(shù)碼管個(gè)位顯示
  96.         MOV A,B;
  97.         MOVC A,@A+DPTR;
  98.         MOV P2,#11111110B
  99.         MOV P0,A;
  100.         LCALL YS
  101.         MOV DPTR,#TAB;南北的數(shù)碼管十位顯示
  102.         MOV A,R3;
  103.         MOV B,#10
  104.         DIV AB
  105.         MOVC A,@A+DPTR;
  106.         MOV P2,#11110111B;
  107.         MOV P0,A
  108.         LCALL YS
  109.         MOV DPTR,#TAB;南北的數(shù)碼管個(gè)位顯示
  110.         MOV A,B;
  111.         MOVC A,@A+DPTR;
  112.         MOV P2,#11111011B
  113.         MOV P0,A;
  114.         LCALL YS
  115.         
  116.         MOV P1,R4;紅綠燈的顯示
  117.         LCALL YS
  118.         RET

  120. YS:        MOV R5,#150 ;延時(shí)函數(shù)
  121. JY:        DJNZ R5,JY ;減一操作
  122.         RET

  124. TAB: DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H,7FH,6FH;數(shù)碼管共陰極


  127. END
復(fù)制代碼

hex下載:
TraficLight.zip (14.31 KB, 下載次數(shù): 21)

分享到:  QQ好友和群QQ好友和群 QQ空間QQ空間 騰訊微博騰訊微博 騰訊朋友騰訊朋友
收藏收藏 分享淘帖 頂頂 踩踩
回復(fù)

使用道具 舉報(bào)

您需要登錄后才可以回帖 登錄 | 立即注冊

本版積分規(guī)則

手機(jī)版|小黑屋|51黑電子論壇 |51黑電子論壇6群 QQ 管理員QQ:125739409;技術(shù)交流QQ群281945664

Powered by 單片機(jī)教程網(wǎng)

快速回復(fù) 返回頂部 返回列表