X1226提供一個(gè)備份電源輸入腳VBACK，允許器件用電池或大容量電容進(jìn)行備份供電。采用電容供電時(shí)，用一個(gè)硅或肖特基二極管連接到Vcc和充電電容的兩端，充電電容連接到Vback管腳，注意不能使用二極管對(duì)電池充電(特別是鋰離子電池)。切換到電池供電的條件是Vcc=Vback-0.1V，正常操作期間，供電電壓Vcc必須高于電池電壓，否則電池電量將逐步耗盡。振蕩器采用外接32.768kH的晶體，產(chǎn)生的振蕩誤差可通過軟件對(duì)數(shù)字微調(diào)寄存器、模擬微調(diào)寄存器的數(shù)值進(jìn)行調(diào)節(jié)加以修正，避免了外接電阻和電容的離散性對(duì)精度的影響。4Kb的EEPROM可用于存儲(chǔ)戶數(shù)據(jù)。
電路組成及工作原理
X1226可與各種類型的的微控制器或微處理器接口，接口方式為串行的I2C接口。其中數(shù)據(jù)總線SDA是一個(gè)雙向引腳，用于輸入或輸出數(shù)據(jù)。其漏極開路輸出在使用過程中需要添加4.7～10kΩ的上拉電阻。本文介紹89C51單片機(jī)與X1226的接口方法，由于89C51單片機(jī)沒有標(biāo)準(zhǔn)的I2C接口，只能用軟件進(jìn)行模擬。
圖1
為了更直觀地看到時(shí)間的變化，采用8位LED數(shù)碼管顯示年、月、日或時(shí)、分、秒，用PS7219A驅(qū)動(dòng)LED數(shù)碼管，數(shù)碼管選擇0.5英寸共陰極紅色或綠色LED數(shù)碼管。由于PS7219A器件內(nèi)含IMP810單片機(jī)監(jiān)控器件，復(fù)位輸出高電平有效，因此在使用51系統(tǒng)時(shí)，無(wú)須添加監(jiān)控器件，使用PS7219A的復(fù)位輸出給51單片機(jī)復(fù)位即可，監(jiān)控電壓為4.63V。硬件設(shè)計(jì)原理圖如圖1所示。
在硬件通電調(diào)試過程中，不能用手去觸摸X1226的晶體振蕩器，否則可能會(huì)導(dǎo)致振蕩器停振，恢復(fù)振蕩器起振的方法是關(guān)閉電源(包括備份電源)后重新上電。另外需要說(shuō)明的是，測(cè)量振蕩器時(shí)，不要用示波器的探頭去測(cè)量X2的振蕩輸出，應(yīng)該用探頭測(cè)量PHZ/IRQ的振蕩輸出，以確定是否起振和振蕩頻率是否準(zhǔn)確，測(cè)量時(shí)建議在該腳加一個(gè)5.1kΩ的上拉電阻。
軟件設(shè)計(jì)
X1226內(nèi)含實(shí)時(shí)時(shí)鐘寄存器(RTC)、狀態(tài)寄存器(SR)、控制寄存器(CONTROL)、報(bào)警寄存器(Alarm0、Alarm1)和客戶存儲(chǔ)數(shù)據(jù)的存儲(chǔ)器。由于實(shí)時(shí)時(shí)鐘寄存器和狀態(tài)寄存器需要進(jìn)行頻繁的寫操作，因此其存儲(chǔ)結(jié)構(gòu)為易失性SRAM結(jié)構(gòu)。其他寄存器均為EEPROM結(jié)構(gòu)，寫操作次數(shù)通常在10萬(wàn)次以上。X1226初始化程序框圖如圖2所示，子程序YS4的作用是延時(shí)4μs。
圖2
● 寫操作
X1226初始化之后，單片機(jī)對(duì)X1226進(jìn)行開始條件的設(shè)置，在寫CCR或EEPROM之前，主機(jī)必須先向狀態(tài)寄存器寫02H，確認(rèn)應(yīng)答信號(hào)，確認(rèn)后寫入06H，再確認(rèn)應(yīng)答信號(hào)。確認(rèn)后啟動(dòng)了寫操作，首先發(fā)送高位地
X1226具有連續(xù)寫入的功能，每收到1字節(jié)后，響應(yīng)一個(gè)應(yīng)答，其內(nèi)部將地址加一。當(dāng)計(jì)數(shù)器達(dá)到該頁(yè)的末尾時(shí)，就自動(dòng)返回到該頁(yè)的首地址。這意味著單片機(jī)可從某一頁(yè)的任何位置開始向存儲(chǔ)器陣列連續(xù)寫入64字節(jié)，或向CCR連續(xù)寫入8字節(jié)的數(shù)據(jù)。寫入X1226數(shù)據(jù)子程序:
● 讀操作
在上電時(shí)，16位地址的默認(rèn)值為0000H。X1226初始化操作之后，單片機(jī)對(duì)X1226進(jìn)行開始條件的設(shè)置，在寫CCR或EEPROM之前，主機(jī)必須先向狀態(tài)寄存器寫02H，確認(rèn)應(yīng)答信號(hào)，確認(rèn)后寫入06H，再確認(rèn)應(yīng)答信號(hào)。確認(rèn)后啟動(dòng)了寫操作，首先發(fā)送高位地址，然后發(fā)送低位地址。X1226每收到一個(gè)地址字節(jié)后，均會(huì)產(chǎn)生一個(gè)應(yīng)答信號(hào)。單片機(jī)發(fā)送另一個(gè)開始條件，將R/W位設(shè)置為1，接著接受8位數(shù)據(jù)。單片機(jī)終止讀操作時(shí)，無(wú)需等待X1226的應(yīng)答信號(hào)，單片機(jī)即可設(shè)置停止條件。讀出X1226數(shù)據(jù)子程序:
● 振蕩器頻率在線補(bǔ)償調(diào)節(jié)
X1226集成了振蕩器補(bǔ)償電路，用戶可通過軟件在線對(duì)振蕩器頻率進(jìn)行微調(diào)，這種微調(diào)通常針對(duì)兩種情況。一種情況是在25℃常溫下，對(duì)振蕩器因器件初始精度帶來(lái)的頻率偏差進(jìn)行補(bǔ)償；第二種情況是對(duì)因溫度引起的頻率漂移進(jìn)行補(bǔ)償。X1226內(nèi)部設(shè)有數(shù)字微調(diào)寄存器(DTR)和模擬微調(diào)寄存器(ATR)，兩個(gè)寄存器均為非易失性寄存器。數(shù)字微調(diào)寄存器具有3位數(shù)字微調(diào)位，調(diào)節(jié)范圍為-30～+30×10-6。模擬微調(diào)寄存器具有6個(gè)模擬微調(diào)位，調(diào)節(jié)范圍為-37～+116×10-6。
對(duì)于因外界環(huán)境溫度變化引起的溫漂補(bǔ)償，要依據(jù)晶體的溫度系數(shù)，在存儲(chǔ)器中建立補(bǔ)償參數(shù)表，不同廠家晶體的溫度系數(shù)是不一樣的，應(yīng)根據(jù)產(chǎn)品數(shù)據(jù)手冊(cè)進(jìn)行選擇。
為了能夠?qū)仄M(jìn)行補(bǔ)償，要求系統(tǒng)中設(shè)置一個(gè)溫度傳感器，并盡量讓它靠近X1226，這樣可以真實(shí)地反映振蕩器的溫度，原理圖如圖3所示。單片機(jī)首先通過系統(tǒng)溫度傳感器獲取環(huán)境溫度，并在補(bǔ)償參數(shù)表中獲取對(duì)應(yīng)的補(bǔ)償值，然后將補(bǔ)償數(shù)據(jù)填寫到相應(yīng)的微調(diào)寄存器中，就能實(shí)現(xiàn)溫漂補(bǔ)償?shù)哪康摹?br />
圖3
由于X1226具有精密的振蕩器補(bǔ)償功能，因此非常適合于環(huán)境溫度變化較大的應(yīng)用場(chǎng)合，同時(shí)也降低了對(duì)晶體性能參數(shù)的要求
下面還為廣大讀者介紹一個(gè)程序：
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; AT89C2051時(shí)鐘程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
; 定時(shí)器T0、T1溢出周期為50MS，T0為秒計(jì)數(shù)用， T1為調(diào)整時(shí)閃爍用，
; P3.7為調(diào)整按鈕，P1口 為字符輸出口，采用共陽(yáng)顯示管。
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 中斷入口程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ORG 0000H ;程序執(zhí)行開始地址
LJMP START ;跳到標(biāo)號(hào)START執(zhí)行
ORG 0003H ;外中斷0中斷程序入口
RETI ;外中斷0中斷返回
ORG 000BH ;定時(shí)器T0中斷程序入口
LJMP INTT0 ;跳至INTTO執(zhí)行
ORG 0013H ;外中斷1中斷程序入口
RETI ;外中斷1中斷返回
ORG 001BH ;定時(shí)器T1中斷程序入口
LJMP INTT1 ;跳至INTT1執(zhí)行
ORG 0023H ;串行中斷程序入口地址
RETI ;串行中斷程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 主 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
START: MOV R0,#70H ;清70H-7AH共11個(gè)內(nèi)存單元
MOV R7,#0BH ;
CLEARDISP: MOV @R0,#00H ;
INC R0 ;
DJNZ R7,CLEARDISP ;
MOV 20H,#00H ;清20H（標(biāo)志用）
MOV 7AH,#0AH ;放入"熄滅符"數(shù)據(jù)
MOV TMOD,#11H ;設(shè)T0、T1為16位定時(shí)器
MOV TL0,#0B0H ;50MS定時(shí)初值（T0計(jì)時(shí)用）
MOV TH0,#3CH ;50MS定時(shí)初值
MOV TL1,#0B0H ;50MS定時(shí)初值（T1閃爍定時(shí)用）
MOV TH1,#3CH ;50MS定時(shí)初值
SETB EA ;總中斷開放
SETB ET0 ;允許T0中斷
SETB TR0 ;開啟T0定時(shí)器
MOV R4,#14H ;1秒定時(shí)用初值（50MS×20）
START1: LCALL DISPLAY ;調(diào)用顯示子程序
JNB P3.7,SETMM1 ;P3.7口為0時(shí)轉(zhuǎn)時(shí)間調(diào)整程序
SJMP START1 ;P3.7口為1時(shí)跳回START1
SETMM1: LJMP SETMM ;轉(zhuǎn)到時(shí)間調(diào)整程序SETMM
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 1秒計(jì)時(shí)程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T0中斷服務(wù)程序
INTT0: PUSH ACC ;累加器入棧保護(hù)
PUSH PSW ;狀態(tài)字入棧保護(hù)
CLR ET0 ;關(guān)T0中斷允許
CLR TR0 ;關(guān)閉定時(shí)器T0
MOV A,#0B7H ;中斷響應(yīng)時(shí)間同步修正
ADD A,TL0 ;低8位初值修正
MOV TL0,A ;重裝初值（低8位修正值）
MOV A,#3CH ;高8位初值修正
ADDC A,TH0 ;
MOV TH0,A ;重裝初值（高8位修正值）
SETB TR0 ;開啟定時(shí)器T0
DJNZ R4, OUTT0 ;20次中斷未到中斷退出
ADDSS: MOV R4,#14H ;20次中斷到（1秒）重賦初值
MOV R0,#71H ;指向秒計(jì)時(shí)單元（71H-72H）
ACALL ADD1 ;調(diào)用加1程序（加1秒操作）
MOV A,R3 ;秒數(shù)據(jù)放入A（R3為2位十進(jìn)制數(shù)組合）
CLR C ;清進(jìn)位標(biāo)志
CJNE A,#60H,ADDMM ;
ADDMM: JC OUTT0 ;小于60秒時(shí)中斷退出
ACALL CLR0 ;大于或等于60秒時(shí)對(duì)秒計(jì)時(shí)單元清0
MOV R0,#77H ;指向分計(jì)時(shí)單元（76H-77H）
ACALL ADD1 ;分計(jì)時(shí)單元加1分鐘
MOV A,R3 ;分?jǐn)?shù)據(jù)放入A
CLR C ;清進(jìn)位標(biāo)志
CJNE A,#60H,ADDHH ;
ADDHH: JC OUTT0 ;小于60分時(shí)中斷退出
ACALL CLR0 ;大于或等于60分時(shí)分計(jì)時(shí)單元清0
MOV R0,#79H ;指向小時(shí)計(jì)時(shí)單元（78H-79H）
ACALL ADD1 ;小時(shí)計(jì)時(shí)單元加1小時(shí)
MOV A,R3 ;時(shí)數(shù)據(jù)放入A
CLR C ;清進(jìn)位標(biāo)志
CJNE A,#24H,HOUR ;
HOUR: JC OUTT0 ;小于24小時(shí)中斷退出
ACALL CLR0 ;大于或等于24小時(shí)小時(shí)計(jì)時(shí)單元清0
OUTT0: MOV 72H,76H ;中斷退出時(shí)將分、時(shí)計(jì)時(shí)單元數(shù)據(jù)移
MOV 73H,77H ;入對(duì)應(yīng)顯示單元
MOV 74H,78H ;
MOV 75H,79H ;
POP PSW ;恢復(fù)狀態(tài)字（出棧）
POP ACC ;恢復(fù)累加器
SETB ET0 ;開放T0中斷
RETI ;中斷返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 閃動(dòng)調(diào)時(shí) 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;T1中斷服務(wù)程序，用作時(shí)間調(diào)整時(shí)調(diào)整單元閃爍指示
INTT1: PUSH ACC ;中斷現(xiàn)場(chǎng)保護(hù)
PUSH PSW ;
MOV TL1, #0B0H ;裝定時(shí)器T1定時(shí)初值
MOV TH1, #3CH ;
DJNZ R2,INTT1OUT ;0.3秒未到退出中斷（50MS中斷6次）
MOV R2,#06H ;重裝0.3秒定時(shí)用初值
CPL 02H ;0.3秒定時(shí)到對(duì)閃爍標(biāo)志取反
JB 02H,FLASH1 ;02H位為1時(shí)顯示單元"熄滅"
MOV 72H,76H ;02H位為0時(shí)正常顯示
MOV 73H,77H ;
MOV 74H,78H ;
MOV 75H,79H ;
INTT1OUT:
POP PSW ;恢復(fù)現(xiàn)場(chǎng)
POP ACC ;
RETI ;中斷退出
FLASH1: JB 01H,FLASH2 ;01H位為1時(shí)，轉(zhuǎn)小時(shí)熄滅控制
MOV 72H,7AH ;01H位為0時(shí)，"熄滅符"數(shù)據(jù)放入分
MOV 73H,7AH ;顯示單元（72H-73H），將不顯示分?jǐn)?shù)據(jù)
MOV 74H,78H ;
MOV 75H,79H ;
AJMP INTT1OUT ;轉(zhuǎn)中斷退出
FLASH2: MOV 72H,76H ;01H位為1時(shí)，"熄滅符"數(shù)據(jù)放入小時(shí)
MOV 73H,77H ;顯示單元（74H-75H），小時(shí)數(shù)據(jù)將不顯示
MOV 74H,7AH ;
MOV 75H,7AH ;
AJMP INTT1OUT ;轉(zhuǎn)中斷退出
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 加1子 程 序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
ADD1: MOV A,@R0 ;取當(dāng)前計(jì)時(shí)單元數(shù)據(jù)到A
DEC R0 ;指向前一地址
SWAP A ;A中數(shù)據(jù)高四位與低四位交換
ORL A,@R0 ;前一地址中數(shù)據(jù)放入A中低四位
ADD A,#01H ;A加1操作
DA A ;十進(jìn)制調(diào)整
MOV R3,A ;移入R3寄存器
ANL A,#0FH ;高四位變0
MOV @R0,A ;放回前一地址單元
MOV A,R3 ;取回R3中暫存數(shù)據(jù)
INC R0 ;指向當(dāng)前地址單元
SWAP A ;A中數(shù)據(jù)高四位與低四位交換
ANL A,#0FH ;高四位變0
MOV @R0,A ;數(shù)據(jù)放入當(dāng)削地址單元中
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 清零程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;對(duì)計(jì)時(shí)單元復(fù)零用
CLR0: CLR A ;清累加器
MOV @R0,A ;清當(dāng)前地址單元
DEC R0 ;指向前一地址
MOV @R0,A ;前一地址單元清0
RET ;子程序返回
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 時(shí)鐘調(diào)整程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;當(dāng)調(diào)時(shí)按鍵按下時(shí)進(jìn)入此程序
SETMM: cLR ET0 ;關(guān)定時(shí)器T0中斷
CLR TR0 ;關(guān)閉定時(shí)器T0
LCALL DL1S ;調(diào)用1秒延時(shí)程序
JB P3.7,CLOSEDIS ;鍵按下時(shí)間小于1秒，關(guān)閉顯示（省電）
MOV R2,#06H ;進(jìn)入調(diào)時(shí)狀態(tài)，賦閃爍定時(shí)初值
SETB ET1 ;允許T1中斷
SETB TR1 ;開啟定時(shí)器T1
SET2: JNB P3.7,SET1 ;P3.7口為0（鍵未釋放），等待
SETB 00H ;鍵釋放，分調(diào)整閃爍標(biāo)志置1
SET4: JB P3.7,SET3 ;等待鍵按下
LCALL DL05S ;有鍵按下，延時(shí)0.5秒
JNB P3.7,SETHH ;按下時(shí)間大于0.5秒轉(zhuǎn)調(diào)小時(shí)狀態(tài)
MOV R0,#77H ;按下時(shí)間小于0.5秒加1分鐘操作
LCALL ADD1 ;調(diào)用加1子程序
MOV A,R3 ;取調(diào)整單元數(shù)據(jù)
CLR C ;清進(jìn)位標(biāo)志
CJNE A,#60H,HHH ;調(diào)整單元數(shù)據(jù)與60比較
HHH: JC SET4 ;調(diào)整單元數(shù)據(jù)小于60轉(zhuǎn)SET4循環(huán)
LCALL CLR0 ;調(diào)整單元數(shù)據(jù)大于或等于60時(shí)清0
CLR C ;清進(jìn)位標(biāo)志
AJMP SET4 ;跳轉(zhuǎn)到SET4循環(huán)
CLOSEDIS:SETB ET0 ;省電（LED不顯示）狀態(tài)。開T0中斷
SETB TR0 ;開啟T0定時(shí)器（開時(shí)鐘）
CLOSE: JB P3.7,CLOSE ;無(wú)按鍵按下，等待。
LCALL DISPLAY ;有鍵按下，調(diào)顯示子程序延時(shí)削抖
JB P3.7,CLOSE ;是干擾返回CLOSE等待
WAITH: JNB P3.7,WAITH ;等待鍵釋放
LJMP START1 ;返回主程序（LED數(shù)據(jù)顯示亮）
SETHH: CLR 00H ;分閃爍標(biāo)志清除（進(jìn)入調(diào)小時(shí)狀態(tài)）
SETHH1: JNB P3.7,SET5 ;等待鍵釋放
SETB 01H ;小時(shí)調(diào)整標(biāo)志置1
SET6: JB P3.7,SET7 ;等待按鍵按下
LCALL DL05S ;有鍵按下延時(shí)0.5秒
JNB P3.7,SETOUT ;按下時(shí)間大于0.5秒退出時(shí)間調(diào)整
MOV R0,#79H ;按下時(shí)間小于0.5秒加1小時(shí)操作
LCALL ADD1 ;調(diào)加1子程序
MOV A,R3 ;
CLR C ;
CJNE A,#24H,HOUU ;計(jì)時(shí)單元數(shù)據(jù)與24比較
HOUU: JC SET6 ;小于24轉(zhuǎn)SET6循環(huán)
LCALL CLR0 ;大于或等于24時(shí)清0操作
AJMP SET6 ;跳轉(zhuǎn)到SET6循環(huán)
SETOUT: JNB P3.7,SETOUT1 ;調(diào)時(shí)退出程序。等待鍵釋放
LCALL DISPLAY ;延時(shí)削抖
JNB P3.7,SETOUT ;是抖動(dòng)，返回SETOUT再等待
CLR 01H ;清調(diào)小時(shí)標(biāo)志
CLR 00H ;清調(diào)分標(biāo)志
CLR 02H ;清閃爍標(biāo)志
CLR TR1 ;關(guān)閉定時(shí)器T1
CLR ET1 ;關(guān)定時(shí)器T1中斷
SETB TR0 ;開啟定時(shí)器T0
SETB ET0 ;開定時(shí)器T0中斷（計(jì)時(shí)開始）
LJMP START1 ;跳回主程序
SET1: LCALL DISPLAY ;鍵釋放等待時(shí)調(diào)用顯示程序（調(diào)分）
AJMP SET2 ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
SET3: LCALL DISPLAY ;等待調(diào)分按鍵時(shí)時(shí)鐘顯示用
AJMP SET4
SET5: LCALL DISPLAY ;鍵釋放等待時(shí)調(diào)用顯示程序（調(diào)小時(shí)）
AJMP SETHH1 ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
SET7: LCALL DISPLAY ;等待調(diào)小時(shí)按鍵時(shí)時(shí)鐘顯示用
AJMP SET6
SETOUT1: LCALL DISPLAY ;退出時(shí)鐘調(diào)整時(shí)鍵釋放等待
AJMP SETOUT ;防止鍵按下時(shí)無(wú)時(shí)鐘顯示
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 顯示程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; 顯示數(shù)據(jù)在70H-75H單元內(nèi)，用六位LED共陽(yáng)數(shù)碼管顯示，P1口輸出段碼數(shù)據(jù)，P3口作
; 掃描控制，每個(gè)LED數(shù)碼管亮1MS時(shí)間再逐位循環(huán)。
DISPLAY: MOV R1,#70H ;指向顯示數(shù)據(jù)首址
MOV R5,#0FEH ;掃描控制字初值
PLAY: MOV A,R5 ;掃描字放入A
MOV P3,A ;從P3口輸出
MOV A,@R1 ;取顯示數(shù)據(jù)到A
MOV DPTR,#TAB ;取段碼表地址
MOVC A,@A+DPTR ;查顯示數(shù)據(jù)對(duì)應(yīng)段碼
MOV P1,A ;段碼放入P1口
LCALL DL1MS ;顯示1MS
INC R1 ;指向下一地址
MOV A,R5 ;掃描控制字放入A
JNB ACC.5,ENDOUT ;ACC.5=0時(shí)一次顯示結(jié)束
RL A ;A中數(shù)據(jù)循環(huán)左移
MOV R5,A ;放回R5內(nèi)
AJMP PLAY ;跳回PLAY循環(huán)
ENDOUT: SETB P3.5 ;一次顯示結(jié)束，P3口復(fù)位
MOV P1,#0FFH ;P1口復(fù)位
RET ;子程序返回
TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
;共陽(yáng)段碼表 "0""1""2" "3""4""5""6""7" "8""9""不亮"
;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;; 延時(shí)程序 ;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;
;1MS延時(shí)程序，LED顯示程序用
DL1MS: MOV R6,#14H
DL1: MOV R7,#19H
DL2: DJNZ R7,DL2
DJNZ R6,DL1
RET
;20MS延時(shí)程序，采用調(diào)用顯示子程序以改善LED的顯示閃爍現(xiàn)象
DS20MS: ACALL DISPLAY
ACALL DISPLAY
ACALL DISPLAY
RET
;延時(shí)程序，用作按鍵時(shí)間的長(zhǎng)短判斷
DL1S: LCALL DL05S
LCALL DL05S
RET
DL05S: MOV R3,#20H ;8毫秒*32=0.196秒
DL05S1: LCALL DISPLAY
DJNZ R3,DL05S1
RET
;
END ;程序結(jié)束