|
|
;4X4矩陣鍵盤(pán)程序。主要原理為掃描鍵盤(pán)矩陣時(shí)，每次只有一行電平拉低。在逐次掃描拉低的這些行的同時(shí)，去讀那些列的電平。
;被拉低的行上，按下的鍵對(duì)應(yīng)的列的電平為0 ，其它為1. 用左移位的指令，在進(jìn)位位CY里就可以檢測(cè)出是0還是1.為1表示無(wú)按下，
;為0表示該鍵按下。在掃描按鍵時(shí)，如無(wú)按下，則取碼指針R1加1后，繼續(xù)掃描 。如有鍵按下，轉(zhuǎn)按鍵處理子程序，按鍵按下標(biāo)志位
;F0清0(表示按下)。此時(shí)，取碼指針的值，就是按鍵的鍵名。 隨后繼續(xù)進(jìn)入按鍵檢測(cè)子程序重新掃描。
;注：本程序只通過(guò)仿真，因無(wú)按鍵防抖，實(shí)物中正常與否，未能確定 。
;2011 04 10 D:\DPJ\4X4KEY.ASM
ORG 00H
AJMP MAIN
ORG 30H
MAIN:
MOV SP,#60H
MOV DPTR,#TABLE
KEY:
ACALL KEY0_1 ;調(diào)用KEY0_1，判斷是否有鍵按下
JB F0,$-2 ;無(wú)鍵按下，轉(zhuǎn)ACALL KEY0_1，繼續(xù)掃描
MOV A,R1 ;R1為取碼指針
MOVC A,@A+DPTR ;取碼，關(guān)送顯示
MOV P1,A
AJMP KEY
KEY0_1: ;按鍵檢測(cè)子程序
SETB F0 ;設(shè)F0=1
MOV R3,#0F7H ;行掃描指針初值（P2.3=0)
MOV R1,#00H ;取碼指針初值
L2:
MOV A,R3 ;載入掃描指針
MOV P2,A ;輸出至P2，開(kāi)始掃描為0的一行
NOP
MOV A,P2 ;讀入P2
SETB C
MOV R5,#4 ;檢測(cè)P2.7~P2.4,共4 列
L3: ;檢測(cè)4列
RLC A ;左移一位(P2.7~P2.4)
JNC KEY1 ;檢測(cè)到C=0，表示被按下
INC R1 ;無(wú)鍵按下則取碼指針加1
DJNZ R5,L3 ;4列檢測(cè)完畢？
MOV A,R3 ;載入掃描指針
SETB C
RRC A ;掃描為0的下一行,
MOV R3,A ;存回R3掃描指針寄存器
JC L2 ;C=0，行掃描完畢
RET
KEY1:
CLR F0 ;F0清0 ，表示按鍵按下
RET
TABLE:
DB 0C0H;0
DB 0F9H;1
DB 0A4H;2
DB 0B0H;3
DB 099H;4
DB 092H;5
DB 082H;
DB 0F8H;7
DB 080H;8
DB 090H;9
DB 088H;A
DB 083H;b
DB 0C6H;C
DB 0A1H;d
DB 086H;E
DB 08EH;F
END
其實(shí)4X4矩陣的51C程序很多，有的也簡(jiǎn)單。這個(gè)完全按上面匯編的寫(xiě)成C的，有點(diǎn)繁了。
//E:\DPJ_C\4X4KEY\4X4KEY.C
//2012 04 17 更新
#include<reg51.h>
#include<intrins.h>
#define uchar unsigned char
#define uint unsigned int
uchar a,b,temp; //a
bit flag;
uchar code tab[]={
0xC0,/*0*/
0xF9,/*1*/
0xA4,/*2*/
0xB0,/*3*/
0x99,/*4*/
0x92,/*5*/
0x82,/*6*/
0xF8,/*7*/
0x80,/*8*/
0x90,/*9*/
0x88,/*A*/
0x83,/*b*/
0xC6,/*C*/
0xA1,/*d*/
0x86,/*E*/
0x8E,/*F*/
};
void keyscan()
{
uchar i,j;
flag=1;//flag 有鍵按下標(biāo)志
temp=0xf7; //temp 行掃描指針
a=0;
for(j=0;j<4;j++)
{
P2=temp;
_nop_();
b=P2; // b 列
for(i=0;i<4;i++)
{
b=b<<1;
if(!CY)
{
flag=0;//有鍵按下，標(biāo)志置0
return; //跳出
}
else
a++;//無(wú)鍵按下，
}
temp=_cror_(temp,1);//掃描下一行
}
}
void main()
{
while(1)
{
keyscan();
if(!flag)
P1=tab[a];
}
}
|
|
[復(fù)制鏈接]
