經(jīng)過幾天的努力，第一個(gè)51單片機(jī)電子時(shí)鐘終于出爐了，通過4位數(shù)碼管來顯示時(shí)間，系統(tǒng)晶振11.0592MHZ，仿真圖中用二極管代替時(shí)鐘冒號(hào)閃爍，非門代替三極管，讓仿真速度與真實(shí)速度達(dá)到一致，本設(shè)計(jì)用了6個(gè)按鈕來對(duì)時(shí)間及鬧鐘時(shí)間的調(diào)節(jié)、關(guān)閉，p3.2接時(shí)間分加1按鈕，p3.3接時(shí)間時(shí)加1按鈕，p3.4接鬧鐘時(shí)間與當(dāng)前時(shí)間切換按鈕，按住不放顯示鬧鐘的時(shí)間，鬧鐘初始化為00：00，放開按鈕則顯示當(dāng)前時(shí)間，p3.5接鬧鐘加1按鈕，p3.6接鬧鐘時(shí)加1按鈕，p3.7接關(guān)閉鬧鐘按鈕
有沒有人會(huì)問 ，怎么沒有減的按鈕呢？？？
為了不用那么多按鈕，所以只設(shè)置了加1的按鈕，那減的怎么辦？？
程序的設(shè)計(jì)是這樣的，當(dāng)分加到59的時(shí)候，再加一次就變00，當(dāng)時(shí)加到23的時(shí)候，再加一次就變00，從而實(shí)現(xiàn)了減的效果，O(∩_∩)O，附帶仿真圖和程序源代碼及實(shí)物圖.........
仿真圖
實(shí)物圖目前還差3個(gè)按鈕，準(zhǔn)備補(bǔ)上\(^o^)/~，電源的指示燈太亮了╮(╯▽╰)╭，準(zhǔn)備把它拆了
作者：胡琴
聯(lián)系qq：1257394091
本程序版本規(guī)本人所有可以任意轉(zhuǎn)載：
技術(shù)支持網(wǎng)站：http://www.torrancerestoration.com
本程序已經(jīng)通過軟件仿真和硬件制作.
程序源代碼：
org 0000h
ajmp main ;調(diào)至主程序
org 000bh ;T0中斷入口地址
ljmp inti0
org 001bh ;T1中斷入口地址
ljmp inti1
org 0030h
main:mov tmod,#11h ;設(shè)T0、T1為模式1
mov ie,#8ah ;開T0、T1中斷允許
mov th0,#4ch ;賦T0 50ms初值
mov tl0,#00h
mov th1,#4ch ;賦T1 50ms初值
mov tl1,#00h
mov sp,#60h ;設(shè)置堆棧指針
mov r0,#20 ; T0 50ms計(jì)數(shù)20次
mov 31h,#00 ;時(shí)間秒初始化
mov 32h,#00 ;時(shí)間分初始化
mov 33h,#00 ;時(shí)間時(shí)初始化
mov 38h,#00 ;鬧鐘分初始化
mov 39h,#00 ;鬧鐘時(shí)初始化
setb tr0 ;啟動(dòng)T0
setb tr1 ;啟動(dòng)T1
loop:lcall display ;調(diào)用時(shí)間顯示子程序
lcall key ;調(diào)用時(shí)間調(diào)節(jié)按鍵子程序
lcall keynz ;調(diào)用鬧鐘按鍵子程序
ajmp loop
inti0:push psw ;保護(hù)現(xiàn)場
push acc
clr ea ;關(guān)中斷
mov th0,#4ch ;重賦50ms初值
mov tl0,#00h
djnz r0,out ;對(duì)50ms計(jì)數(shù)判斷
mov r0,#20 ;重賦50ms計(jì)數(shù)值
inc 31h ;秒加1
cpl p2.2 ;P2.2取反輸出
mov a,31h
cjne a,#60,out ;判秒是否加到60，沒有加到中斷返回
mov 31h,#00 ;秒加到60，對(duì)秒清零
inc 32h ;分加1
mov a,32h
cjne a,#60,out ;判分是否加到60，沒有加到就中斷返回
mov 32h,#00 ;分加到60，對(duì)分清零
inc 33h ;時(shí)加1
mov a,33h
cjne a,#24,out ;判時(shí)是否加到24，沒有就中斷返回
mov 33h,#00 ;時(shí)加到24，對(duì)時(shí)清零
out: setb ea ;開中斷
pop acc ;恢復(fù)現(xiàn)場
pop psw
reti ;中斷返回
inti1:push psw ;保護(hù)現(xiàn)場
push acc
clr ea ;關(guān)中斷
mov th1,#4ch ;賦50ms初值
mov tl1,#00h
inc 3ah
mov a,3ah
cjne a,#20,out1 ;判斷50ms計(jì)數(shù)是否到20，沒到就中斷返回
mov 3ah,#00 ;50ms計(jì)數(shù)到20，將計(jì)數(shù)單元清零
mov a,32h
cjne a,38h,out1 ;鬧鐘分與時(shí)間分判斷
mov a,33h
cjne a,39h,out1 ;鬧鐘時(shí)與時(shí)間時(shí)判斷
clr p1.0 ;相等就清p1.0輸出
out1: setb ea ;開中斷
pop acc ;恢復(fù)現(xiàn)場
pop psw
reti ;中斷返回
display:mov a,31h ;秒顯示
mov b,#10
div ab
mov 20h,a ;將秒十位存20h
mov 21h,b ;將秒個(gè)位存21h
disp1: mov a,20h ;秒十位顯示
mov dptr,#table ;查表
movc a,@a+dptr ;將A與查表的值相加，回存給A
mov p0,a ;將A的值賦給P0口
clr p2.0 ;點(diǎn)亮秒十位
lcall del1ms ;調(diào)用延時(shí)1MS子程序
setb p2.0 ;滅秒十位
disp2: mov a,21h ;秒個(gè)位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.1
lcall del1ms
setb p2.1
disp3: mov a,32h ;分顯示
mov b,#10
div ab
mov 22h,a
mov 23h,b
disp4: mov a,22h ;分十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.6
lcall del1ms
setb p2.6
disp5: mov a,23h ;分個(gè)位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.7
lcall del1ms
setb p2.7
disp6: mov a,33h ;時(shí)顯示
mov b,#10
div ab
mov 24h,a
mov 25h,b
disp7: mov a,24h ;時(shí)十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
disp8: mov a,25h ;時(shí)個(gè)位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.5
lcall del1ms
setb p2.5
ret
display1:mov a,38h ;鬧鐘分顯示
mov b,#10
div ab
mov 26h,a
mov 27h,b
dispnz1:mov a,26h ;鬧鐘分十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.6
lcall del1ms
setb p2.6
dispnz2:mov a,27h ;鬧鐘分個(gè)位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.7
lcall del1ms
setb p2.7
dispnz3:mov a,39h ;鬧鐘時(shí)顯示
mov b,#10
div ab
mov 28h,a
mov 29h,b
dispnz4:mov a,28h ;鬧鐘時(shí)十位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.4
lcall del1ms
setb p2.4
dispnz5:mov a,29h ;鬧鐘時(shí)個(gè)位顯示
mov dptr,#table
movc a,@a+dptr
mov p0,a
clr p2.5
lcall del1ms
setb p2.5
ret
table:db 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H ;數(shù)字0-9的十六進(jìn)制數(shù)
del1ms:mov r7,#10 ;1ms延時(shí)子程序
del1: mov r6,#50
del2:djnz r6,del2
djnz r7,del1
ret
del20ms:mov r5,#40 ;20ms延時(shí)子程序
del3:mov r4,#250
del4:djnz r4,del4
djnz r5,del3
ret
key:jnb p3.2,key1 ;時(shí)間分加1按鈕
jnb p3.3,key2 ;時(shí)間時(shí)加1按鈕
sjmp keyout
key1:lcall del20ms ;20ms延時(shí)消抖
jb p3.2,keyout
jnb p3.2,$ ;等待按鍵放開
inc 32h ;分加1
mov a,32h
cjne a,#60,keyout ;判分是否加到60，沒有就返回
mov 32h,#00
sjmp keyout
key2:lcall del20ms ;20ms延時(shí)消抖
jb p3.3,keyout
jnb p3.3,$ ;等待按鍵放開
inc 33h ;時(shí)加1
mov a,33h
cjne a,#24,keyout ;判時(shí)是否加到24，沒有就返回
mov 33h,#00 ;時(shí)加到24，時(shí)清零
sjmp keyout
keyout:ret
keynz:jnb p3.4,keynz1 ;鬧鐘時(shí)間和當(dāng)前時(shí)間切換按鈕
jnb p3.5,keynz2 ;鬧鐘加分1按鈕
jnb p3.6,keynz3 ;鬧鐘時(shí)加1按鈕
jnb p3.7,keynz4 ;關(guān)閉鬧鐘按鈕
sjmp nzout
nz1:lcall display1 ;調(diào)用顯示鬧鐘時(shí)間子程序
jnb p3.5,keynz2
jnb p3.6,keynz3
keynz1:jnb p3.4,nz1 ;按住按鍵不放開顯示鬧鐘時(shí)間并可以調(diào)，放開則顯示當(dāng)前時(shí)間
sjmp nzout
keynz2:lcall del20ms
jb p3.5,nzout
jnb p3.5,$ ;等待按鍵放開
inc 38h ;鬧鐘分加1
mov a,38h
cjne a,#60,nzout ;判鬧鐘分是否加到60，沒有就返回
mov 38h,#00 ;鬧鐘分加到60，將鬧鐘分清零
sjmp nzout
keynz3:lcall del20ms
jb p3.6,nzout
jnb p3.6,$ ;等待按鍵放開
inc 39h ;鬧鐘時(shí)加1
mov a,39h
cjne a,#24,nzout ;判鬧鐘時(shí)是否加到24，沒有就中斷返回
mov 39h,#00 ;鬧鐘時(shí)加到24，鬧鐘時(shí)清零
sjmp nzout
keynz4:jb p3.7,nzout
jnb p3.7,$ ;等待按鍵放開
setb p1.0 ;關(guān)閉鬧鐘
sjmp nzout
nzout:ret
end